[pcmaster]

I wonder.. if I were to record the player's velocity and then teleportentity the bot with the same one (so not calculating it), wouldn't that technically fix those?
Or not work at all?

[blaacky]

No, that can often cause the bot to go off track and he'll just be jumping in the air and shit. You can perhaps record both velocity and position. Teleport with the recorded velocity and make sure he's near the correct position. This shouldn't be necessary though.

[pcmaster]

Sorry to be annoying, but I still get quite hefty "lags" or corrections often.
I also tried my idea of saving the velocity, but it turned out to be even more laggy.

Current code (mostly unchanged from my last post)

Spoiler

PHP Code:

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float vel[3], float angles[3], int &weapon, int &subtype, int &cmdnum, int &tickcount, int &seed, int mouse[2])
{
    if(client == g_iReplayBotClient)
    {
        if(g_hFrames != null && g_iReplayTick != -1)
        {
            if(g_iReplayTick >= g_hFrames.Length)
            {
                g_iReplayTick = -1;
                CreateTimer(0.5, ResetReplay);
                
                return Plugin_Continue;
            }
            
            g_iReplayTick++;
            
            float vecPosition[3];
            vecPosition[0] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 0);
            vecPosition[1] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 1);
            vecPosition[2] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 2);
            
            float vecAngles[3];
            vecAngles[0] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 3);
            vecAngles[1] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 4);
            
            float vecCurrentPos[3];
            GetEntPropVector(client, Prop_Data, "m_vecOrigin", vecCurrentPos);
            
            buttons = GetArrayCell(g_hFrames, g_iReplayTick -1, 5);
            
            if(GetVectorDistance(vecPosition, vecCurrentPos) > 50.0)
            {
                TeleportEntity(client, vecPosition, vecAngles, NULL_VECTOR);
            }
            else
            {
                float vecVelocity[3];
                MakeVectorFromPoints(vecCurrentPos, vecPosition, vecVelocity);
                ScaleVector(vecVelocity, 1.0/GetTickInterval());
                
                TeleportEntity(client, NULL_VECTOR, vecAngles, vecVelocity);
            }
        }
    }
    else
    {
        if(g_bRecord[client] && !Timer_IsPlayerTouchingZoneType(client, ZtStart))
        {
            g_iPlayerFrames[client]++;
            g_hPlayerFrames[client].Resize(g_iPlayerFrames[client]);

            float vecPosition[3];
            GetClientAbsOrigin(client, vecPosition);
            
            float vecVelocity[3];
            GetEntPropVector(client, Prop_Data, "m_vecAbsVelocity", vecVelocity); 
            
            SetArrayCell(g_hPlayerFrames[client], g_iPlayerFrames[client] - 1, vecPosition[0], 0);
            SetArrayCell(g_hPlayerFrames[client], g_iPlayerFrames[client] - 1, vecPosition[1], 1);
            SetArrayCell(g_hPlayerFrames[client], g_iPlayerFrames[client] - 1, vecPosition[2], 2);
            
            SetArrayCell(g_hPlayerFrames[client], g_iPlayerFrames[client] - 1, angles[0], 3);
            SetArrayCell(g_hPlayerFrames[client], g_iPlayerFrames[client] - 1, angles[1], 4);
            
            SetArrayCell(g_hPlayerFrames[client], g_iPlayerFrames[client] - 1, buttons, 5);
        }
    }
    
    return Plugin_Continue;
} 


Example replay on surf_aircontrol_ksf (lags begin after about half of the map).
https://youtu.be/kuWZffJMbMA

Smooth replay on surf_ace_fix (only one very short hiccup)
https://youtu.be/1o1aXNV1rBs

And lastly, a half-half replay, with a smooth start then hefty lags later
https://youtu.be/SMHcKm6T-T0

Thanks again everyone for your help!

[Mehis]

That seems to be this part:

PHP Code:

if(GetVectorDistance(vecPosition, vecCurrentPos) > 50.0) 


Increase it. Try 128.0

Also, you should use this:

PHP Code:

#define MAX_DIST    128.0 // Change it to your liking.
#define MAX_DIST_SQ    MAX_DIST * MAX_DIST

if(GetVectorDistance(vecPosition, vecCurrentPos, true) > MAX_DIST_SQ) 


There's no reason to square root the result since you are just comparing it.

[pcmaster]

Thanks, that fixed the hard lags on aircontrol (there still are some on other maps, but not that many anymore).
The only problem I still have is those weird "flicks" you can see on doodles after stage 4, like it miscalculates the speed/angles somehow.

[Mehis]

Try these:

PHP Code:

float vecAngles[3];
vecAngles[0] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 3);
vecAngles[1] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 4);
// To
angles[0] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 3);
angles[1] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 4);


// Reset the cmd velocity
vel = view_as<float>( {0.0, 0.0, 0.0} );


// You can also try giving the bot noclip and disable gravity on spawn... (will also disable annoying footsteps)
SetEntityMoveType( client, MOVETYPE_NOCLIP );
SetEntityGravity( client, 0.0 );

// As a last option make sure the bot's render mode isn't RENDER_NONE since I've had bad experiences with it. 


This basically sums up what I've done and my bots are fine.

[aexi0n]

I've actually had some recent success with using a prop dynamic with a player model then parenting a camera to it. The replays are not viewable without using the command, but in exchange its smoother and it also doesn't take up a player slot.

[pcmaster]

Thanks a lot, it's running smoothly now (apart from rare, minimal hiccups here and there - even KSF's bots have these).

This is what I ended up changing:

PHP Code:

float vecAngles[3];
// keep the following two lines
vecAngles[0] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 3);
vecAngles[1] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 4);
// add these
angles[0] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 3);
angles[1] = GetArrayCell(g_hFrames, g_iReplayTick - 1, 4);


// Reset the cmd velocity
vel = view_as<float>( {0.0, 0.0, 0.0} ); 


I think the significant part was overwriting the predicted velocity/angles, as the bot itself did these (as in, the game).