[redivcram]

title

For example... store player's money, armor and a custom currency.. Can this be done by storing them in an array?

new gArray[33]= { gMoney, gArmor, gCredits }

Just save gArray in the savevalue function?

[OciXCrom]

PHP Code:

//SaveData:

format(szVaultData, charsmax(szVaultData), "%i#%i#%i#", gMoney[id], gArmor[id], gCredits[id])
nvault_set(g_Vault, szVaultKey, szVaultData)

//LoadData:
format(szVaultData, charsmax(szVaultData), "%i#%i#%i#", gMoney[id], gArmor[id], gCredits[id])
nvault_get(g_Vault, szVaultKey, szVaultData, charsmax(szVaultData))
replace_all(szVaultData, charsmax(szVaultData), "#", " ")

new szMoney[10], szArmor[10], szCredits[10]
parse(szVaultData, szMoney, charsmax(szMoney), szArmor, charsmax(szArmor), szCredits, charsmax(szCredits))

gMoney[id] = str_to_num(szMoney)
gArmor[id] = str_to_num(szArmor)
gCredits[id] = str_to_num(szCredits) 


[Bugsy]

You can do it an easier way. Let me know how many numbers you need to store and the max possible value of each.

[redivcram]

Save them permanently even if the server crashes... if It's even possible. So max possible value of... 200 for one value, for the other value let it be played time... so I don't know the limit But I also want it to be permanently saved.

@OcixCrom I'll see Bugsy's way and decide which is more suitable for me

[silentscope]

Originally Posted by redivcram Save them permanently even if the server crashes...

good point, how would it affect on performance if its saved permanently?

[redivcram]

Originally Posted by silentscope good point, how would it affect on performance if its saved permanently?

What about saving data in a text document for each player? That is.. each document for each steamid.. will that affect performance and how?

[Bugsy]

My original plan was to store the values within 1 cell since there are 4 bytes to work with. This is useful if you are storing multiple booleans or multiple small value numbers. Play time can get high so this approach would not be good because you would probably need 16 bits just for play time alone, leaving only 16 for the remainder of the values. Also, it could be confusing unless you are familiar with bit operations.

Instead here is something easier. For this you will need nVault Utility

PHP Code:


#include <amxmodx>
#include <nvault_util>

new const Version[] = "0.1";

const MAXPLAYERS = 32;
const TASK_DELAY_PRINT = 34214;

enum _:PlayerStuff
{
    Money,
    Armor,
    Credits,
    PlayTime,
    SteamID[ 32 ]
}
new psPlayerData[ MAXPLAYERS + 1 ][ PlayerStuff ];
new g_Vault;

public plugin_init() 
{
    register_plugin( "nVault Array Example" , Version , "bugsy" );
    
    if ( ( g_Vault = nvault_open( "TestVault" ) ) == INVALID_HANDLE )
        set_fail_state( "Error opening vault" );
}

public plugin_end()
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    get_user_authid( id , psPlayerData[ id ][ SteamID ] , charsmax( psPlayerData[] ) );
    
    LoadData( id );
}

public client_disconnect( id )
{
    SaveData( id );
    remove_task( id + TASK_DELAY_PRINT );
    
    arrayset( psPlayerData[ id ] , 0 , sizeof( psPlayerData[] ) );
}

public SaveData( id )
{
    //Test data
    psPlayerData[ id ][ Money ] = 15333;
    psPlayerData[ id ][ Armor ] = 100;
    psPlayerData[ id ][ Credits ] = 23132123;
    psPlayerData[ id ][ PlayTime ] = 664243;
    
    nvault_set_array( g_Vault , psPlayerData[ id ][ SteamID ] , psPlayerData[ id ] , sizeof( psPlayerData[] ) );
}

public LoadData( id )
{
    new iTimeStamp;
    
    if ( nvault_get_array( g_Vault , psPlayerData[ id ][ SteamID ] , psPlayerData[ id ] , sizeof( psPlayerData[] ) , iTimeStamp ) )
    {
        set_task( 7.0 , "DelayPrint" , id + TASK_DELAY_PRINT );
    }
}

public DelayPrint( id )
{
    id -= TASK_DELAY_PRINT;
    
    client_print( id , print_chat , "Data loaded: Money=%d Armor=%d Credits=%d PlayTime=%d SteamID=%s" , psPlayerData[ id ][ Money ] ,
                                                             psPlayerData[ id ][ Armor ] ,
                                                             psPlayerData[ id ][ Credits ] ,
                                                             psPlayerData[ id ][ PlayTime ] ,
                                                             psPlayerData[ id ][ SteamID ] );
} 


[OciXCrom]

Bear in mind that the data is saved when the client successfully disconnects from the server, so if the server crashes, none of it will get saved. You can avoid this by saving the data in another way, for example when the player spawns, which will have a far less impact when it crashes, but I'm not sure how this will affect the performance.

[redivcram]

I'll keep that in mind. But can I add inside plugin_end an index for online players with get_players and when it crashes (ends) it saves it for every player? Yes.. confusing indeed

[Bugsy]

Yes, you can call the save function any time you want. Doing it at disconnect is normally done because it avoids redundant saves, plus it gives you the accurate last known data for the player.

How often does the average persons server crash? I ran one for years and it was very rare for me. If you have something that is causing a crash, address it. Don't let it be and work around the fact that you will get crashes.

Originally Posted by redivcram I'll keep that in mind. But can I add inside plugin_end an index for online players with get_players and when it crashes (ends) it saves it for every player? Yes.. confusing indeed

No, when a crash occurs nothing gets called. It's like a light switch. plugin_end() only gets called on graceful shutdown and map change.