[Bonqe]

Could somebody be so kind & code simple plugin or if its already coded drop me the link, that only players with ADMIN_LEVEL_H flag could buy, take from floor & use AWP Sniper?

I'd like that in awp_ type maps all players could use AWP sniper, but that not really nessesery to put in the plugin, i can just make in CFG to turn off this plugin when awp_ map is choosed.

[ConnorMcLeod]

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "1.0.0"

#define MAX_PLAYERS 32

#define XO_WEAPONBOX    4
#define m_rgpPlayerItems_wpnbx_slot1 35

new g_iLastTouchedBox[MAX_PLAYERS+1]

public plugin_init()
{
    register_plugin("Awp VIP", VERSION, "ConnorMcLeod")

    RegisterHam(Ham_Spawn, "player", "Player_Spawn_Post", 1)
    RegisterHam(Ham_Touch, "weaponbox", "WeaponBox_Touch")

    register_menucmd(register_menuid("T_BuyRifle", 1), MENU_KEY_5, "BuyAwp")
    register_menucmd(register_menuid("CT_BuyRifle", 1), MENU_KEY_6, "BuyAwp")
}

public client_putinserver(id)
{
    g_iLastTouchedBox[id] = 0
}

public Player_Spawn_Post( id )
{
    g_iLastTouchedBox[id] = 0
}

public WeaponBox_Touch(iWpnBx, id)
{
    if( is_user_alive(id) && pev(iWpnBx, pev_flags) & FL_ONGROUND )
    {
        new iWeapon = get_pdata_cbase(iWpnBx, m_rgpPlayerItems_wpnbx_slot1, XO_WEAPONBOX)
        if( iWeapon > 0 && cs_get_weapon_id(iWeapon) == CSW_AWP && !CanHaveAwp( id ) )
        {
            if( g_iLastTouchedBox[id] != iWpnBx )
            {
                if( !user_has_weapon(id, CSW_SCOUT) )
                {
                    client_print(id, print_center, "#Cstrike_TitlesTXT_Cannot_Buy_This")
                }
                g_iLastTouchedBox[id] = iWpnBx
            }
            return HAM_SUPERCEDE
        }
    }
    return HAM_IGNORED
}

public BuyAwp(id)
{
    if( !CanHaveAwp( id ) )
    {
        client_print(id, print_center, "#Cstrike_TitlesTXT_Cannot_Buy_This")
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

public client_command(id)
{
    static szCommand[8]

    if( read_argv(0, szCommand, charsmax(szCommand)) < 7 )
    {
        return CheckArgAwp(id, szCommand)
    }
    return PLUGIN_CONTINUE
}

public CS_InternalCommand(id, const szCommand[])
{
    return CheckArgAwp(id, szCommand)
}

CheckArgAwp(id, const szCommand[])
{
    static const awp[] = "awp"
    static const magnum[] = "magnum"

    if(    !CanHaveAwp( id )
    &&    ( equali(szCommand, awp) || equali(szCommand, magnum) )    )
    {
        client_print(id, print_center, "#Cstrike_TitlesTXT_Cannot_Buy_This")
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

bool:CanHaveAwp( id )
{
    return !!(get_user_flags(id) & ADMIN_LEVEL_H)
} 


[Niksa]

Can you help me bcs i didn't find it i have an only fy snow server and i want a plugin where only admins with flag t can pick awp on fy_snow and normal players can not they drop it and a text appear "awp is only for vip use" sorry for bad english please help me ty

[Exolent[jNr]]

That's what that plugin does, for VIP's with ADMIN_LEVEL_H (flag 't') access.

[Niksa]

I tried 2 time the plugin doesn't work i complied it put in plugins and wrote in plugins.ini and i restart my server i play only fy_snow on my server and everybody can pick the awp normal players and admins with flag t can you make me another that admins with flag t can use it only and normal players drop it and a text appear "awp is only for vip use" sorry for bad english ty

[Exolent[jNr]]

Are you sure the plugin is running?

[Niksa]

Yes i tried 2 times doesn't work everybody can pick it

[Exolent[jNr]]

Run it again and post the output of these commands while it is running:
rcon meta list
rcon amxx plugins
rcon meta version
rcon version
status