[Doc-Holiday]

For somereason im getting an error on this... not 100% sure why any insight is helpful.

Accessing the array:

PHP Code:

public TargetMenuHandler(Handle:hMenu, MenuAction:iAction, iClient, iItem)
{
    if(iAction == MenuAction_Select)
    {
        decl String:szMenuItem[3];
        GetMenuItem(hMenu, iItem, szMenuItem, sizeof(szMenuItem));
        g_iTarget[iClient] = GetClientOfUserId(StringToInt(szMenuItem));
        
        /* Get Target Info */
        g_iTimeStamp[iClient] = (GetTime() -g_iTimeDifference);
        
        GetArrayString(g_hTargetNames[iClient], g_iTarget[iClient], g_szSafeTargetName, sizeof(g_szSafeTargetName));
        GetArrayString(g_hTargetIP[iClient], g_iTarget[iClient], g_szTargetIP, sizeof(g_szTargetIP));
        GetArrayString(g_hTargetAuthID[iClient], g_iTarget[iClient], g_szTargetAuthID, sizeof(g_szTargetAuthID));
        
        ClearArray(g_hTargetNames[iClient]);
        ClearArray(g_hTargetIP[iClient]);
        ClearArray(g_hTargetAuthID[iClient]);
        
        /* Display Main Menu */
        DisplayMenu(g_hMainMenu, iClient, MENU_TIME_FOREVER);
    }
} 


Declarations:

PHP Code:

/* Target Handlers */
new Handle:g_hTargetNames[MAXPLAYERS+1] = {INVALID_HANDLE, ...};
new Handle:g_hTargetIP[MAXPLAYERS+1] = {INVALID_HANDLE, ...};
new Handle:g_hTargetAuthID[MAXPLAYERS+1] = {INVALID_HANDLE, ...}; 


Where the receive Values:

PHP Code:

stock AddPlayersToMenu(Handle:hMenu, iClient)
{
    decl String:szName[MAX_NAME_LENGTH], String:szSafeName[2 * MAX_NAME_LENGTH + 1], String:szIP[32], String:szAuthID[32], String:szMenuItem[3];
    new iMenuIndex;
    
    if(g_hTargetNames[iClient] == INVALID_HANDLE)
        g_hTargetNames[iClient] = CreateArray(32);
        
    if(g_hTargetIP[iClient] == INVALID_HANDLE)
        g_hTargetIP[iClient] = CreateArray(32);
    
    if(g_hTargetAuthID[iClient] == INVALID_HANDLE)
        g_hTargetAuthID[iClient] = CreateArray(32);
    
    for(new i=1; i<=MaxClients; i++)
    {
        if(IsClientInGame(i) && !IsFakeClient(i))
        {
            GetClientName(i, szName, sizeof(szName));
            ParsePlayerName(szName, szSafeName, sizeof(szSafeName));
            GetClientIP(i, szIP, sizeof(szIP));
            GetClientAuthString(i, szAuthID, sizeof(szAuthID));
            
            iMenuIndex = PushArrayString(g_hTargetNames[iClient], szSafeName);
            PushArrayString(g_hTargetIP[iClient], szIP);
            PushArrayString(g_hTargetAuthID[iClient], szAuthID);
            
            IntToString(iMenuIndex, szMenuItem, sizeof(szMenuItem))
            
            AddMenuItem(hMenu, szMenuItem, szName);
        }
    }
} 


Errors:

E:\Downloads\reporttoforum-beta.sp(769) : error 048: array (s do not match
E:\Downloads\reporttoforum-beta.sp(770) : error 048: array (s do not match
E:\Downloads\reporttoforum-beta.sp(771) : error 048: array (s do not match

[Powerlord]

What are the declarations of g_szSafeTargetName, g_szTargetIP, and g_szTargetAuthID?

[Doc-Holiday]

Originally Posted by Powerlord What are the declarations of g_szSafeTargetName, g_szTargetIP, and g_szTargetAuthID?

PHP Code:

/* Target Variables */
new g_iTarget[MAXPLAYERS+1];
new String:g_szSafeTargetName[MAXPLAYERS+1][MAX_NAME_LENGTH * 2 + 1];
new String:g_szTargetName[MAXPLAYERS+1][MAX_NAME_LENGTH];
new String:g_szTargetAuthID[MAXPLAYERS+1][32];
new String:g_szTargetIP[MAXPLAYERS+1][32];
new g_iTimeStamp[MAXPLAYERS+1]; 


Thanks for that lol... not really sure why i didnt check that... Fixed code below.

PHP Code:

public TargetMenuHandler(Handle:hMenu, MenuAction:iAction, iClient, iItem)
{
    if(iAction == MenuAction_Select)
    {
        decl String:szMenuItem[3];
        GetMenuItem(hMenu, iItem, szMenuItem, sizeof(szMenuItem));
        g_iTarget[iClient] = GetClientOfUserId(StringToInt(szMenuItem));
        
        /* Get Target Info */
        g_iTimeStamp[iClient] = (GetTime() -g_iTimeDifference);
        
        GetArrayString(g_hTargetNames[iClient], g_iTarget[iClient], g_szSafeTargetName[iClient], sizeof(g_szSafeTargetName[]));
        GetArrayString(g_hTargetIP[iClient], g_iTarget[iClient], g_szTargetIP[iClient], sizeof(g_szTargetIP[]));
        GetArrayString(g_hTargetAuthID[iClient], g_iTarget[iClient], g_szTargetAuthID[iClient], sizeof(g_szTargetAuthID[]));
        
        ClearArray(g_hTargetNames[iClient]);
        ClearArray(g_hTargetIP[iClient]);
        ClearArray(g_hTargetAuthID[iClient]);
        
        /* Display Main Menu */
        DisplayMenu(g_hMainMenu, iClient, MENU_TIME_FOREVER);
    }
} 


[friagram]

Not sure how sm calcs array sizes but in c you could just mutiply and index providing you had the cells, i assumed it was the same.