[bogdyuttzu]

I see in CSSDK CAK47::SecondaryAttack but the function is empty. Its posible to hook the function with ham? Ham_Weapon_SecondaryAttack or with orpheu?

[StickP0le]

 RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_ak47", "speed_ak47", 1)

[bogdyuttzu]

I don't want primary attack....

[ConnorMcLeod]

Doesn't work with ham, i think the function doesn't exist but i'm not sure.

You can use Ham_Item_PostFrame and check hold keys, look at this plugin : http://forums.alliedmods.net/showthread.php?p=1158121

[bogdyuttzu]

The function exist but is empty.

[jim_yang]

Yes, the function exist means it can be hooked at least, no matter it is empty or not.
But if the function is never called, then there is no effect when you hook it.

[Devil259]

The thing you can do is to verify if the player press the secondaryattack button and get the ak47, then do something.

[ConnorMcLeod]

Tested and works :

PHP Code:

/*    Formatright © 2011, ConnorMcLeod

    This plugin is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "0.0.3"
#define PLUGIN "Weapons SecondaryAttack Enabler"

const XO_WEAPON = 4
const m_pPlayer = 41
const m_flNextSecondaryAttack = 47

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    const bitNeedToEnableWeapons = 1<<CSW_XM1014 | 1<<CSW_C4 | 1<<CSW_MAC10 | 1<<CSW_ELITE | 1<<CSW_UMP45 | 1<<CSW_GALIL | 1<<CSW_MP5NAVY | 1<<CSW_M249 | 1<<CSW_M3 | 1<<CSW_TMP | 1<<CSW_AK47 | 1<<CSW_P90
    new szWeaponName[32]
    for(new iId = CSW_P228; iId<=CSW_P90; iId++)
    {
        if( bitNeedToEnableWeapons & 1<<iId )
        {
            get_weaponname(iId, szWeaponName, charsmax(szWeaponName))
            RegisterHam(Ham_Item_PostFrame, szWeaponName, "CBasePlayerWeapon_ItemPostFrame", 0)
        }
    }
}

public CBasePlayerWeapon_ItemPostFrame( iEnt )
{
    static id, button

    if(    (button = pev
                            (id = get_pdata_cbase(iEnt, m_pPlayer, XO_WEAPON),
                            pev_button))
            & IN_ATTACK2
    &&    get_pdata_float(iEnt, m_flNextSecondaryAttack, XO_WEAPON) <= 0.0    )
    {
        ExecuteHamB(Ham_Weapon_SecondaryAttack, iEnt)
        // in the hooking plugin you may remove IN_ATTACK from button if you have executed something so PrimaryAttack won't be executed in the same frame
        // you can also set m_flNextAttack > 0.0 so ItemPostFrame will be ignored

        set_pev(id, pev_button, button & ~IN_ATTACK2)
    }
} 


+ Your code in the following plugin :

PHP Code:

#include <amxmodx>
#include <hamsandwich>

#define VERSION "0.0.1"
#define PLUGIN ""

const XO_WEAPON = 4
const m_pPlayer = 41

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_ak47", "CAK47_SecondaryAttack")
}

public CAK47_SecondaryAttack( iEnt )
{
    new id = get_pdata_cbase(iEnt, m_pPlayer, XO_WEAPON)
    client_print(id, print_center, "AK SecondaryAttack !!")
} 


Plugin example :

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "0.0.1"
#define PLUGIN "FlashLight On Secondary Attack"

const XO_WEAPON = 4
const m_pPlayer = 41
const m_flNextSecondaryAttack = 47

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    const bitFreeSecondaryAttackWeapons = 1<<CSW_XM1014 | 1<<CSW_C4 | 1<<CSW_MAC10 | 1<<CSW_ELITE | 1<<CSW_UMP45 | 1<<CSW_GALIL | 1<<CSW_MP5NAVY | 1<<CSW_M249 | 1<<CSW_M3 | 1<<CSW_TMP | 1<<CSW_AK47 | 1<<CSW_P90
    new szWeaponName[32]
    for(new iId = CSW_P228; iId<=CSW_P90; iId++)
    {
        if( bitFreeSecondaryAttackWeapons & 1<<iId )
        {
            get_weaponname(iId, szWeaponName, charsmax(szWeaponName))
            RegisterHam(Ham_Weapon_SecondaryAttack, szWeaponName, "MWeaponsWeapons_SecondaryAttack", 0)
        }
    }
}

public MWeaponsWeapons_SecondaryAttack( iWeapon )
{
    new id = get_pdata_cbase(iWeapon, m_pPlayer, XO_WEAPON)
    set_pev(id, pev_impulse, 100)
    set_pdata_float(iWeapon, m_flNextSecondaryAttack, 0.4)
} 


[bogdyuttzu]

Thanks Connor