[taski]

Having an odd issue with entity disappearing on seemingly random, but consistent parts of the map depending on where the observer is. Not sure what's causing it as I haven't worked with entities in this game that much. I've tried a few different methods of creating the entity, different rendermodes and perhaps other things. All seems to have this same effect.

In some maps like dust2 and nuke the entity doesn't actually appear at all.
On a bigger map it does appear but disappears once the observer walks into seemingly random parts of the map, so clearly something is not right.

Here's the function where entity in question is being created:

Spoiler

PHP Code:

stock createThink()
{
    /* createThink()

    - parameters : ( )
    - description : creates an entity that runs recorded paths back and forth, called on mapstart
    - return : -
    */

    // new ent = create_entity("info_player_deathmatch");
    new ent = engfunc( EngFunc_CreateNamedEntity,engfunc( EngFunc_AllocString, "info_target") );

    if(!ent) {
        log_amx("Failed to create think entity");
        return; 
    }
  
    entity_set_model(ent, BOT_MODEL);     
    new Float:maxs[3] = {16.0, 16.0, 36.0};
    new Float:mins[3] = {-16.0, -16.0, -36.0};

    engfunc(EngFunc_SetSize, ent, mins, maxs); 

    set_pev(ent, pev_solid, SOLID_NOT);
    set_pev(ent, pev_scale, 0.5);
    set_pev(ent, pev_renderfx, kRenderFxDistort);
    set_pev(ent, pev_frame, 0.0);
    set_pev(ent, pev_rendermode, kRenderFxDistort);
    set_pev(ent, pev_renderamt, 0);

    pathLoopEntity = ent;
    //log_amx("Think created OK, ID: %i", ent);
    set_pev(ent, pev_classname, "path_visuals");
    set_pev( ent, pev_nextthink, get_gametime() + 0.1 ); 
} 


And here's the thinking function where the entity being moved frame by frame

Spoiler

PHP Code:

public _entityThink(ent)
{
    /* _entityThink()

    - parameters : ( [int] entity ID )
    - description : processes path movement for created entity 
    - return : -
    */

    if( !pev_valid(ent) ) return FMRES_IGNORED;

    if(ent == pathLoopEntity)
    {
        set_pev(ent, pev_nextthink, get_gametime() );

        // multiplier skips frames so it speeds up the entity 
        static multiplier = 3;
        new len = ArraySize(movementArray);

        if(len <= 0) return FMRES_IGNORED;
        
        if( pathLoopEntityFrame < ArraySize(movementArray) && pathLoopEntityFrame >= 0 ) 
        {
            static frameArray[enumMovement];
            ArrayGetArray(movementArray, pathLoopEntityFrame, frameArray);
            set_pev( ent, pev_origin, frameArray[REC_POS] ); 

            client_print(0, print_center, "DEBUG %.2f , %.2f , %.2f - (ID %i)", 
            frameArray[REC_POS][0], frameArray[REC_POS][1], frameArray[REC_POS][2], ent);

            beam(ent);
            if(!goBackwards) pathLoopEntityFrame += multiplier;
            else pathLoopEntityFrame -= multiplier;
        }
        else 
        {
            if(!goBackwards)
            {
                pathLoopEntityFrame -= multiplier;
                goBackwards = true; 
            } else {
                pathLoopEntityFrame += multiplier;
                goBackwards = false; 
            }
        }
    }
    return FMRES_IGNORED;
} 


Sort of similar post was created a week ago (nothing much to see):
https://forums.alliedmods.net/showthread.php?t=346159

Made an attempt to scout some other threads, couldn't quite find anything similar.

[Phant]

Did you tried to use "cycler_sprite" instead of "info_target"?

[georgik57]

Try using what phant said or env_sprite. Don't set any rendering or scaling options.
IMO try removing this completely and see what happens and also try to spawn entity with dllfunc_spawn:

PHP Code:

set_pev(ent, pev_solid, SOLID_NOT);
    set_pev(ent, pev_scale, 0.5);
    set_pev(ent, pev_renderfx, kRenderFxDistort);
    set_pev(ent, pev_frame, 0.0);
    set_pev(ent, pev_rendermode, kRenderFxDistort);
    set_pev(ent, pev_renderamt, 0); 


[taski]

Originally Posted by Phant Did you tried to use "cycler_sprite" instead of "info_target"?

Now I have. That just makes it really laggy, and the same issue persists

Originally Posted by georgik57 Try using what phant said or env_sprite. Don't set any rendering or scaling options. IMO try removing this completely and see what happens and also try to spawn entity with dllfunc_spawn: PHP Code: set_pev(ent, pev_solid, SOLID_NOT);     set_pev(ent, pev_scale, 0.5);     set_pev(ent, pev_renderfx, kRenderFxDistort);     set_pev(ent, pev_frame, 0.0);     set_pev(ent, pev_rendermode, kRenderFxDistort);     set_pev(ent, pev_renderamt, 0);

Thanks for the replies, already tried both of these. Whether there was rendering / scaling, DLLFunc_Spawn / DispatchSpawn or not, it makes no difference.
However, looking at hlsdk_const.inc, this was fixed by just setting movetype to 10, it seems to be 0 by default (NONE). I tried 12 before (FOLLOW) and that had the same problem.

But MOVETYPE_BOUNCE fixes this. If you get some unwanted bouncing, MOVETYPE_FLY also works.
If anyone has this problem you can fiddle with different movetypes to see what suits you.

Spoiler

PHP Code:

#define    MOVETYPE_NONE                   0           // Never moves
#define    MOVETYPE_WALK                   3           // Player only - moving on the ground
#define    MOVETYPE_STEP                   4           // Gravity, special edge handling -- monsters use this
#define    MOVETYPE_FLY                    5           // No gravity, but still collides with stuff
#define    MOVETYPE_TOSS                   6           // Gravity/Collisions
#define    MOVETYPE_PUSH                   7           // No clip to world, push and crush
#define    MOVETYPE_NOCLIP                 8           // No gravity, no collisions, still do velocity/avelocity
#define    MOVETYPE_FLYMISSILE             9           // Extra size to monsters
#define    MOVETYPE_BOUNCE                 10          // Just like Toss, but reflect velocity when contacting surfaces
#define MOVETYPE_BOUNCEMISSILE          11          // Bounce w/o gravity
#define MOVETYPE_FOLLOW                 12          // Track movement of aiment
#define    MOVETYPE_PUSHSTEP               13          // BSP model that needs physics/world collisions (uses nearest hull for world collision) 


Here's the working function:

Spoiler

PHP Code:

stock createThink()
{
    /* createThink()

    - parameters : ( )
    - description : creates an entity that runs recorded paths back and forth, called on mapstart
    - return : -
    */

    new ent = create_entity("info_player_deathmatch");
    // new ent = engfunc( EngFunc_CreateNamedEntity,engfunc( EngFunc_AllocString, "cycler_sprite") );

    if(!ent) {
        log_amx("Failed to create think entity");
        return; 
    }
  
    entity_set_model(ent, BOT_MODEL);     
    new Float:maxs[3] = {16.0, 16.0, 36.0};
    new Float:mins[3] = {-16.0, -16.0, -36.0};
    engfunc(EngFunc_SetSize, ent, mins, maxs); 

    log_amx("Entity %i default movetype: %i", ent, entity_get_int(ent, 14));

    // Not necessary
    set_pev(ent, pev_solid, SOLID_NOT);
    set_pev(ent, pev_scale, 0.5);
    set_pev(ent, pev_renderfx, kRenderFxDistort);
    set_pev(ent, pev_frame, 0.0);
    set_pev(ent, pev_rendermode, kRenderFxDistort);
    set_pev(ent, pev_renderamt, 0);

    // Necessary to fix invisibility 
    set_pev(ent, pev_movetype, MOVETYPE_BOUNCE);
    log_amx("Entity %i new movetype: %i", ent, entity_get_int(ent, 14));

    pathLoopEntity = ent;
    //log_amx("Think created OK, ID: %i", ent);
    set_pev(ent, pev_classname, "path_visuals");
    set_pev( ent, pev_nextthink, get_gametime() + 0.1 ); 
}