[ghost95v]

Hello, i really would like make this: if a player Buy Survivor and he already has a Jetpack, automatically drop his Jetpack & if is possible to remove jetpack so the survivor cant pickup again.

im using ZPA , and this Jetpack code

PHP Code:

#include < amxmodx >
#include < engine >
#include < fakemeta >
#include < hamsandwich >
#include < xs >
#include < zombie_plague_advance >

native get_user_jetpack( iPlayer );
native user_drop_jetpack( iPlayer );
native set_user_fuel( iPlayer, Float: fFuel );
native set_user_rocket_time( iPlayer, Float: fTime );
native set_user_jetpack( iPlayer, iJetpack );

new g_iJetpack, gmsgSayText, bool: g_bConnected[ 33 ], g_cName[ 33 ][ 32 ];


public zp_user_infect_attempt( iPlayer )
    if( get_user_jetpack( iPlayer ) )
        user_drop_jetpack( iPlayer );

public zp_user_infected_pre( iPlayer )
    if( get_user_jetpack( iPlayer ) )
        user_drop_jetpack( iPlayer );

public zp_user_infected_post( iPlayer )
    if( get_user_jetpack( iPlayer ) )
        user_drop_jetpack( iPlayer );

public client_putinserver( iPlayer )
{
    g_bConnected[ iPlayer ] = true;

    get_user_name( iPlayer, g_cName[ iPlayer ], 31 );
}

public client_disconnect( iPlayer )
    g_bConnected[ iPlayer ] = false;

public client_infochanged( iPlayer )
{
    static cInfo[ 32 ];
    get_user_info( iPlayer, "name", cInfo, 31 );

    if( !equali( g_cName[ iPlayer ], cInfo ) )
        copy( g_cName[ iPlayer ], 31, cInfo );
}

public plugin_init( )
{
    g_iJetpack = zp_register_extra_item( "Jetpack + Bazooka", 30, ZP_TEAM_HUMAN );
    gmsgSayText = get_user_msgid( "SayText" );
    register_logevent( "RoundStart", 2, "1=Round_Start" );
    
}

public zp_extra_item_selected( iPlayer, iItem )
{
    if( iItem == g_iJetpack )
    {
        if( get_user_jetpack( iPlayer ) )
        {
            DoSayTextMessage( iPlayer, "^x04[ZP]^x01 You already have a^x03 Jetpack!" );

            zp_set_user_ammo_packs( iPlayer, zp_get_user_ammo_packs( iPlayer ) + 30 );
        }

        else
        {
            set_user_jetpack( iPlayer, 1 );
            set_user_fuel( iPlayer, 250.0 );

            DoSayTextMessage( iPlayer, "^x04[ZP]^x01 Press^x03 CTRL+SPACE^x01 to fly!" );
            DoSayTextMessage( iPlayer, "^x04[ZP]^x01 Press^x03 RIGHT CLICK^x01 to shoot!" );
            
            
        }
    }
}

public Rocket_Touch( iOwner, iRocket )
{
    if( g_bConnected[ iOwner ] )
    {
        static iPlayers[ 32 ], iNum, i;
        get_players( iPlayers, iNum, "a" );

        for( i = 0; i < iNum; i++ )
        {
            if( zp_get_user_zombie( iPlayers[ i ] ) )
            {
                static Float: fDistance, Float: fDamage;
                fDistance = entity_range( iPlayers[ i ], iRocket );

                if( fDistance < 320.0 )
                {
                    fDamage = 1050.0 - fDistance;
                
                    static Float: fVelocity[ 3 ];
                    pev( iPlayers[ i ], pev_velocity, fVelocity );
                    xs_vec_mul_scalar( fVelocity, 2.75, fVelocity );
                    fVelocity[ 2 ] *= 1.75;
                    set_pev( iPlayers[ i ], pev_velocity, fVelocity );
                    
                    if( float( get_user_health( iPlayers[ i ] ) ) - fDamage > 0.0 )
                        ExecuteHamB( Ham_TakeDamage, iPlayers[ i ], iRocket, iOwner, fDamage, DMG_BLAST );
                        
                    else ExecuteHamB( Ham_Killed, iPlayers[ i ], iOwner, 2 );


                    DoSayTextMessage( iOwner, "^x04[ZP]^x01 Damage to^x04 %s^x01 ::^x04 %0.0f^x01 damage", g_cName[ iPlayers[ i ] ], fDamage );
                }
            }
        }
    }
}

public Jetpack_Touch( iPlayer )
    return zp_get_user_zombie( iPlayer ) ? PLUGIN_HANDLED : PLUGIN_CONTINUE;

public RoundStart( )
{
    static iPlayers[ 32 ], iNum, i;
    get_players( iPlayers, iNum, "a" );

    for( i = 0; i < iNum; i++ )
        if( get_user_jetpack( iPlayers[ i ] ) )
        set_user_rocket_time( iPlayers[ i ], 0.0 );
}

DoSayTextMessage( iTarget, cMessage[ ], any: ... )
{
    static cBuffer[ 192 ];
    vformat( cBuffer, 191, cMessage, 3 );

    message_begin( MSG_ONE_UNRELIABLE, gmsgSayText, _, iTarget );
    write_byte( iTarget );
    write_string( cBuffer );
    message_end( );
} 


[zmd94]

Just try to put this code:

PHP Code:

public zp_user_humanized_pre( iPlayer )
    if( get_user_jetpack( iPlayer ) )
        user_drop_jetpack( iPlayer ); 


[ghost95v]

Originally Posted by zmd94 Just try to put this code: PHP Code: public zp_user_humanized_pre( iPlayer )     if( get_user_jetpack( iPlayer ) )         user_drop_jetpack( iPlayer );

Works ...But... this is Dropin jetpack and when is Armagddon round , or Plague round ... i would like to make to drop , when its only Survivor
, how can we , add a check , if is armageddon round, and plague round , to do not drop jetpack ?

[ghost95v]

I solved a check if is Armageddone round, Survivors not drop Jetpack .. but , how can we make, for plague round too ,,, and , how to block pick up by survivor, when survivor try to pickup one in , ground

i added check to dont not drop, when its lnj_round.

PHP Code:

public zp_user_humanized_pre( iPlayer )
    if( get_user_jetpack( iPlayer ) )
    if( zp_is_lnj_round () )
        return;
    else
    user_drop_jetpack( iPlayer ); 


[zmd94]

Just try to change this:

PHP Code:

public Jetpack_Touch( iPlayer )
    return zp_get_user_zombie( iPlayer ) ? PLUGIN_HANDLED : PLUGIN_CONTINUE; 


--->

PHP Code:

public Jetpack_Touch( iPlayer )
{
    if (zp_get_user_zombie( iPlayer ))
        return PLUGIN_HANDLED;
        
    if (zp_get_user_survivor( iPlayer ))
        return PLUGIN_HANDLED;
        
    return PLUGIN_CONTINUE;
} 


[ghost95v]

not works, Still, Survivor can pickup the jetpack , and zombies too LOL

[zmd94]

Just try again. I have updated the code. ;)

[ghost95v]

Originally Posted by zmd94 Just try again. I have updated the code. ;)

Thank you , works perfectly ... but, how to add a check for "Plague round" too, to do not drop jetpacks, of survivors ? i added only lnj_round.

PHP Code:

public zp_user_humanized_pre( iPlayer )
    if( get_user_jetpack( iPlayer ) )
    if( zp_is_lnj_round () )
        return;
    else
    user_drop_jetpack( iPlayer ); 


[zmd94]

Just try this code:

PHP Code:

public zp_user_humanized_pre( iPlayer )
{
    if( get_user_jetpack( iPlayer ) )
    {
        if( !zp_is_lnj_round () && !zp_is_plague_round())
        {
            user_drop_jetpack( iPlayer ); 
        }
    }
} 


[ghost95v]

yes, thnx man. i was already done that, like this "if( zp_is_lnj_round () || zp_is_plague_round () )" .


Sorry, another question, about pickup.(we prevent surv pickup jetpack whole round). Exist a way to make Survivor to pickup the jetpack in round end ? (ex. to pickup, after the message "Win no one"etc... htis happens, event round_end, or zp_round_ended , i think )