[Aooka]

Voilà j'ai fais un petit plugin hier et aujourd'hui et il ne marche pas vraiment ... Même pas du tout il fait crash le serveur où je le met et rien ne se marque dans les logs du serveurs donc : Problème.

Voici le code que j'ai écris :

Spoiler

#include < amxmodx >
#include < engine >

new g_iMenu , g_iMenuStop;
new bool: g_bHas3dView[ 33 ];

public plugin_init( )
{
    register_plugin( "3D view cmd" , "1.0" , "Aooka" );
    
    register_clcmd( "say /3d" , "ClientCommand_View" );
    register_clcmd( "say_team /3d" , "ClientCommand_View" );
    
    register_clcmd( "say /stop3d" , "ClientCommand_StopView" );
    register_clcmd( "say_team /stop3d" , "ClientCommand_StopView" );
    
    g_iMenu = menu_create( "# Player in 3D view ?" , "handlerView" );
    menu_additem( g_iMenu , "Yes sure" );
    menu_additem( g_iMenu , "No thanks" );
    
    g_iMenuStop = menu_create( "# Remove 3D view ?" , "handlerStopView" );
    menu_additem( g_iMenuStop , "Yes i want" );
    menu_additem( g_iMenuStop , "No lol" );
}

public client_connect( id ) g_bHas3dView[ id ] = false;

public client_disconnect( id ) g_bHas3dView[ id ] = false;

public ClientCommand_View( const id )
{
    if( is_user_alive( id ) && g_bHas3dView[ id ] == false )
    {
        menu_display( id , g_iMenu );
    }
    
    else client_print( id , print_chat , "You have already a 3D view !" );
}

public handlerView( const id , const g_iMenu , const item )
{
    switch( item )
    {
        case 0:
        {
            g_bHas3dView[ id ] = true;
            
            set_view( id , CAMERA_3RDPERSON );
            client_print( id , print_chat , "You see now your player in 3D !" );
        }
        
        case 1:
        {
            g_bHas3dView[ id ] = false;
            
            client_print( id , print_chat , "You do not see your player in 3D !" );
        }
    }
    return 0;
}

public ClientCommand_StopView( const id )
{
    if( is_user_alive( id ) )
        if( g_bHas3dView[ id ] )
            menu_display( id , g_iMenuStop );
        
        else client_print( id , print_chat , "You do not have a 3D view !" );
    
    else client_print( id , print_chat , "You must be alive !" );
}

public handlerStopView( const id , const g_iMenuStop , const item )
{
    switch( item )
    {
        case 0:
        {
            g_bHas3dView[ id ] = false;
            
            set_view( id , CAMERA_NONE );
            client_print( id , print_chat , "You remove the 3D view !" );
        }
        case 1:
            return 1;
    }
    return 0;
}

Voilà du coup je ne vois pas trop comment faire pour résoudre ce problème... Merci bien

Edit1: Après quelques recherche j'ai trouve ceci :

precache_model( "models/rpgrocket.mdl" );

Mais je n'ai pas trouvé le model qui va avec

[ConnorMcLeod]

Il existe par défaut, ne t'en occuppe pas, il faut juste le précacher.

[Aooka]

Merci bien, je vais allé essayé sa

[Aooka]

Alors j'ai testé et sa marche du tonnerre. Seul point noire si puis-je dire ^^ c'est que mon joueur je le vois semi invisible et pas "normalement". Voici un screen que je vous ais fais :

Spoiler

[R@pid0]

Je ne savais pas que sa existais c'est super sa dit donc.

Par contre le semi invisible est obligatoire ou existe t'il une technique pour voir correctement le joueur ?

Et Cela marche t'il bien avec les armes ?

Merci

[micapat]

La semi-invisibilité est codée dans le module engine directement.

PHP Code:

int AddToFullPack(struct entity_state_s *state, int e, edict_t *ent, edict_t *host, int hostflags, int player, unsigned char *pSet)
{
    if(ent == host) {
        if(FStrEq(STRING(ent->v.classname), "player")) {
            if(plinfo[ENTINDEX(ent)].iViewType != CAMERA_NONE) {
                ent->v.rendermode = kRenderTransTexture;
                ent->v.renderamt = 100;
                RETURN_META_VALUE(MRES_IGNORED, 0);
            }
        }
    }

    if(FStrEq(STRING(ent->v.classname), "player")) {
        if(plinfo[ENTINDEX(ent)].iViewType != CAMERA_NONE) {
            ent->v.rendermode = plinfo[ENTINDEX(ent)].iRenderMode;
            ent->v.renderamt = plinfo[ENTINDEX(ent)].fRenderAmt;
        }
    }

    RETURN_META_VALUE(MRES_IGNORED, 0);
} 


[bboygrun]

Originally Posted by R@pid0 Par contre le semi invisible est obligatoire ou existe t'il une technique pour voir correctement le joueur ?

Oui c'est possible, tient :

PHP Code:

#include < amxmodx >
#include < engine >
#include < fakemeta >

new g_iMenu , g_iMenuStop;
new bool: g_bHas3dView[ 33 ];

public plugin_init( )
{
    register_plugin( "3D view cmd" , "1.0" , "Aooka" );
    
    register_clcmd( "say /3d" , "ClientCommand_View" );
    register_clcmd( "say_team /3d" , "ClientCommand_View" );
    
    register_clcmd( "say /stop3d" , "ClientCommand_StopView" );
    register_clcmd( "say_team /stop3d" , "ClientCommand_StopView" );
    
    register_forward( FM_AddToFullPack, "fwAddToFullPack", true );
    
    g_iMenu = menu_create( "# Player in 3D view ?" , "handlerView" );
    menu_additem( g_iMenu , "Yes sure" );
    menu_additem( g_iMenu , "No thanks" );
    
    g_iMenuStop = menu_create( "# Remove 3D view ?" , "handlerStopView" );
    menu_additem( g_iMenuStop , "Yes i want" );
    menu_additem( g_iMenuStop , "No lol" );
}

public plugin_precache( ) precache_model( "models/rpgrocket.mdl" );

public client_connect( id ) g_bHas3dView[ id ] = false;

public client_disconnect( id ) g_bHas3dView[ id ] = false;

public ClientCommand_View( const id )
{
    if( is_user_alive( id ) && g_bHas3dView[ id ] == false )
    {
        menu_display( id , g_iMenu );
    }
    
    else client_print( id , print_chat , "You have already a 3D view !" );
}

public handlerView( const id , const g_iMenu , const item )
{
    switch( item )
    {
        case 0:
        {
            g_bHas3dView[ id ] = true;
            
            set_view( id , CAMERA_3RDPERSON );
            client_print( id , print_chat , "You see now your player in 3D !" );
        }
        
        case 1:
        {
            g_bHas3dView[ id ] = false;
            
            client_print( id , print_chat , "You do not see your player in 3D !" );
        }
    }
    return 0;
}

public ClientCommand_StopView( const id )
{
    if( is_user_alive( id ) )
        if( g_bHas3dView[ id ] )
            menu_display( id , g_iMenuStop );
        
        else client_print( id , print_chat , "You do not have a 3D view !" );
    
    else client_print( id , print_chat , "You must be alive !" );
}

public handlerStopView( const id , const g_iMenuStop , const item )
{
    switch( item )
    {
        case 0:
        {
            g_bHas3dView[ id ] = false;
            
            set_view( id , CAMERA_NONE );
            client_print( id , print_chat , "You remove the 3D view !" );
        }
        case 1:
            return 1;
    }
    return 0;
}

public fwAddToFullPack( const es, const e, const ent, const host, const host_flags, const player, const p_set )
{
    if( player && g_bHas3dView[ ent ] )
    {
        set_es( es, ES_RenderMode, kRenderNormal );
    }
} 


[Aooka]

Merci bien Bboy.
Par contre juste je suis allé voir vite fait les différens forward et je suis donc tombé sur sa :

FM_AddToFullPack,		// int )	(entState, e, ent, host, iHostFlags, iPlayer, pSet)

Et je me demandais pourquoi as-tu utiliser ce forward au lieu d'un autre car la description de ce dernier est très restreinte. Il y en a plein qui se ressemble. Comment bien choisir son forward en fait ?

Bon après c'est sur y'en a c'est logique du style FM_Spawn etc mais y'en a ...

[ConnorMcLeod]

/*
AddToFullPack

Return 1 if the entity state has been filled in for the ent and the entity will be propagated to the client, 0 otherwise

state is the server maintained copy of the state info that is transmitted to the client
a MOD could alter values copied into state to send the "host" a different look for a particular entity update, etc.
e and ent are the entity that is being added to the update, if 1 is returned
host is the player's edict of the player whom we are sending the update to
player is 1 if the ent/e is a player and 0 otherwise
pSet is either the PAS or PVS that we previous set up.  We can use it to ask the engine to filter the entity against the PAS or PVS.
we could also use the pas/ pvs that we set in SetupVisibility, if we wanted to.  Caching the value is valid in that case, but still only for the current frame
*/
int AddToFullPack( struct entity_state_s *state, int e, edict_t *ent, edict_t *host, int hostflags, int player, unsigned char *pSet )

Parce que c'est dans ce forward que le module engine fait croire au joueur qu'il est semi invisible, donc on intervient après le module engine et on remet les choses à leurs places.
Maintenant l'autre question est pourquoi le module engine intervient-il dans cette fonction ?
Cette fonction sert à envoyer au joueur toutes les informations concernant les entités (joueurs et autres), en altérant certaines valeur, on peut faire apparaitre une entité différemment à 2 joueurs différents, ou ne pas faire apparaître du tout certaines entités à certains joueurs.
Les informations reçues par les joueurs servent à mettre à jour tout ce qui est visuel, mais aussi à prédire les movements (collisions).

[Aooka]

Merci beaucoup Connor je vais lire sa !

J'ai regardé par ici http://www.amxmodx.org/funcwiki.php?go=inc&id=31 et aussi par là : http://www.amxmodx.org/funcwiki.php?...id=16#const_fm mais je ne trouve aucune description telle que la tienne.
J'aimerais juste savoir où as-tu trouvé une telle description ?

Merci