[klippy]

"static" on global variables (and functions) means their scope is restricted to file scope, meaning you can't use them outside of the file that declared them.

Also, seeing that locals in that function take only 16 bytes, I'm sure there's something else that's wrong.
Does it happen every time that function gets called or is it random? What is g_iPlayerTeam? You are missing many things that the posted code references.

You should cut your plugin to the minimum possible amount of code that's able to reproduce that issue so we can test it out.

[edon1337]

Originally Posted by KliPPy "static" on global variables (and functions) means their scope is restricted to file scope, meaning you can't use them outside of the file that declared them. Also, seeing that locals in that function take only 16 bytes, I'm sure there's something else that's wrong. Does it happen every time that function gets called or is it random? What is g_iPlayerTeam? You are missing many things that the posted code references. You should cut your plugin to the minimum possible amount of code that's able to reproduce that issue so we can test it out.

It happens randomly, but says it happens in Ham_Spawn, which can't be, because Ham_Spawn is called just at player spawn.

g_iPlayerTeam is an array used for new player teams

PHP Code:

#define MAX_PLAYERS 32

static Float:g_fTeamGlow[ MAX_PLAYERS + 1 ][ 3 ];

new g_iPlayerTeam[ MAX_PLAYERS + 1 ];

public fw_HamSpawnPost( id )
{
    if( g_iPlayerTeam[ id ] != NO_TEAM )
    {
        new Float:fRender[ 3 ];
        pev( id, pev_rendercolor, fRender );

        new iTeam = g_iPlayerTeam[ id ];
        
        if( ( fRender[ 0 ] != g_fTeamGlow[ iTeam ][ 0 ] ) || ( fRender[ 1 ] != g_fTeamGlow[ iTeam ][ 1 ] ) || ( fRender[ 2 ] != g_fTeamGlow[ iTeam ][ 2 ] ) )
        {
            set_user_rendering( id, kRenderFxGlowShell, floatround( g_fTeamGlow[ iTeam ][ 0 ] ), floatround( g_fTeamGlow[ iTeam ][ 1 ] ), floatround( g_fTeamGlow[ iTeam ][ 2 ] ), kRenderNormal, 30 );
        }
    }
    return HAM_IGNORED;
}

public OnNewRound( )
{
    for( new iTeam=1; iTeam <= g_iMaxTeams; iTeam++ )
    {
        g_fTeamGlow[ iTeam ][ 0 ] = random_float( 0.0, 255.0 );
        g_fTeamGlow[ iTeam ][ 1 ] = random_float( 0.0, 255.0 );
        g_fTeamGlow[ iTeam ][ 2 ] = random_float( 0.0, 255.0 );
    }

    new szPlayers[ 32 ], iNum;
    get_players( szPlayers, iNum, "a" );

    static iTempID;
    for( new i; i < iNum; i++ )
    {
        iTempID = szPlayers[ i ];
        
        set_user_rendering( iTempID, kRenderFxGlowShell, floatround( g_fTeamGlow[ g_iPlayerTeam[ iTempID ] ][ 0 ] ), floatround( g_fTeamGlow[ g_iPlayerTeam[ iTempID ] ][ 1 ] ), floatround( g_fTeamGlow[ g_iPlayerTeam[ iTempID ] ][ 2 ] ), kRenderNormal, 30 );
        
        if( g_iPlayerTeam[ iTempID ] == NO_TEAM && get_user_team( iTempID ) != 3 )
        {
            FindAvailableTeam( iTempID );
        }
    }
}

FindAvailableTeam( id )
{
    for( new iTeam=1; iTeam <= g_iMaxTeams; iTeam++ )
    {
        if( IsTeamAvailable( iTeam ) )
        {
            g_iPlayerTeam[ id ] = iTeam;
            g_iTeammates[ iTeam ]++;
            
            break;
        }
        continue;
    }
}

IsTeamAvailable( iTeam )
{
    return g_iTeammates[ iTeam ] < g_iPlayerPerTeam ? 1 : 0;
} 


[Clauu]

Regarding your case there is no point using static for Float:g_fTeamGlow
Leave it static only for Float:fRender[ 3 ], iTeam and maybe szPlayers[ 32 ], iNum depending how often that function will be called.

if( ( fRender[ 0 ] != g_fTeamGlow[ iTeam ][ 0 ] ) || ( fRender[ 1 ] != g_fTeamGlow[ iTeam ][ 1 ] ) || ( fRender[ 2 ] != g_fTeamGlow[ iTeam ][ 2 ] ) )

Are you sure that this is line 124?

[klippy]

You should cut your plugin to the minimum possible amount of code that's able to reproduce that issue so we can test it out.

[edon1337]

What I posted before was the literal minimum code.

PHP Code:

#include < amxmodx >
#include < hamsandwich >
#include < fakemeta >
#include < fun >

#define MAX_PLAYERS 32
#define NO_TEAM 0

new g_iPlayerPerTeam;
new g_iMaxTeams;

new g_iTeammates[ MAX_PLAYERS + 1 ];
new g_iPlayerTeam[ MAX_PLAYERS + 1 ];

new Float:g_fTeamGlow[ MAX_PLAYERS + 1 ][ 3 ];

new HamHook:g_iHamTakeDamageFw;

public plugin_init( )
{
    register_plugin( "CS Battle Royale Fake Teams", "1.0", "DoNii" );
    
    register_event( "HLTV", "OnNewRound", "a", "1=0", "2=0" ) ;
    
    RegisterHam( Ham_TakeDamage, "player", "fw_HamSpawnPost", 1 );
    
    g_iHamTakeDamageFw = RegisterHam( Ham_TakeDamage, "player", "fw_HamTakeDamagePre", 0 );
    DisableHamForward( g_iHamTakeDamageFw );
}

public plugin_cfg( )
{
    EnableHamForward( g_iHamTakeDamageFw );
}

public client_disconnect( id )
{
    if( g_iPlayerTeam[ id ] != NO_TEAM )
    {
        g_iTeammates[ g_iPlayerTeam[ id ] ]--;
        g_iPlayerTeam[ id ] = NO_TEAM;
    }
    g_iPlayerTeam[ id ] = NO_TEAM;
}

public client_connect( id )
{
    g_iPlayerTeam[ id ] = NO_TEAM;
    FindAvailableTeam( id );
}

public fw_HamSpawnPost( id )
{
    if( ! is_user_alive( id ) )
    return HAM_IGNORED;

    if( g_iPlayerTeam[ id ] != NO_TEAM )
    {
        static Float:fRender[ 3 ];
        pev( id, pev_rendercolor, fRender );

        static iTeam;
        iTeam = g_iPlayerTeam[ id ];
        
        if( ( fRender[ 0 ] != g_fTeamGlow[ iTeam ][ 0 ] ) || ( fRender[ 1 ] != g_fTeamGlow[ iTeam ][ 1 ] ) || ( fRender[ 2 ] != g_fTeamGlow[ iTeam ][ 2 ] ) )
        {
            set_user_rendering( id, kRenderFxGlowShell, floatround( g_fTeamGlow[ iTeam ][ 0 ] ), floatround( g_fTeamGlow[ iTeam ][ 1 ] ), floatround( g_fTeamGlow[ iTeam ][ 2 ] ), kRenderNormal, 30 );
        }
    }
    return HAM_IGNORED;
}

public fw_HamTakeDamagePre( iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits )
{    
    if( iVictim == iAttacker )
    return HAM_IGNORED;

    if( g_iPlayerTeam[ iVictim ] != g_iPlayerTeam[ iAttacker ] )
    {
        ExecuteHamB( Ham_TakeDamage, iVictim, iInflictor, iAttacker, fDamage, iDamageBits );
    }
    return HAM_SUPERCEDE;
}

public OnNewRound( )
{
    for( new iTeam=1; iTeam <= g_iMaxTeams; iTeam++ )
    {
        g_fTeamGlow[ iTeam ][ 0 ] = random_float( 0.0, 255.0 );
        g_fTeamGlow[ iTeam ][ 1 ] = random_float( 0.0, 255.0 );
        g_fTeamGlow[ iTeam ][ 2 ] = random_float( 0.0, 255.0 );
    }

    static szPlayers[ 32 ], iNum;
    get_players( szPlayers, iNum, "a" );

    static iTempID;
    for( new i; i < iNum; i++ )
    {
        iTempID = szPlayers[ i ];
        
        set_user_rendering( iTempID, kRenderFxGlowShell, floatround( g_fTeamGlow[ g_iPlayerTeam[ iTempID ] ][ 0 ] ), floatround( g_fTeamGlow[ g_iPlayerTeam[ iTempID ] ][ 1 ] ), floatround( g_fTeamGlow[ g_iPlayerTeam[ iTempID ] ][ 2 ] ), kRenderNormal, 30 );
        
        if( g_iPlayerTeam[ iTempID ] == NO_TEAM && ( get_user_team( iTempID ) == 1 || get_user_team( iTempID ) == 2 ) )
        {
            FindAvailableTeam( iTempID );
        }
    }
}

FindAvailableTeam( id )
{
    for( new iTeam=1; iTeam <= g_iMaxTeams; iTeam++ )
    {
        if( IsTeamAvailable( iTeam ) )
        {
            g_iPlayerTeam[ id ] = iTeam;
            g_iTeammates[ iTeam ]++;
            
            break;
        }
        continue;
    }
}

IsTeamAvailable( iTeam )
{
    return g_iTeammates[ iTeam ] < g_iPlayerPerTeam ? 1 : 0;
} 


Fun fact it's not even showing me the line where the error is anymore, I realised it happens when I shoot at someone, but not sure whether that's the issue, I see nothing wrong with Ham_TakeDamage.

L 02/26/2018 - 01:14:20: [AMXX] Displaying debug trace (plugin "CsBattleRoyaleFakeTeams.amxx") L 02/26/2018 - 01:14:20: [AMXX] Run time error 3: stack error

[Th3822]

It looks like the issue is the recursion on the Ham_TakeDamage hook
it seems that you are trying to block damage incorrectly and in that code you call Ham_TakeDamage again with ExecuteHamB, so it does call all plugin's Ham_TakeDamage hooks again, repeating over and over again...

There is a warning about that on the .inc:

Originally Posted by hamsandwich.inc /** * Executes the virtual function on the entity, this will trigger all hooks on that function. * Be very careful about recursion! * Look at the Ham enum for parameter lists. * * @param function The function to call. * @param id The id of the entity to execute it on. */ native ExecuteHamB(Ham:function, this, any:...);

after looking at your code, there is no reason to calling Ham_TakeDamage again just to "allow" the damage, try using this:

PHP Code:

public fw_HamTakeDamagePre( iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits )
{
    if ( iVictim != iAttacker && g_iPlayerTeam[ iVictim ] == g_iPlayerTeam[ iAttacker ] )
    {
        return HAM_SUPERCEDE;
    }
    return HAM_IGNORED;
} 


[edon1337]

Originally Posted by Th3822 It looks like the issue is the recursion on the Ham_TakeDamage hook it seems that you are trying to block damage incorrectly and in that code you call Ham_TakeDamage again with ExecuteHamB, so it does call all plugin's Ham_TakeDamage hooks again, repeating over and over again... There is a warning about that on the .inc: after looking at your code, there is no reason to calling Ham_TakeDamage again just to "allow" the damage, try using this: PHP Code: public fw_HamTakeDamagePre( iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits ) {     if ( iVictim != iAttacker && g_iPlayerTeam[ iVictim ] == g_iPlayerTeam[ iAttacker ] )     {         return HAM_SUPERCEDE;     }     return HAM_IGNORED; }

I'm not trying to block the damage, I'm trying to produce it.
What I want to do:

public fw_HamTakeDamagePre( iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits )
{
    if( g_iPlayerTeam[ iVictim ] != g_iPlayerTeam[ iAttacker ] ) // enemies
    {
        // allow damage (doesnt matter whether they are both CT or T) you can't just return HAM_SUPERCEDE if they are both T or CT
    }
    return HAM_SUPERCEDE; // block friendlyfire
}

[klippy]

Why not just let it the original call pass through instead of replicating it? That's exactly what Th3822's code does and is what you are trying to do.

[edon1337]

Originally Posted by KliPPy Why not just let it the original call pass through instead of replicating it? That's exactly what Th3822's code does and is what you are trying to do.

How is it what I'm asking for if all he's doing is returning HAM_IGNORED?

[klippy]

Originally Posted by edon1337 How is it what I'm asking for if all he's doing is returning HAM_IGNORED?

Exactly. If you want to allow damage (as the comment in your previous post states) then all you have to do is return HAM_IGNORED.