[miniman]

is that possible to add TerminateRound for CSS?
would be very useful

[berni]

No, unfortunately CS:S doesn't provide an entity for ending a round.
The only way would be with a signature/symbol and smlib doesn't use SDKCalls.

[miniman]

Originally Posted by berni No, unfortunately CS:S doesn't provide an entity for ending a round. The only way would be with a signature/symbol and smlib doesn't use SDKCalls.

any good reason why?
well I can give you the sig if you need it

[GoD-Tony]

Was using smlibs and noticed this:

stock Client_SetMaxSpeed(client, Float:value)
{
    Client_SetMaxSpeed(client, value);
}

Maybe I can add a new one while I'm posting:

Float:GetClientMapTime(client)
{
    /* Retrieves the time played on the current map. */
    new Float:fClientTime = GetClientTime(client);
    new Float:fGameTime = GetGameTime();
    return (fClientTime < fGameTime) ? fClientTime : fGameTime;
}

[berni]

Originally Posted by GoD-Tony Was using smlibs and noticed this: Code: stock Client_SetMaxSpeed(client, Float:value) {     Client_SetMaxSpeed(client, value); }

It should call Entity_SetMaxSpeed, fixed on svn.
You can use Entity_SetMaxSpeed in the meanwhile, Client_SetMaxSpeed ist just a wrapper

Originally Posted by GoD-Tony Was using smlibs and noticed this: Maybe I can add a new one while I'm posting: Code: Float:GetClientMapTime(client) { &nbsp;&nbsp;&nbsp;&nbsp;/* Retrieves the time played on the current map. */ &nbsp;&nbsp;&nbsp;&nbsp;new Float:fClientTime = GetClientTime(client); &nbsp;&nbsp;&nbsp;&nbsp;new Float:fGameTime = GetGameTime(); &nbsp;&nbsp;&nbsp;&nbsp;return (fClientTime < fGameTime) ? fClientTime : fGameTime; }

Added function Client_GetMapTime()

[FunkyLoveCow]

The SVN repository is asking for a username and password.

[berni]

The webhost was moved a while ago, should be fixed now

Greetings ~Berni

[rhelgeby]

Logic mistake in String_ToLower and String_ToUpper. They only write changed characters back to the output. A string with just lowercase letters passed to String_ToLower will give empty output.

It's Fixed by adding a else statement and passing the value directly from input to output (same applies to String_ToUpper):

PHP Code:

/**
 * Converts the whole String to lower case.
 * Only works with alphabetical characters (not ÖÄÜ) because Sourcemod suxx !
 * The Output String can be the same as the Input String.
 *
 * @param input                Input String.
 * @param output            Output String.
 * @param size                Max Size of the Output string
 * @noreturn
 */
stock String_ToLower(const String:input[], String:output[], size)
{
    size--;

    new x=0;
    while (input[x] != '\0' || x < size) {
        
        if (IsCharUpper(input[x])) {
            output[x] = CharToLower(input[x]);
        }
        else {
            // Lowercase letter or another symbol. Pass it directly to output.
            output[x] = input[x];
        }
        
        x++;
    }
    
    output[x] = '\0';
} 


Btw, you don't really need to write '\0'. It's exactly the same as writing just 0. The escape sequence may add a little noise in the code so it's harder to read. Remember that characters are numbers.

[berni]

Yeah, changed

Originally Posted by rhelgeby Btw, you don't really need to write '\0'. It's exactly the same as writing just 0. The escape sequence may add a little noise in the code so it's harder to read. Remember that characters are numbers.

Since we are dealing with characters we also handle the string terminator as one ^^ I don't think it confuses anyone because this sequence is well known.

[Peace-Maker]

I'm using those stocks quite often lately.
They're used to draw a box of lasers limited by two diagonally opposite points as edges.

Would be great to have them included, so i don't need to paste them all the time

[IMG]http://img843.**************/img843/9093/antirusheditzone.th.jpg[/IMG]

PHP Code:

/**
 * Sends a boxed beam effect to one player.
 * 
 * Ported from eventscripts vecmath library.
 *
 * @param client        The client to show the box to.
 * @param uppercorner    One upper corner of the box.
 * @param bottomcorner    One bottom corner of the box.
 * @param ModelIndex    Precached model index.
 * @param HaloIndex        Precached model index.
 * @param StartFrame    Initital frame to render.
 * @param FrameRate        Beam frame rate.
 * @param Life            Time duration of the beam.
 * @param Width            Initial beam width.
 * @param EndWidth        Final beam width.
 * @param FadeLength    Beam fade time duration.
 * @param Amplitude        Beam amplitude.
 * @param color            Color array (r, g, b, a).
 * @param Speed            Speed of the beam.
 * @noreturn
 */
stock TE_SendBeamBoxToClient(client, const Float:uppercorner[3], const Float:bottomcorner[3], ModelIndex, HaloIndex, StartFrame, FrameRate, Float:Life, Float:Width, Float:EndWidth, FadeLength, Float:Amplitude, const Color[4], Speed)
{
    new clients[1];
    clients[0] = client;
    TE_SendBeamBox(clients, 1, uppercorner, bottomcorner, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
}

/**
 * Sends a boxed beam effect to all players.
 * 
 * Ported from eventscripts vecmath library.
 *
 * @param uppercorner    One upper corner of the box.
 * @param bottomcorner    One bottom corner of the box.
 * @param ModelIndex    Precached model index.
 * @param HaloIndex        Precached model index.
 * @param StartFrame    Initital frame to render.
 * @param FrameRate        Beam frame rate.
 * @param Life            Time duration of the beam.
 * @param Width            Initial beam width.
 * @param EndWidth        Final beam width.
 * @param FadeLength    Beam fade time duration.
 * @param Amplitude        Beam amplitude.
 * @param color            Color array (r, g, b, a).
 * @param Speed            Speed of the beam.
 * @noreturn
 */
stock TE_SendBeamBoxToAll(const Float:uppercorner[3], const Float:bottomcorner[3], ModelIndex, HaloIndex, StartFrame, FrameRate, Float:Life, Float:Width, Float:EndWidth, FadeLength, Float:Amplitude, const Color[4], Speed)
{
    new total = 0;
    new clients[MaxClients];
    for (new i=1; i<=MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            clients[total++] = i;
        }
    }
    TE_SendBeamBox(clients, total, uppercorner, bottomcorner, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
}

/**
 * Sends a boxed beam effect to a list of players.
 * 
 * Ported from eventscripts vecmath library.
 *
 * @param clients        An array of clients to show the box to.
 * @param numClients    Number of players in the array.
 * @param uppercorner    One upper corner of the box.
 * @param bottomcorner    One bottom corner of the box.
 * @param ModelIndex    Precached model index.
 * @param HaloIndex        Precached model index.
 * @param StartFrame    Initital frame to render.
 * @param FrameRate        Beam frame rate.
 * @param Life            Time duration of the beam.
 * @param Width            Initial beam width.
 * @param EndWidth        Final beam width.
 * @param FadeLength    Beam fade time duration.
 * @param Amplitude        Beam amplitude.
 * @param color            Color array (r, g, b, a).
 * @param Speed            Speed of the beam.
 * @noreturn
 */
stock TE_SendBeamBox(clients[], numClients, const Float:uppercorner[3], const Float:bottomcorner[3], ModelIndex, HaloIndex, StartFrame, FrameRate, Float:Life, Float:Width, Float:EndWidth, FadeLength, Float:Amplitude, const Color[4], Speed)
{
    // Create the additional corners of the box
    new Float:tc1[3];
    AddVectors(tc1, uppercorner, tc1);
    tc1[0] = bottomcorner[0];
    new Float:tc2[3];
    AddVectors(tc2, uppercorner, tc2);
    tc2[1] = bottomcorner[1];
    new Float:tc3[3];
    AddVectors(tc3, uppercorner, tc3);
    tc3[2] = bottomcorner[2];
    new Float:tc4[3];
    AddVectors(tc4, bottomcorner, tc4);
    tc4[0] = uppercorner[0];
    new Float:tc5[3];
    AddVectors(tc5, bottomcorner, tc5);
    tc5[1] = uppercorner[1];
    new Float:tc6[3];
    AddVectors(tc6, bottomcorner, tc6);
    tc6[2] = uppercorner[2];
    
    // Draw all the edges
    TE_SetupBeamPoints(uppercorner, tc1, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(uppercorner, tc2, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(uppercorner, tc3, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc6, tc1, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc6, tc2, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc6, bottomcorner, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc4, bottomcorner, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc5, bottomcorner, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc5, tc1, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc5, tc3, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc4, tc3, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
    TE_SetupBeamPoints(tc4, tc2, ModelIndex, HaloIndex, StartFrame, FrameRate, Life, Width, EndWidth, FadeLength, Amplitude, Color, Speed);
    TE_Send(clients, numClients);
}