[Rivotril]

Hello, how can i modify the weapon earning money from killing with 'X' weapon? thanks!

[CookieCrumbler]

Weapon Money Reward(Similar)

[Rivotril]

Originally Posted by CookieCrumbler Weapon Money Reward(Similar)

yeah but not quite what i'm trying to do, thx anyway

what i want to do is give less money (than 300 per kill) with a weapon or more with another weapon and the hud that checks the earning (that says 300 everytime you kill) say the amount of money that you actually are getting

[jimaway]

register_message(get_user_msgid("Money"), "message_money")

public message_money(msgid, msgdest, id)
{
   set_msg_arg_int(1, get_msg_argtype(1), /*whatever amount you need*/)
}

[Bugsy]

jimaway: That will only update the HUD message.

Not thoroughly tested. The below will give $50 for all weapons, including knife. If you want, a modifier can be added if the kill was via headshot to give an extra $X or multiply pay by X. You can also modify money impact for team-kill.

PHP Code:


#include <amxmodx>
#include <cstrike>
#include <fakemeta>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

new const WeaponMoney[] = 
{
    0,
    50, //P228
    0,
    50, //SCOUT
    50, //Grenade
    50, //XM1014
    0,  //C4
    50, //Mac10
    50, //Aug
    0,  //Smoke
    50, //Elites
    50, //FiveSeven
    50, //Ump45
    50, //SG550
    50, //Galil
    50, //Famas
    50, //USP
    50, //Glock
    50, //Awp
    50, //MP5Navy
    50, //M249
    50, //M3
    50, //M4A1
    50, //Tmp
    50, //G3SG1
    0,  //Flashbang
    50, //Deagle
    50, //SG552
    50, //AK47
    50, //Knife
    50  //P90
};

const m_iAccount = 115;
const Default_Kill_Money = 300;

new g_iWeaponID[ MAX_PLAYERS + 1 ];

public plugin_init() 
{
    register_plugin( "Kill Money by Weapon" , Version , "bugsy" );
    
    register_event( "DeathMsg" , "Event_DeathMsg" , "a" , "1>0" );
    register_message( get_user_msgid( "Money" ) , "Message_Money" );
}

public Event_DeathMsg()
{
    new iKiller = read_data( 1 );
    new iVictim = read_data( 2 );
    
    if ( ( iKiller != iVictim ) && is_user_connected( iKiller ) && ( cs_get_user_team( iKiller ) != cs_get_user_team( iVictim ) ) )
    {
        g_iWeaponID[ iKiller ] = get_user_weapon( iKiller );
    }
}

public Message_Money( iMsgId , iMsgDest , id )
{
    if ( g_iWeaponID[ id ] )
    {    
        new iNewMoney = clamp( ( get_pdata_int( id , m_iAccount ) - Default_Kill_Money ) + WeaponMoney[ g_iWeaponID[ id ] ] , 0 , 16000 );
        
        set_pdata_int( id , m_iAccount , iNewMoney );
        
        set_msg_arg_int( 1 , ARG_LONG , iNewMoney );
        set_msg_arg_int( 2 , ARG_BYTE , 1 );
        
        g_iWeaponID[ id ] = 0;
    }
} 


[JusTGo]

Originally Posted by Bugsy snip

You don't need to check IsPlayer and is_user_connected because is_user_connected already checks for valid index

PHP Code:

static cell AMX_NATIVE_CALL is_user_connected(AMX *amx, cell *params) /* 1 param */
{
    int index = params[1];

    if (index < 1 || index > gpGlobals->maxClients)
        return 0;

    CPlayer* pPlayer = GET_PLAYER_POINTER_I(index);

    return (pPlayer->ingame ? 1 : 0);
} 


[Bugsy]

Yeah, I know, I added is_user_connected() last minute and didn't consider that.

[Relaxing]

Originally Posted by Bugsy jimaway: That will only update the HUD message. Not thoroughly tested. The below will give $50 for all weapons, including knife. If you want, a modifier can be added if the kill was via headshot to give an extra $X or multiply pay by X. You can also modify money impact for team-kill. PHP Code: #include <amxmodx> #include <cstrike> #include <fakemeta> new const Version[] = "0.1"; #define MAX_PLAYERS 32 new const WeaponMoney[] =  {     0,     50, //P228     0,     50, //SCOUT     50, //Grenade     50, //XM1014     0,  //C4     50, //Mac10     50, //Aug     0,  //Smoke     50, //Elites     50, //FiveSeven     50, //Ump45     50, //SG550     50, //Galil     50, //Famas     50, //USP     50, //Glock     50, //Awp     50, //MP5Navy     50, //M249     50, //M3     50, //M4A1     50, //Tmp     50, //G3SG1     0,  //Flashbang     50, //Deagle     50, //SG552     50, //AK47     50, //Knife     50  //P90 }; const m_iAccount = 115; const Default_Kill_Money = 300; new g_iWeaponID[ MAX_PLAYERS + 1 ]; public plugin_init()  {     register_plugin( "Kill Money by Weapon" , Version , "bugsy" );          register_event( "DeathMsg" , "Event_DeathMsg" , "a" , "1>0" );     register_message( get_user_msgid( "Money" ) , "Message_Money" ); } public Event_DeathMsg() {     new iKiller = read_data( 1 );     new iVictim = read_data( 2 );          if ( ( iKiller != iVictim ) && is_user_connected( iKiller ) && ( cs_get_user_team( iKiller ) != cs_get_user_team( iVictim ) ) )     {         g_iWeaponID[ iKiller ] = get_user_weapon( iKiller );     } } public Message_Money( iMsgId , iMsgDest , id ) {     if ( g_iWeaponID[ id ] )     {             new iNewMoney = clamp( ( get_pdata_int( id , m_iAccount ) - Default_Kill_Money ) + WeaponMoney[ g_iWeaponID[ id ] ] , 0 , 16000 );                  set_pdata_int( id , m_iAccount , iNewMoney );                  set_msg_arg_int( 1 , ARG_LONG , iNewMoney );         set_msg_arg_int( 2 , ARG_BYTE , 1 );                  g_iWeaponID[ id ] = 0;     } }

Why are you resetting the g_iWeaponID? Because even if you don't reset it, it won't corrupt anything.

[Natsheh]

Originally Posted by Relaxing Why are you resetting the g_iWeaponID? Because even if you don't reset it, it won't corrupt anything.

Because message money is also called on gaining money other than killing thats why he reset it.

But saddly this wont work for grenades.

PHP Code:

public Event_DeathMsg()
{
    new iKiller = read_data( 1 );
    new iVictim = read_data( 2 );
    
    if ( ( iKiller != iVictim ) && is_user_connected( iKiller ) && ( cs_get_user_team( iKiller ) != cs_get_user_team( iVictim ) ) )
    {
        new szWp[32]
        add(szWp, 7, "weapon_")
        read_data(4, szWp[7], charsmax(szWp))
        if(equal(szWp[7], "grenade")) formatex(szWp, charsmax(szWp), "weapon_hegrenade");
        g_iWeaponID[ iKiller ] = get_weaponid( szWp );
    }
} 


This should work for hegrenade kill

[Relaxing]

Originally Posted by Natsheh Because message money is also called on gaining money other than killing thats why he reset it. But saddly this wont work for grenades.

Gotcha