[Uncle Jessie]

hi, how to block the voting or any commands for incap players? any links to sample script.

PHP Code:

public Action:Jointeam2(client, args)
{
    ClientCommand(client,"jointeam 2");
    return Plugin_Handled;
}
public Action:Spectate(client, args)
{
    ChangeClientTeam(client, 1);
    return Plugin_Handled;
} 


[Timocop]

You mean like this?

PHP Code:

public void OnPluginStart()
{
    if(!AddCommandListener(eCommandReceiver))
        SetFailState("CommandListener not available!");
}

public Action eCommandReceiver(int client, const char[] command, int argc)
{
    //IsClientIncap is pseudo-code, use what you want here
    if(IsClientIncap(client)) {
        if(StrEqual(command, "jointeam"))
            return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


[Uncle Jessie]

Originally Posted by Timocop You mean like this?

Mean check that the player incapacitated and block commands like this. I did not find something like that here.

PHP Code:

public OnPluginStart()
{
    RegConsoleCmd("sm_join", Jointeam2);
    RegConsoleCmd("sm_afk", Spectate);
}
public Action:Jointeam2(client, args)
{
    ClientCommand(client,"jointeam 2");
    return Plugin_Handled;
}
public Action:Spectate(client, args)
{
    ChangeClientTeam(client, 1);
    return Plugin_Handled;
} 


[Timocop]

You can search in other peoples plugins for that or use NetProps, good for starters.

PHP Code:

/**
* Is client Incapacitated (L4D)
*/
stock bool:Client_IsInIncapped(client)
{
    return (GetEntProp(client, Prop_Send, "m_isIncapacitated", 1) > 0);
} 


PHP Code:


public OnPluginStart()
{
    RegConsoleCmd("sm_join", Jointeam2);
    RegConsoleCmd("sm_afk", Spectate);
}

public Action:Jointeam2(client, args)
{
    if(!IsValidClient(client) || IsClientIncapped(client))
    return Plugin_Handled;
    
    FakeClientCommand(client,"jointeam 2");
    return Plugin_Handled;
}

public Action:Spectate(client, args)
{
    if(!IsValidClient(client) || IsClientIncapped(client))
    return Plugin_Handled;
    
    ChangeClientTeam(client, 1);
    return Plugin_Handled;
}

stock bool:IsValidClient(client)
{
    return (client > 0
            && client <= MaxClients
            && IsClientInGame(client));
}

stock bool:IsClientIncapped(client)
{
    return (GetEntProp(client, Prop_Send, "m_isIncapacitated", 1) > 0);
} 


[Uncle Jessie]

Originally Posted by Timocop You can search in other peoples plugins for that or use NetProps, good for starters.

It works, thank you very much!