[ddhoward]

Originally Posted by Dragokas (1) && (2) considered in SourcePawn: will (2) be called if (1) is false ?

No, Sourcepawn uses "lazy" or "short-circuit" evaluation. This allows you to do things like this:

if (0 < index <= MaxClients && IsClientInGame(index))

Passing an index that is less than 1 or greater than MaxClients to IsClientInGame() will cause errors, but the above snippet is safe, as the first part of the conditional ensures that invalid indexes will never make it to the second part.

[Dragokas]

Headline, nice, thanks.

[Dragokas]

ddhoward, so, your example in SourcePawn do:

1) 0 < index
2) index <= MaxClients
...

not:

1) 0 < index
2) (bool result) <= MaxClients
as C++ do.

?

[Dragokas]

Ok, here is another one I can't understand and explain:

L 03/19/2018 - 20:402: [SM] Native "GetClientTeam" reported: Client 2 is not in game L 03/19/2018 - 20:402: [SM] Displaying call stack trace for plugin "MuLS.smx": L 03/19/2018 - 20:402: [SM] [0] Line 801, plugin.sp::HasIdlePlayer() L 03/19/2018 - 20:402: [SM] [1] Line 680, plugin.sp::TotalFreeBots() L 03/19/2018 - 20:402: [SM] [2] Line 164, plugin.sp::JoinTeam() L 03/19/2018 - 20:402: [SM] [3] Line 412, plugin.sp::Timer_AutoJoinTeam()

public bool HasIdlePlayer(int bot)
{
	if(!IsFakeClient(bot))
		return false
	
	if(IsClientConnected(bot) && IsClientInGame(bot))
	{
		if((GetClientTeam(bot) == TEAM_SURVIVORS) && IsAlive(bot))
		{
			if(IsFakeClient(bot))
			{
				int client = GetClientOfUserId(GetEntProp(bot, Prop_Send, "m_humanSpectatorUserID"))			
				if(client)
				{
					if(!IsFakeClient(client) && (GetClientTeam(client) == TEAM_SPECTATORS))
						return true
				}
			}
		}
	}
	return false
}

This time IsClientInGame is directly before GetClientTeam call.

[Fyren]

Originally Posted by Dragokas ddhoward, so, your example in SourcePawn do: 1) 0 < index 2) index <= MaxClients ... not: 1) 0 < index 2) (bool result) <= MaxClients as C++ do. ?

Yes, in SP you can do 1 < x < 10 to check if x is between 1 and 10. It's not like in C++.

This time IsClientInGame is directly before GetClientTeam call.

There's two calls. If it's the one for the client, you don't do a check.

[ddhoward]

Originally Posted by Dragokas -snip-

Why two different IsFakeClient() calls to the same index?

You're calling IsFakeClient() before IsClientConnected(), which will result in errors. The index passed to IsFakeClient must have a client.

IsClientInGame() is a function that breaks Sourcemod's typical behavior in that it is not necessary to call IsClientConnected() through it. IsClientInGame() includes its own IsClientConnected() check.


Here's your code but cleaned up. I'm thinking that you're trying to determine if the passed index is populated by a living bot on the Survivors team, with a human spectator on him?

PHP Code:

public bool HasIdlePlayer(int bot)
{
    if(IsClientInGame(bot) && IsFakeClient(bot))
    {
        if(IsPlayerAlive(bot) && GetClientTeam(bot) == TEAM_SURVIVORS)
        {
            int client = GetClientOfUserId(GetEntProp(bot, Prop_Send, "m_humanSpectatorUserID"))            
            if(client)
            {
                if(IsClientInGame(client) && !IsFakeClient(client) && GetClientTeam(client) == TEAM_SPECTATORS)
                    return true
            }
        }
    }
    return false
} 


[Dragokas]

There's two calls. If it's the one for the client, you don't do a check.

What you mean? Here is a check:

	if(IsClientConnected(bot) && IsClientInGame(bot))
	{
		if((GetClientTeam(bot) == TEAM_SURVIVORS) && IsAlive(bot))

Two calls. Yes. But will something change if I write it inline?

ddhoward, you are right. Fixed now. Thank you. Again, not my code, so I didn't done optimization yet.
However, SM log say that exception raised in GetClientTeam(), not IsFakeClient().
BTW, thanks for IsClientInGame explanation.

[Fyren]

I mean here:

PHP Code:

                int client = GetClientOfUserId(GetEntProp(bot, Prop_Send, "m_humanSpectatorUserID"))            
                if(client)
                {
                    if(!IsFakeClient(client) && (GetClientTeam(client) == TEAM_SPECTATORS))
                        return true
                } 


You call GetClientTeam in two places. ddhoward's change adds another IsClientInGame check for the client one.

[Dragokas]

Fyren, ahh, I see. Thanks.