[Syncron.]

Didn't work with CSW_KNIFE,why?
i'm write:
give_user_weapon(id, CSW_KNIFE )
and after this i'm thinking maybe must to set clip so => give_user_weapon(id, CSW_KNIFE, 1 )

[Craxor]

what? you don't need this stock for knives, just do give_item( id, "weapon_knife" );

[Natsheh]

here's my stock that im using

Includes :- amxmodx & Fakemeta & cstrike

PHP Code:


#if !defined CSW_SHIELD
    #define CSW_SHIELD 2
#endif

stock give_player_weapon(const id, const wId, iClip=0, iBPammo=0, wpnname[], wLen)
{
    if(!is_user_alive(id) || !(CSW_P228 <= wId <= CSW_VESTHELM) || iClip < 0 || iBPammo < 0) return -1;
    
    new Float:fOrigin[3], wpnent;
    pev(id, pev_origin, fOrigin)
    
    switch( wId )
    {
        case CSW_VEST, CSW_VESTHELM:
        {
            wpnent = fm_create_entity("armoury_entity", fOrigin)
            if(!wpnent) return 0;
            set_pev(wpnent,pev_spawnflags,SF_NORESPAWN);
            cs_set_armoury_type(wpnent, wId);
            dllfunc(DLLFunc_Spawn, wpnent);
            copy(wpnname, wLen, "Armour")
        }
        case CSW_SHIELD:
        {
            wpnent = fm_create_entity("weapon_shield", fOrigin);
            if(!wpnent) return 0;
            set_pev(wpnent,pev_spawnflags,SF_NORESPAWN);
            dllfunc(DLLFunc_Spawn, wpnent);
            copy(wpnname, wLen, "Shield");
        }
        default :
        {
            new sWpnname[24];
            get_weaponname(wId, sWpnname, charsmax(sWpnname))
            
            new sWpns[32], wnums;
            new bitwpns = get_user_weapons(id, sWpns, wnums);
            
            if(bitwpns & (1<<wId))
            {
                while ( ((wpnent = engfunc(EngFunc_FindEntityByString, wpnent, "classname", sWpnname))) > 0 && pev(wpnent,pev_owner) != id ) { }
                wpnent = (pev_valid(wpnent) && pev(wpnent, pev_owner) == id) ? wpnent:0;
            }
            
            if(!wpnent)
            {
                wpnent = fm_create_entity(sWpnname, fOrigin);
                if(!wpnent) return 0;
                set_pev(wpnent,pev_spawnflags,SF_NORESPAWN);
                dllfunc(DLLFunc_Spawn, wpnent);
            }
            
            copy(wpnname, wLen, sWpnname[7]);
            ucfirst(wpnname);
            
            if(wId != CSW_HEGRENADE && wId != CSW_SMOKEGRENADE && wId != CSW_FLASHBANG)
                cs_set_weapon_ammo(wpnent, iClip);
            else if(wId == CSW_C4) cs_set_user_plant(id);
            
            cs_set_user_bpammo(id, wId, iBPammo);
        }
    }
    
    return 1;
}

stock fm_create_entity(const Entname[], Float:fOrigin[3])
{
    new wEnt = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, Entname));
    
    if(!pev_valid(wEnt)) return -1;
    
    engfunc(EngFunc_SetOrigin, wEnt, fOrigin);
    
    return wEnt
} 


[Depresie]

Originally Posted by Craxor what? you don't need this stock for knives, just do give_item( id, "weapon_knife" );

You should also add the knife into this, regardless..

[Craxor]

why? The goal of this is scop is to sett ammo/bpammo without problems/errors, knives can't have ammo.

[Bugsy]

I agree with them, Craxor. This way it covers everything. The end user may attempt to use it with knife not knowing it was not built to handle knives. The function name is not indicative of this.

[Craxor]

I will update it, btw, how can i give an error at compilation if user use CSW_KNIFE? assert wilt work ?

[Bugsy]

Just make it give knife... and no

Edit: It works with knife, I just tested it with this: give_user_weapon( id , CSW_KNIFE );

However, you should prevent the give ammo natives from being called:

give_user_weapon( index , iWeaponTypeID , iClip=0 , iBPAmmo=0 , szWeapon[]="" , maxchars=0 )
{
    if ( !( CSW_P228 <= iWeaponTypeID <= CSW_P90 ) || ( iClip < 0 ) || ( iBPAmmo < 0 ) || !is_user_alive( index ) )
        return -1;
    
    new szWeaponName[ 20 ] , iWeaponEntity , bool:bIsGrenade;
    
    const GrenadeBits = ( ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_C4 ) );
    
    if ( ( bIsGrenade = bool:!!( GrenadeBits & ( 1 << iWeaponTypeID ) ) ) )
        iClip = clamp( iClip ? iClip : iBPAmmo , 1 );
    
    get_weaponname( iWeaponTypeID , szWeaponName , charsmax( szWeaponName ) );
    
    if ( ( iWeaponEntity = user_has_weapon( index , iWeaponTypeID ) ? find_ent_by_owner( -1 , szWeaponName , index ) : give_item( index , szWeaponName ) ) > 0 )
    {
        if ( iWeaponTypeID != CSW_KNIFE )
        {
            if ( iClip && !bIsGrenade )
                cs_set_weapon_ammo( iWeaponEntity , iClip );
        
            if ( iWeaponTypeID == CSW_C4 ) 
                cs_set_user_plant( index , 1 , 1 );
            else
                cs_set_user_bpammo( index , iWeaponTypeID , bIsGrenade ? iClip : iBPAmmo ); 
        }
        
        if ( maxchars )
            copy( szWeapon , maxchars , szWeaponName[7] );
    }
    
    return iWeaponEntity;
}

[Craxor]

Doneeeeeeeee

[Bugsy]

While I agree that give_item() is more proper and efficient for giving a knife, the function does handle knives so I don't think your big red blurb is appropriate. Also, it does cover the alive check which is a convenience to the scripter.

I would also give the code a heading of 'Function' instead of 'Stock'. Basically you should only ever use a 'stock' defined function or variable in an include file. What many people refer to as 'stocks' on these forums are actually functions. Stock simply makes the function/variable not get compiled into the binary (.amxx) if it is never used in the code--hence it is appropriate in include files since include files have a ton of code that scripters may only use 1 or 2 functions from.

From the Pawn language guide:

Stock declarations

A global variable may be declared as “stock”. A stock declaration is one 
that the parser may remove or ignore if the variable turns out not to be 
used in the program.

Stock variables are useful in combination with stock functions.  A public 
variable may be declared as “stock” as well —declaring public variables 
as “public stock” enables you to declare all public variables that a host 
application provides in an include file, with only those variables that the 
script actually uses winding up in the P-code file.