[BrutalGoerge]

Hi, for my medic ammo plugin, i just noticed it was showing 255 ammo for pyro and heavy all the time, and I'm not quite sure when this started happening, if it was a tf2 update, or sm change.

here's the code that I was using to read the ammo

stock GetHeavyPyroAmmo(client)
{
	new ammoOffset = FindSendPropInfo("CTFPlayer", "m_iAmmo");
	return GetEntData(client, ammoOffset + 4, 4);
}

ive tried doing different multiples of 4 for the offset 0-32, all just give me 255
before i go crazy with this later, i was hoping that maybe someone already knows!

thx :>

[BrutalGoerge]

yeah im too dumb to figure this out, no matter what i change, it says PRIMARY AMMO: 255
/help me :<

[Tylerst]

What you're doing is fine, the problem probably lies in how you use it in your plugin.

Edit: Found the problem, in your stock ShowInfo(medic, target):

PHP Code:

class = TF2_GetPlayerClass(target);
if (class == TFClass_Pyro || class == TFClass_Heavy)
{
      iAmmo1 = GetHeavyPyroAmmo(target);
      Format(sMessage, sizeof(sMessage), "Primary Ammo: %i ", iAmmo1);
}
else if (iClip1 == -1)
{
     iAmmo1 = TF2_GetSlotAmmo(target, 0);
     if (iAmmo1 != -1)
     {
          Format(sMessage, sizeof(sMessage), "Primary Ammo: %i ", iAmmo1);
     }
}
if (iClip1 != -1)
{
     Format(sMessage, sizeof(sMessage), "Primary Ammo: %i / %i ", iClip1, g_aClientSettings[target][iMaxClip1]);
} 


Fix by changing the if(iClip1 != -1) to else, I also suggest adding a sniper check with the heavy/pyro since it would have the same problem, and possibly use a switch for better performance since this will be calculated repeatedly.

Another observation when I glanced at it, you check that the class isn't medic, right after checking that the class IS demoman?

if (class == TFClass_DemoMan)
{
     if (iClip2 != -1 && class != TFClass_Medic)
     {
          Format(sMessage, sizeof(sMessage), "%sSecondary Ammo: %i / %i ", sMessage, iClip2, g_aClientSettings[target][iMaxClip2]);
     }
}

Here's an example of how I would change that particular section:

PHP Code:

if (iClip1 == -1)
{
     iAmmo1 = TF2_GetSlotAmmo(target, 0);
     if (iAmmo1 != -1) Format(sMessage, sizeof(sMessage), "Primary Ammo: %i ", iAmmo1);
}
else Format(sMessage, sizeof(sMessage), "Primary Ammo: %i / %i ", iClip1, g_aClientSettings[target][iMaxClip1]);
 
new class = TF2_GetPlayerClass(target);
switch(class)
{
     case TFClass_Pyro, TFClass_Heavy, TFClass_Sniper:
     {
          iAmmo1 = GetHeavyPyroAmmo(target);
          Format(sMessage, sizeof(sMessage), "Primary Ammo: %i ", iAmmo1);
     }
     case TFClass_DemoMan:
     {
          if (iClip2 != -1) Format(sMessage, sizeof(sMessage), "%sSecondary Ammo: %i / %i ", sMessage, iClip2, g_aClientSettings[target][iMaxClip2]);
     }
} 


[BrutalGoerge]

wow don't i feel like the stooge mcFuck I dont even remember changing that bit, so i thought it was changes in tf2 that screwed it up and nothing i did... so i wasn't even looking at that portion

thanks a lot!!!!!!