[jeezybox]

Hello,

I need to find where is this command stored in the sourcemod files, I order the list of IP.

For example, we are having a lot of players, when I type sm_ip, I want to order the list by IP.

Best Regards

[Ilusion9]

You are using a custom plugin. Maybe tell us which one? There's no sm_ip command in the default sourcemod plugins.

[jeezybox]

#include <sourcemod>
#include <sdktools>
#include <cstrike>

public OnPluginStart()
{
	CreateConVar("Sm IP", "1.0", "Window");
	RegConsoleCmd("sm_ip", CmdIp);
}
public Action:CmdIp(client, args)
{
	if(!IsClientInGame(client))
		return Plugin_Continue;

	new ilee = 0;
	PrintToConsole(client, "IP graczy grajacych na serwerze:");
	for(new i = 1, max = GetMaxClients(); i <= max; ++ i)
	{
		if(IsClientInGame(i))
		{
			new String:nazwa_gracza[65];
			new String:ip_gracza[65];
			GetClientName(i, nazwa_gracza[i], 64);
			GetClientIP(i, ip_gracza[i], 64);

			PrintToConsole(client, "%d) %s - %s.", i, nazwa_gracza[i], ip_gracza[i]);
			ilee = i;
		}
	}

	PrintToConsole(client, "Wszystkich graczy: %d.", ilee);
	return Plugin_Continue;
}

Okay, this is the code, how can I order the IPs, I want to order the IPs so I can detect people with same IP playing in opposite teams. This will be much easier if console outputs ordered IP.

[Marttt]

You can use some "Sort" functions from Sourcemod

https://sm.alliedmods.net/new-api/sorting/SortStrings

Functions
SortADTArray
SortADTArrayCustom
SortCustom1D
SortCustom2D
SortFloats
SortIntegers
SortStrings

[Ilusion9]

try this:

PHP Code:


#include <sourcemod>
#include <sdktools>
#include <cstrike>

enum struct PlayerInfo
{
    char name[MAX_NAME_LENGTH];
    char ip[65];
}

public OnPluginStart()
{
    RegConsoleCmd("sm_ip", Command_IP);
}

public Action Command_IP(int client, int args)
{
    ArrayList listPlayers = new ArrayList(sizeof(PlayerInfo));
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            PlayerInfo info;
            GetClientName(i, info.name, sizeof(PlayerInfo::name));
            GetClientIP(i, info.ip, sizeof(PlayerInfo::ip));
            listPlayers.PushArray(info);
        }
    }
    
    listPlayers.SortCustom(sortPlayers);
    
    PrintToConsole(client, "IP graczy grajacych na serwerze:");
    for (int i = 0; i < listPlayers.Length; i++)
    {
        PlayerInfo info;
        listPlayers.GetArray(i, info);
        PrintToConsole(client, "%d) %s - %s.", i + 1, info.name, info.ip);
    }

    PrintToConsole(client, "Wszystkich graczy: %d.", listPlayers.Length);
    delete listPlayers;
    
    return Plugin_Handled;
}


public int sortPlayers(int index1, int index2, Handle array, Handle hndl)
{
    PlayerInfo info1, info2;
    view_as<ArrayList>(array).GetArray(index1, info1);
    view_as<ArrayList>(array).GetArray(index2, info2);
    
    return strcmp(info1.ip, info2.ip);
}