[heroicpower7613]

hey.
how do I calculate the position on front of a client but slightly to left?

like so:


here's a code to get origin directly in front of player:

Originally Posted by zipcore better use this: PHP Code: stock void AddInFrontOf(float vecOrigin[3], float vecAngle[3], float units, float output[3]) {     float vecAngVectors[3];     vecAngVectors = vecAngle; //Don't change input     GetAngleVectors(vecAngVectors, vecAngVectors, NULL_VECTOR, NULL_VECTOR);     for (int i; i < 3; i++)     output[i] = vecOrigin[i] + (vecAngVectors[i] * units); }

but that's not exactly what I'm after.
thanks.

[eyal282]

This is 45 degrees to the left, and I'll give it 80 units from the player's position. IDK if I need to reduce or add 45 degrees but try this:

new Float:EyeOrigin[3], Float:EyeAngles[3], Float:TestAngle[3];

GetClientEyePosition(client, EyeOrigin);
GetClientEyeAngles(client, EyeAngles);

EyeAngles[1] += 45.0;

GetAngleVectors(EyeAngles, TestAngle, NULL_VECTOR, NULL_VECTOR);

for(new i=0;i < 3;i++)
{
Origin[i] += TestAngle[i] * 80.0;
}

Note: I'm bad at vectors so this might be horribly wrong.

[Stugger]

You can give this a shot

float direction[3], newPosition[3];

// Here we get the forward vector of the client, set the distance to move forward and store it
GetAngleVectors(clientAngles, direction, NULL_VECTOR, NULL_VECTOR);
ScaleVector(direction, FLOAT_UNITS_TO_MOVE_FORWARD);
AddVectors(clientPosition, direction, newPosition);
						
// Then from the forwards position, get the right vector, negate it since we want to move left, set the distance to move left and overwrite newPosition
GetAngleVectors(clientAngles, NULL_VECTOR, direction, NULL_VECTOR);
NegateVector(direction);
ScaleVector(direction, FLOAT_UNITS_TO_MOVE_LEFT);
AddVectors(newPosition, direction, newPosition);

[heroicpower7613]

Originally Posted by eyal282 This is 45 degrees to the left, and I'll give it 80 units from the player's position. IDK if I need to reduce or add 45 degrees but try this:

hey thanks for the reply, but I don't think it worked.

Originally Posted by Stugger You can give this a shot

thanks so much, it works very well!

here is the stock if anyone needs it.

PHP Code:

stock void AddInFrontOf( float fOrigin[3], float fAngles[3], float fDistanceToFront, float fDistanceToLeft, float fOutput[3] )
{
    float fDir[3];

    GetAngleVectors(fAngles, fDir, NULL_VECTOR, NULL_VECTOR);
    ScaleVector(fDir, fDistanceToFront);
    AddVectors(fOrigin, fDir, fOutput);
                            
    GetAngleVectors(fAngles, NULL_VECTOR, fDir, NULL_VECTOR);
    NegateVector(fDir);
    ScaleVector(fDir, fDistanceToLeft);
    AddVectors(fOutput, fDir, fOutput);
}