[TheSpaniard]

As the heading suggests i want to load nvault data on player spawn
but there is a catch i want to save it only if a player selects it on the menu where there are three options, and those are -
1. New Weapons
2. Previous Weapons
3. Save and Don't ask again

For previous menu i made a public load_user_weapons(id).
But need help on how to make it for 3rd option.
and i want it to be compatible with multiple players spawns in a single round,so data needs to be loaded on every spawn.

Here is the code:-

Spoiler

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fun>
#include <nvault>
#include <fakemeta_util>
#include <hamsandwich>

#define PLUGIN "VipMenu"
#define VERSION "2.0"
#define AUTHOR "TheSpaniard"

new count[33];

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_Spawn, "player", "Fwd_PlayerSpawn_Post", 1);
    register_clcmd("say /vip", "primary_wep_menu")
}

public Fwd_PlayerSpawn_Post(id)
{
    if(!is_user_alive(id) || is_user_bot(id))
        return PLUGIN_HANDLED;
    
    if(!(get_user_flags(id) & ADMIN_LEVEL_H))
        return PLUGIN_HANDLED
    
    count[id] = 0;
    
    strip_user_weapons(id);
    set_pdata_int(id, 116, 0);
    give_item(id, "weapon_knife");
    selection(id);
    
    return PLUGIN_CONTINUE;
}

public selection(id)
{
    new select = menu_create("Choose", "selector")
    
    menu_additem( select, "New Weapons", "1", 0)
    menu_additem( select, "Previous Weapons", "2", 0)
    menu_additem( select, "Save and don't show again", "3", 0)
}

public selector(id, menu, item)
{
    switch(item)
    {
        case 0: primary_wep_menu(id)
        
        case 1: load_user_weapons(id)
        
        case 3: 
    

public primary_wep_menu(id)
{
    new menu = menu_create("\rPrimary Weapon's Menu", "menu_handler");
    
    menu_additem(menu, "\wAWP", "1", 0)
    menu_additem(menu, "\wM4A1", "2", 0)
    menu_additem(menu, "\wAK47", "3", 0)
    menu_additem(menu, "\wSG552 [Assault-Rifle]", "4", 0)
    menu_additem(menu, "\wFAMAS", "5", 0)
    menu_additem(menu, "\wSG550 [Sniper]", "6", 0)
    menu_additem(menu, "\wGALIL", "7", 0)
    menu_additem(menu, "\wD3AU1 [Auto-Snipe]", "8", 0)
    menu_additem(menu, "\wSCOUT", "9", 0)
    menu_additem(menu, "\wBULLPUP", "10", 0)
    menu_additem(menu, "\wMP5", "11", 0)
    menu_additem(menu, "\wTMP", "12", 0)
    menu_additem(menu, "\wMAC 10", "13", 0)
    menu_additem(menu, "\wUMP45", "14", 0)
    menu_additem(menu, "\wP90", "15", 0)
    menu_additem(menu, "\wM249 [Machine Gun]", "16", 0)
    menu_additem(menu, "\wXM1014", "17", 0)
    menu_additem(menu, "\wM3", "18", 0)
    
    menu_setprop( menu, MPROP_EXIT, MEXIT_ALL )
    menu_display( id, menu, 0 )
    
    return PLUGIN_CONTINUE;
}

public menu_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    new CsTeams:team = cs_get_user_team(id)
    if(team == CS_TEAM_T)
    {
        cs_set_user_armor(id, 50, CS_ARMOR_VESTHELM)
    }
    else
    {
        give_item(id, "item_thighpack")
    }
    switch(item)
    {
        case 0:
        {
            give_item(id, "weapon_awp")
            cs_set_user_bpammo(id, CSW_AWP, 30)
        }
        case 1:
        {
            give_item(id, "weapon_m4a1")
            cs_set_user_bpammo(id, CSW_M4A1, 90)
        }
        case 2:
        {
            give_item(id, "weapon_ak47")
            cs_set_user_bpammo(id, CSW_AK47, 90)
        }
        case 3:
        {
            give_item(id, "weapon_sg552")
            cs_set_user_bpammo(id, CSW_SG552, 90)
        }
        case 4:
        {
            give_item(id, "weapon_famas")
            cs_set_user_bpammo(id, CSW_FAMAS, 90)
        }
        case 5:
        {
            give_item(id, "weapon_sg550")
            cs_set_user_bpammo(id, CSW_SG550, 90)
        }
        case 6:
        {
            give_item(id, "weapon_galil")
            cs_set_user_bpammo(id, CSW_GALIL, 90)
        }
        case 7:
        {
            give_item(id, "weapon_g3sg1")
            cs_set_user_bpammo(id, CSW_G3SG1, 90)
        }
        case 8:
        {
            give_item(id, "weapon_scout")
            cs_set_user_bpammo(id, CSW_SCOUT, 90)
        }
        case 9:
        {
            give_item(id, "weapon_aug")
            cs_set_user_bpammo(id, CSW_AUG, 90)
        }
        case 10:
        {
            give_item(id, "weapon_mp5navy")
            cs_set_user_bpammo(id, CSW_MP5NAVY, 120)
        }
        case 11:
        {
            give_item(id, "weapon_tmp")
            cs_set_user_bpammo(id, CSW_TMP, 120)
        }
        case 12:
        {
            give_item(id, "weapon_mac10")
            cs_set_user_bpammo(id, CSW_MAC10, 120)
        }
        case 13:
        {
            give_item(id, "weapon_ump45")
            cs_set_user_bpammo(id, CSW_UMP45, 100)
            
        }
        case 14:
        {
            give_item(id, "weapon_p90")
            cs_set_user_bpammo(id, CSW_P90, 100)
            
        }
        case 15:
        {
            give_item(id, "weapon_m249")
            cs_set_user_bpammo(id, CSW_M249, 90)
        }
        case 16:
        {
            give_item(id, "weapon_m3")
            cs_set_user_bpammo(id, CSW_M3, 90)
        }
        case 17:
        {
            give_item(id, "weapon_xm1014")
            cs_set_user_bpammo(id, CSW_XM1014, 90)
        }
    }
    
    if(++count[id] < 2)
    {
        primary_wep_menu(id);
    }
    else
    {
        secondary_wep_menu(id)
    }
    
    menu_destroy(menu);
    return PLUGIN_CONTINUE;
}

public secondary_wep_menu(id)
{
    new secmenu = menu_create("\rSecondary Weapon's Menu", "secondary_handler");
    
    menu_additem(secmenu, "\wDeagle", "1", 0)
    menu_additem(secmenu, "\wFive-Seven", "2", 0)
    menu_additem(secmenu, "\wGlock", "3", 0)
    menu_additem(secmenu, "\wElites", "4", 0)
    menu_additem(secmenu, "\wUSP 45", "5", 0)
    menu_additem(secmenu, "\wP228", "6", 0)
    
    menu_setprop( secmenu, MPROP_EXIT, MEXIT_ALL )
    menu_display( id, secmenu, 0 )
}

public secondary_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    new CsTeams:team = cs_get_user_team(id)
    if(team == CS_TEAM_T)
    {
        cs_set_user_armor(id, 50, CS_ARMOR_VESTHELM)
    }
    else
    {
        give_item(id, "item_thighpack")
    }
    switch(item)
    {
        case 0:
        {
            give_item(id, "weapon_deagle")
            cs_set_user_bpammo(id, CSW_DEAGLE, 35)
        }
        case 1:
        {
            give_item(id, "weapon_fiveseven")
            cs_set_user_bpammo(id, CSW_FIVESEVEN, 100)
        }
        case 2:
        {
            give_item(id, "weapon_glock18")
            cs_set_user_bpammo(id, CSW_GLOCK18, 100)
        }
        case 3:
        {
            give_item(id, "weapon_elite")
            cs_set_user_bpammo(id, CSW_ELITE, 120)
        }
        case 4:
        {
            give_item(id, "weapon_usp")
            cs_set_user_bpammo(id, CSW_USP, 100)
        }
        case 5:
        {
            give_item(id, "weapon_p228")
            cs_set_user_bpammo(id, CSW_P228, 52)
        }
    }
    return PLUGIN_HANDLED
}

public save_user_weapons(id)
{
    
}

public load_user_weapons(id)
{
    
} 


[KiLLeR.]

As I said in your another thread you don't need to save this in nVault. Later I will give you code.

Here is the code: (Read the comments)

Spoiler

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

enum _:wdata
{
    name[32],
    w_name[32],
    csw_id,
    bpammo
}

new primary_weapons[][wdata] =
{
    { "AWP", "weapon_awp", CSW_AWP, 30 },
    { "M4A1", "weapon_m4a1", CSW_M4A1, 90 },
    { "AK47", "weapon_ak47", CSW_AK47, 90 }
    // I was too lazy to add all weapons... you can do it by yourself, is not that hard.;-
};

new secondary_weapons[][wdata] =
{
    { "Deagle", "weapon_deagle", CSW_DEAGLE, 35 },
    { "Five-Seven", "weapon_fiveseven", CSW_FIVESEVEN, 100 },
    { "Glock18", "weapon_glock18", CSW_GLOCK18, 100 },
    { "Elite", "weapon_elite", CSW_ELITE, 120 },
    { "USP", "weapon_usp", CSW_USP, 100 },
    { "P228", "weapon_p228", CSW_P228, 52 }
};

const m_fHasPrimary = 116;

new bool:prim_wep_equiped[33], bool:menu_enabled[33], previous_equipment[3][33];

public plugin_init() 
{
    register_plugin("Equip Menu", "1.0", "KiLLeR ;]]");
    
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1);
}

public client_putinserver(id)
{
    // by default menu is enabled!
    menu_enabled[id] = true;
}

public fw_PlayerSpawn_Post(id)
{
    if(!is_user_alive(id) || is_user_bot(id))
        return PLUGIN_HANDLED;
    
    if(!(get_user_flags(id) & ADMIN_LEVEL_H))
        return PLUGIN_HANDLED;
    
    strip_user_weapons(id);
    give_item(id, "weapon_knife");
    
    //set_pdata_int(id, m_fHasPrimary, 0); // I'm not sure why did you use this?! Do you even know what it does?!
    
    if(menu_enabled[id])
    {
        prim_wep_equiped[id] = false;
        equip_menu(id);
    }
    else
    {
        give_previous_weapons(id);
    }
    
    return PLUGIN_CONTINUE;
}

public equip_menu(id)
{
    new menu = menu_create("Equip Menu", "equip_menu_handler")
    
    menu_additem(menu, "New Weapons", "1")
    menu_additem(menu, "Previous Weapons", "2")
    menu_additem(menu, "Save and don't show menu again", "3")
    
    menu_display(id, menu);
}

public equip_menu_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    switch(item)
    {
        case 0: primary_wep_menu(id);
        case 1: give_previous_weapons(id)
        case 2: menu_enabled[id] = false;
    }
    
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

public primary_wep_menu(id)
{
    new menu = menu_create("\rPrimary Weapon's Menu", "primary_wep_handler");
    
    new item[64], num[4];
    
    for(new i=0; i<sizeof primary_weapons; i++)
    {
        copy(item, charsmax(item), primary_weapons[i][name]);
        num_to_str(i, num, charsmax(num));
        menu_additem(menu, item, num);
    }
    
    menu_display(id, menu);
    
    return PLUGIN_CONTINUE;
}

public primary_wep_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new item_access, info[6], item_name[64], item_callback;
    menu_item_getinfo(menu, item, item_access, info, charsmax(info), item_name, charsmax(item_name), item_callback);
    
    new key = str_to_num(info);
    
    give_item(id, primary_weapons[key][w_name]);
    cs_set_user_bpammo(id, primary_weapons[key][csw_id], primary_weapons[key][bpammo]);
    
    if(!prim_wep_equiped[id])
    {
        prim_wep_equiped[id] = true;
        previous_equipment[0][id] = key;
        primary_wep_menu(id);
    }
    else
    {
        previous_equipment[1][id] = key; 
        secondary_wep_menu(id);
    }
    
    menu_destroy(menu);
    return PLUGIN_CONTINUE;
}

secondary_wep_menu(id)
{
    new menu = menu_create("\rSecondary Weapon's Menu", "secondary_wep_handler");
    
    new item[64], num[4];
    
    for(new i=0; i<sizeof secondary_weapons; i++)
    {
        copy(item, charsmax(item), secondary_weapons[i][name]);
        num_to_str(i, num, charsmax(num));
        menu_additem(menu, item, num);
    }
    
    menu_display(id, menu);
    
    return PLUGIN_CONTINUE;
}

public secondary_wep_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new item_access, info[6], item_name[64], item_callback;
    menu_item_getinfo(menu, item, item_access, info, charsmax(info), item_name, charsmax(item_name), item_callback);
    
    new key = str_to_num(info);
    
    previous_equipment[2][id] = key; 
    
    give_item(id, secondary_weapons[key][w_name]);
    cs_set_user_bpammo(id, secondary_weapons[key][csw_id], secondary_weapons[key][bpammo]);
    
    if(cs_get_user_team(id) == CS_TEAM_T)
    {
        cs_set_user_armor(id, 50, CS_ARMOR_VESTHELM)
    }
    else
    {
        give_item(id, "item_thighpack")
    }
    
    menu_destroy(menu);
    return PLUGIN_CONTINUE;
}

give_previous_weapons(id)
{
    give_item(id, primary_weapons[previous_equipment[0][id]][w_name]);
    cs_set_user_bpammo(id, primary_weapons[previous_equipment[0][id]][csw_id], primary_weapons[previous_equipment[0][id]][bpammo]);
    give_item(id, primary_weapons[previous_equipment[1][id]][w_name]);
    cs_set_user_bpammo(id, primary_weapons[previous_equipment[1][id]][csw_id], primary_weapons[previous_equipment[1][id]][bpammo]);
    give_item(id, primary_weapons[previous_equipment[2][id]][w_name]);
    cs_set_user_bpammo(id, primary_weapons[previous_equipment[2][id]][csw_id], primary_weapons[previous_equipment[2][id]][bpammo]);
    
    if(cs_get_user_team(id) == CS_TEAM_T)
    {
        cs_set_user_armor(id, 50, CS_ARMOR_VESTHELM)
    }
    else
    {
        give_item(id, "item_thighpack")
    }
}

Test and tell me if everything is okay.

[TheSpaniard]

Originally Posted by KiLLeR. As I said in your another thread you don't need to save this in nVault. Later I will give you code. //set_pdata_int(id, m_fHasPrimary, 0); // I'm not sure why did you use this?! Do you even know what it does?! Test and tell me if everything is okay.

You did it i didnt do it.

Previous weapons option works but save options doesn't work, i think you forgot to add option to enable guns menu again after saving.

[KiLLeR.]

Originally Posted by TheSpaniard You did it i didnt do it.

What do you mean!?

Originally Posted by TheSpaniard Previous weapons option works but save options doesn't work, i think you forgot to add option to enable guns menu again after saving.

What do you mean by save options doesn't work?! Because when you press that options you will recieve last selected equipment on every spawn and the menu won't show up anymore. (Or at least that's what I understand by saving your equipiment, and also that's how work in CSDM).

[TheSpaniard]

Originally Posted by KiLLeR. What do you mean!?

I mean the line you commented out is added by you, and you were right i don't even know whatever that means.

Originally Posted by KiLLeR. What do you mean by save options doesn't work?! Because when you press that options you will receive last selected equipment on every spawn and the menu won't show up anymore. (Or at least that's what I understand by saving your equipment, and also that's how work in CSDM).

The save option doesn't work when first selected after second spawn however it starts to work and after further use i spotted that the previous weapons option gives primary weapons but it doesn't give secondary weapon everything else is working fine thanks to you.

[KiLLeR.]

Originally Posted by TheSpaniard I mean the line you commented out is added by you, and you were right i don't even know whatever that means.

It was added by you, look at the code that you have given in first post... I only added constant with proper name instead of just some number because that's correct.

Originally Posted by TheSpaniard The save option doesn't work when first selected after second spawn however it starts to work and after further use i spotted that the previous weapons option gives primary weapons but it doesn't give secondary weapon everything else is working fine thanks to you.

I will test it. Hold on...
Here is the fixed version:

Spoiler

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define VIP_FLAG     ADMIN_LEVEL_H

enum _:wdata
{
    name[32],
    w_name[32],
    csw_id,
    bpammo
}

new primary_weapons[][wdata] =
{
    { "AWP", "weapon_awp", CSW_AWP, 30 },
    { "M4A1", "weapon_m4a1", CSW_M4A1, 90 },
    { "AK47", "weapon_ak47", CSW_AK47, 90 }
    // I was too lazy to add all weapons... you can do it by yourself, is not that hard.;-
};

new secondary_weapons[][wdata] =
{
    { "Deagle", "weapon_deagle", CSW_DEAGLE, 35 },
    { "Five-Seven", "weapon_fiveseven", CSW_FIVESEVEN, 100 },
    { "Glock18", "weapon_glock18", CSW_GLOCK18, 100 },
    { "Elite", "weapon_elite", CSW_ELITE, 120 },
    { "USP", "weapon_usp", CSW_USP, 100 },
    { "P228", "weapon_p228", CSW_P228, 52 }
};

new bool:prim_wep_equiped[33], bool:menu_enabled[33], previous_equipment[3][33];

public plugin_init() 
{
    register_plugin("Equip Menu", "1.0", "KiLLeR ;]]");
    
    // This command will re-enable the menu if someone choice 3rd options. If you wish change the command name.
    register_clcmd("say /enable", "clcmd_enable"); 
    register_clcmd("say_team /enable", "clcmd_enable");
    
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1);
}

public client_putinserver(id)
{
    // by default menu is enabled!
    menu_enabled[id] = true;
}

public clcmd_enable(id)
{
    if(!(get_user_flags(id) & VIP_FLAG))
        return PLUGIN_HANDLED;
    
    menu_enabled[id] = true;
    client_print(id, print_chat, "You have re-enabled your equpiment menu!");
    
    return PLUGIN_CONTINUE;
}

public fw_PlayerSpawn_Post(id)
{
    if(!is_user_alive(id) || is_user_bot(id))
        return PLUGIN_HANDLED;
    
    if(!(get_user_flags(id) & VIP_FLAG))
        return PLUGIN_HANDLED;
    
    strip_user_weapons(id);
    give_item(id, "weapon_knife");
    
    if(menu_enabled[id])
    {
        prim_wep_equiped[id] = false;
        equip_menu(id);
    }
    else
    {
        give_previous_weapons(id);
    }
    
    return PLUGIN_CONTINUE;
}

public equip_menu(id)
{
    new menu = menu_create("Equip Menu", "equip_menu_handler")
    
    menu_additem(menu, "New Weapons", "1")
    menu_additem(menu, "Previous Weapons", "2")
    menu_additem(menu, "Save and don't show menu again", "3")
    
    menu_display(id, menu);
}

public equip_menu_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    switch(item)
    {
        case 0: primary_wep_menu(id);
        case 1: give_previous_weapons(id)
        case 2:
        {   
            menu_enabled[id] = false;
            give_previous_weapons(id);
        }
    }
    
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

public primary_wep_menu(id)
{
    new menu = menu_create("\rPrimary Weapon's Menu", "primary_wep_handler");
    
    new item[64], num[4];
    
    for(new i=0; i<sizeof primary_weapons; i++)
    {
        copy(item, charsmax(item), primary_weapons[i][name]);
        num_to_str(i, num, charsmax(num));
        menu_additem(menu, item, num);
    }
    
    menu_display(id, menu);
    
    return PLUGIN_CONTINUE;
}

public primary_wep_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new item_access, info[6], item_name[64], item_callback;
    menu_item_getinfo(menu, item, item_access, info, charsmax(info), item_name, charsmax(item_name), item_callback);
    
    new key = str_to_num(info);
    
    give_item(id, primary_weapons[key][w_name]);
    cs_set_user_bpammo(id, primary_weapons[key][csw_id], primary_weapons[key][bpammo]);
    
    if(!prim_wep_equiped[id])
    {
        prim_wep_equiped[id] = true;
        previous_equipment[0][id] = key;
        primary_wep_menu(id);
    }
    else
    {
        previous_equipment[1][id] = key; 
        secondary_wep_menu(id);
    }
    
    menu_destroy(menu);
    return PLUGIN_CONTINUE;
}

secondary_wep_menu(id)
{
    new menu = menu_create("\rSecondary Weapon's Menu", "secondary_wep_handler");
    
    new item[64], num[4];
    
    for(new i=0; i<sizeof secondary_weapons; i++)
    {
        copy(item, charsmax(item), secondary_weapons[i][name]);
        num_to_str(i, num, charsmax(num));
        menu_additem(menu, item, num);
    }
    
    menu_display(id, menu);
    
    return PLUGIN_CONTINUE;
}

public secondary_wep_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new item_access, info[6], item_name[64], item_callback;
    menu_item_getinfo(menu, item, item_access, info, charsmax(info), item_name, charsmax(item_name), item_callback);
    
    new key = str_to_num(info);
    
    previous_equipment[2][id] = key; 
    
    give_item(id, secondary_weapons[key][w_name]);
    cs_set_user_bpammo(id, secondary_weapons[key][csw_id], secondary_weapons[key][bpammo]);
    
    if(cs_get_user_team(id) == CS_TEAM_T)
    {
        cs_set_user_armor(id, 50, CS_ARMOR_VESTHELM)
    }
    else
    {
        give_item(id, "item_thighpack")
    }
    
    menu_destroy(menu);
    return PLUGIN_CONTINUE;
}

give_previous_weapons(id)
{
    give_item(id, primary_weapons[previous_equipment[0][id]][w_name]);
    cs_set_user_bpammo(id, primary_weapons[previous_equipment[0][id]][csw_id], primary_weapons[previous_equipment[0][id]][bpammo]);
    give_item(id, primary_weapons[previous_equipment[1][id]][w_name]);
    cs_set_user_bpammo(id, primary_weapons[previous_equipment[1][id]][csw_id], primary_weapons[previous_equipment[1][id]][bpammo]);
    give_item(id, secondary_weapons[previous_equipment[2][id]][w_name]);
    cs_set_user_bpammo(id, secondary_weapons[previous_equipment[2][id]][csw_id], secondary_weapons[previous_equipment[2][id]][bpammo]);
    
    if(cs_get_user_team(id) == CS_TEAM_T)
    {
        cs_set_user_armor(id, 50, CS_ARMOR_VESTHELM)
    }
    else
    {
        give_item(id, "item_thighpack")
    }
}

[TheSpaniard]

Originally Posted by KiLLeR. It was added by you, look at the code that you have given in first post... I only added constant with proper name instead of just some number because that's correct.

First code is also given by you look in the other thread where i asked the same question.
and you forgot the command to reenable the menu after selecting the save option.
like
say /guns to display the menu again

[KiLLeR.]

Originally Posted by TheSpaniard First code is also given by you look in the other thread where i asked the same question. and you forgot the command to reenable the menu after selecting the save option. like say /guns to display the menu again

Look the above post, I have fixed the problem and added command to re-enable the menu.
Also look at this: https://imgur.com/a/x2xLe, this is your first code before my posts in the another thread. So it wasn't added by me.... Anyway I have removed it from the fixed version (above).