[trannygranny]

#include <sourcemod>
#include <sdkhooks>
#include <sdktools_functions>

public Plugin:myinfo = 
{
    name = "Give Healthshot",
    description = "Gives a healthshot to all players every round."
}

public OnPluginStart()
{
    HookEvent( "player_spawn", SpawnEvent );
}

public Action:SpawnEvent(Handle:event,const String:name[],bool:dontBroadcast)
{
	new client_id = GetEventInt(event, "userid");
	new client = GetClientOfUserId(client_id);
	ServerCommand( "sm_giveweapon %i weapon_healthshot", client );
	ServerCommand( "sm_giveweapon %i healthshot", client );
}

Anyone know why this isn't working?

[Fyren]

If whatever plugin provides that functionality just uses ProcessTargetString, then it won't understand cliend IDs and you use should use the user ID prefixed by #.

If that plugin provides natives (which it does, from Googling), you should absolutely use them and not ServerCommand.

If you have a specific question about that other plugin, you should ask in its thread.

[LenHard]

PHP Code:

#include <sourcemod>
#include <sdktools_functions>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("player_spawn", Event_PlayerSpawn, EventHookMode_Post);
}

public void Event_PlayerSpawn(Event hEvent, const char[] sEventName, bool bDontBroadcast)
{
    int iUser = hEvent.GetInt("userid");

    if (IsClientInGame(GetClientOfUserId(iUser))) {
        CreateTimer(0.7, Timer_Delay, iUser); // Delay to be safe
    }
}

public Action Timer_Delay(Handle hTimer, int iUser)
{
    int client = GetClientOfUserId(iUser);
    
    if (IsClientInGame(client)) {
        GivePlayerItem(client, "weapon_healthshot");
    }
} 


Try this

[ThatKidWhoGames]

Originally Posted by LenHard PHP Code: #include <sourcemod> #include <sdktools_functions> #pragma semicolon 1 #pragma newdecls required public void OnPluginStart() {     HookEvent("player_spawn", Event_PlayerSpawn, EventHookMode_Post); } public void Event_PlayerSpawn(Event hEvent, const char[] sEventName, bool bDontBroadcast) {     int iUser = hEvent.GetInt("userid");     if (IsClientInGame(GetClientOfUserId(iUser))) {         CreateTimer(0.7, Timer_Delay, iUser); // Delay to be safe     } } public Action Timer_Delay(Handle hTimer, int iUser) {     int client = GetClientOfUserId(iUser);          if (IsClientInGame(client)) {         GivePlayerItem(client, "weapon_healthshot");     } }  Try this

If this is for TF2, when a player touches the resupply locker, they will lose the weapon and not get it back. You need to hook post_inventory _application instead and get rid of the timer. If this is not for TF2, completely disregard this post.

[Psyk0tik]

Originally Posted by LenHard PHP Code: #include <sourcemod> #include <sdktools_functions> #pragma semicolon 1 #pragma newdecls required public void OnPluginStart() {     HookEvent("player_spawn", Event_PlayerSpawn, EventHookMode_Post); } public void Event_PlayerSpawn(Event hEvent, const char[] sEventName, bool bDontBroadcast) {     int iUser = hEvent.GetInt("userid");     if (IsClientInGame(GetClientOfUserId(iUser))) {         CreateTimer(0.7, Timer_Delay, iUser); // Delay to be safe     } } public Action Timer_Delay(Handle hTimer, int iUser) {     int client = GetClientOfUserId(iUser);          if (IsClientInGame(client)) {         GivePlayerItem(client, "weapon_healthshot");     } }  Try this

Shorten the code up a bit like this:

PHP Code:

#include <sourcemod>
#include <sdktools_functions>
#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("player_spawn", Event_PlayerSpawn, EventHookMode_Post);
}

public void Event_PlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
    int iUser = GetClientOfUserId(event.GetInt("userid"));
    if (IsClientInGame(iUser))
    {
        CreateTimer(0.7, Timer_Delay, iUser); // Delay to be safe
    }
}

public Action Timer_Delay(Handle timer, any client)
{
    if (IsClientInGame(client))
    {
        GivePlayerItem(client, "weapon_healthshot");
    }
} 


[ThatKidWhoGames]

Originally Posted by Crasher_3637 Shorten the code up a bit like this: PHP Code: #include <sourcemod> #include <sdktools_functions> #pragma semicolon 1 #pragma newdecls required public void OnPluginStart() {     HookEvent("player_spawn", Event_PlayerSpawn, EventHookMode_Post); } public void Event_PlayerSpawn(Event event, const char[] name, bool dontBroadcast) {     int iUser = GetClientOfUserId(event.GetInt("userid"));     if (IsClientInGame(iUser))     {         CreateTimer(0.7, Timer_Delay, iUser); // Delay to be safe     } } public Action Timer_Delay(Handle timer, any client) {     if (IsClientInGame(client))     {         GivePlayerItem(client, "weapon_healthshot");     } }

PHP Code:

#include <sourcemod>
#include <sdktools_functions>
#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("player_spawn", Event_PlayerSpawn);
}

public void Event_PlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
    int userid = event.GetInt("userid"), client = GetClientOfUserId(userid);
    if (IsValidClient(client))
    {
        CreateTimer(0.7, Timer_Delay, userid); // Delay to be safe
    }
}

public Action Timer_Delay(Handle timer, any userid)
{
    int client = GetClientOfUserId(userid);
    if (IsValidClient(client))
    {
        GivePlayerItem(client, "weapon_healthshot");
    }
}

bool IsValidClient(int client)
{
    return client > 0 && client <= MaxClients && IsClientInGame(client);
} 


Added a proper valid client check. I believe IsClientInGame still counts the console. Also, the event mode defaults to post so I got rid of that.

[shanapu]

don't pass clientIDs through timers, always use userIDs

[ThatKidWhoGames]

Originally Posted by shanapu don't pass clientIDs through timers, always use userIDs

Out of curiosity, why is that? I've seen people say that before. Is it to make sure the correct player you are trying to target is affected?

[shanapu]

Originally Posted by ThatKidWhoGames Out of curiosity, why is that? I've seen people say that before. Is it to make sure the correct player you are trying to target is affected?

yes, when the timer (or Request Frame) runs the client could disconnect and a new player could join and get the same clientID.

[ThatKidWhoGames]

Originally Posted by shanapu yes, when the timer (or Request Frame) runs the client could disconnect and a new player could join and get the same clientID.

Thanks for the info! As such, I have updated my post with the code to use the userid instead of the client's id.