[cen0x]

Heya,

I want to remove the Teamattack message for cs;go but I cant found how it works. I tried already PreHook and change the Broadcast bool but its not work. Does anyone know how it works?

regards
cen0x

[Leonardo]

Not sure if it'll work in cago, but in older games you could simply block a specific chat text ('SayText' or 'SayText2' usermessage) coming from user #0

[cen0x]

I have no idea how to solve it^^

[Dkmuniz]

PHP Code:

public Action:Event_TextMsg(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{

    decl String:text[64];
    if (GetUserMessageType() == UM_Protobuf)
        PbReadString(bf, "params", text, sizeof(text), 0);
    else
        BfReadString(bf, text, sizeof(text));
    
    if (StrContains(text, "#SFUI_Notice_Killed_Teammate") != -1)
        return Plugin_Handled;
    
    if (StrContains(text, "#Cstrike_TitlesTXT_Game_teammate_attack") != -1)
        return Plugin_Handled;
    
    if (StrContains(text, "#Hint_try_not_to_injure_teammates") != -1)
        return Plugin_Handled;

    return Plugin_Continue;
}

public Action:Event_HintText(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{

    decl String:text[64];
    if (GetUserMessageType() == UM_Protobuf)
        PbReadString(bf, "text", text, sizeof(text));
    else
        BfReadString(bf, text, sizeof(text));

    if (StrContains(text, "#SFUI_Notice_Hint_careful_around_teammates") != -1)
        return Plugin_Handled;

    return Plugin_Continue;
} 


PHP Code:

public OnPluginStart()
{
HookUserMessage(GetUserMessageId("TextMsg"), Event_TextMsg, true);
HookUserMessage(GetUserMessageId("HintText"), Event_HintText, true);

} 


[cen0x]

It works, thank u.