[Solved] [CS:GO] Plugin Crashing Server - Need help!

Di3Z1E · **Author**

Hey,
I made a plugin that supposed to allow players to make a vote for Headshots only in-game.
Code compiled with 1 warning, but crashing the server...

disclaimer:
i'm not pro, just a dude who plays around and sometimes make tiny cool stuff

PHP Code:


			
#include <sourcemod>

#include <sdkhooks>

#include <colors_csgo>



public Plugin myinfo =

{

    name = "HS Mode Only Via Vote",

    author = "Di3Z1E",

    description = "Allowing the players to initiate a vote for Headshots Only.",

    version = "1.00",

    url = ""

};



bool votedone=false;

int countyes=0;

int countno=0;







public void OnPluginStart()

{

    RegConsoleCmd("sm_hso", Command_HSonly, "Start Vote For Head Shot Mode Only");

}



public Action Command_HSonly(int client, int args)

{

     

    PrintToChat(client, " \x10[המחתרת]\x01 Launched HS Mode Only Vote!")

    return Plugin_Handled;

}  



public Action votemenu(int client, int args)

{

    char menuinfo[255];

    Format(menuinfo, sizeof(menuinfo), "Activate Only Headshots mode?", client);

    Menu hsonly = new Menu(votemenuhs);

    hsonly.SetTitle(menuinfo);

    

    Format(menuinfo, sizeof(menuinfo), "Yes", client);

    hsonly.AddItem("yes", menuinfo);

    

    Format(menuinfo, sizeof(menuinfo), "No", client);

    hsonly.AddItem("no", menuinfo);

    

    hsonly.ExitButton = true;

    hsonly.Display(client, MENU_TIME_FOREVER);

    return Plugin_Handled;

}





public int votemenuhs(Menu hsonly, MenuAction action, int client, int selection)

{

    char info[32];

    hsonly.GetItem(selection, info, sizeof(info));

    

    if (strcmp(info, "yes") == 0)

    {

        countyes++;

    }

    

    else if (strcmp(info, "no") == 0)

    {

        countno++;

    }

    else if (action == MenuAction_End)

    {

        delete hsonly;

    }

    

    if (countyes>(countno+countyes)/2)

    {

        ServerCommand("sm_rcon mp_damage_headshot_only 1");

        votedone=true;

    }

    else if (countno>(countno+countyes/2))

    {

        ServerCommand("sm_rcon mp_damage_headshot_only 0");

        votedone=true;

    }

}





public void OnMapStart()

{

    votedone=false;

    countno=0;

    countyes=0;

}

edit:
set it to php instead of code

8guawong · 12-27-2018 , 17:31 Re: [CS:GO] Plugin Crashing Server - Need help!

And what makes you think it was this plugin that crashes the server?

Di3Z1E · 12-27-2018 , 17:53 Re: [CS:GO] Plugin Crashing Server - Need help!

Quote:

Originally Posted by 8guawong

And what makes you think it was this plugin that crashes the server?

When i put it in the server it crash, when i put it out back the server works fine...

Starbish · *Last edited by Starbish; 12-27-2018 at 19:31.*

PHP Code:


			
    Format(menuinfo, sizeof(menuinfo), "Yes", client);

PHP Code:


			
    Format(menuinfo, sizeof(menuinfo), "No", client);

I think these are not valid use... but i also don't think it crashed server

Bacardi · 12-27-2018 , 20:30 Re: [CS:GO] Plugin Crashing Server - Need help!

You are creating normal menu instead vote menu.

However, when you create menu, you make it work with default menu actions.
(MenuAction_Select|MenuAction_Cancel|MenuActi on_End)

So, menu Handler is called on those menu actions, Handle will work more than once, remember.

And in each menu action, param1 and param2 have own meaning.
param1 is not always client index, param2 is not everytime selection.
https://sm.alliedmods.net/new-api/menus/__raw

That is your problem, you are using param1 and param2 wrong.

Here wiki to create vote
https://wiki.alliedmods.net/Menu_API...d)#Simple_Vote

8guawong · *Last edited by 8guawong; 12-28-2018 at 03:14.*

Quote:

Originally Posted by Di3Z1E

When i put it in the server it crash, when i put it out back the server works fine...

so does the server crash when you load the plugin?

step to test it

1. put your plugin in the disabled folder
2. after server starts do sm plugins load disabled/blah.smx

Di3Z1E · 12-29-2018 , 20:27 Re: [CS:GO] Plugin Crashing Server - Need help!

Quote:

Originally Posted by Bacardi

You are creating normal menu instead vote menu.

However, when you create menu, you make it work with default menu actions.
(MenuAction_Select|MenuAction_Cancel|MenuActi on_End)

So, menu Handler is called on those menu actions, Handle will work more than once, remember.

And in each menu action, param1 and param2 have own meaning.
param1 is not always client index, param2 is not everytime selection.
https://sm.alliedmods.net/new-api/menus/__raw

That is your problem, you are using param1 and param2 wrong.

Here wiki to create vote
https://wiki.alliedmods.net/Menu_API...d)#Simple_Vote

So i created this:

PHP Code:


			
#pragma semicolon 1



#define PLUGIN_AUTHOR "Di3Z1E"

#define PLUGIN_VERSION "1.00"



#include <sourcemod>

#include <sdktools>

#include <cstrike>





public Plugin myinfo = 

{

    name = "Headshot Only", 

    author = PLUGIN_AUTHOR, 

    description = "Allowing Players To Vote For Only Headshot Mode.", 

    version = PLUGIN_VERSION, 

    url = ""

};



public void OnPluginStart()

{

    RegConsoleCmd("sm_hs", Command_HS, "Run vote for Headshot only mode.");

}



    

void DoVoteMenu(args)

{

        if (IsVoteInProgress())

    {

        return;

    }    

    Menu menu = new Menu(Command_HS);

    menu.SetTitle("Activate only Headshots mode?");

    menu.AddItem("yes", "Yes", param1);

    menu.AddItem("no", "No", param2);

    menu.ExitButton = false;

    menu.DisplayVoteToAll(60);

}     

    

public int Command_HS(Menu menu, MenuAction action, int param1, int param2)

{

        if (action == MenuAction_End)

        {

            

            delete menu;

        }

        else if (action == MenuAction_VoteEnd)

        {

            

            if (param1 == 0)

            {

                menu.GetItem(param1);

                ServerCommand("sm_rcon mp_damage_headshot_only 1");

            }

            if (param2 == 1)

            {

                menu.GetItem(param2);

                ServerCommand("sm_rcon mp_damage_headshot_only 0");

            }

        }

}

And i got this:

PHP Code:


			
// E:\Counter Strike Global Offenisve\_Di3Z1E Plugins\Headshot Only Mode.sp(22) : error 100: function prototypes do not match

// E:\Counter Strike Global Offenisve\_Di3Z1E Plugins\Headshot Only Mode.sp(52) : error 092: number of arguments does not match definition

// E:\Counter Strike Global Offenisve\_Di3Z1E Plugins\Headshot Only Mode.sp(57) : error 092: number of arguments does not match definition

// E:\Counter Strike Global Offenisve\_Di3Z1E Plugins\Headshot Only Mode.sp(26) : warning 203: symbol is never used: "DoVoteMenu"

any help ?

Cruze · 12-30-2018 , 01:09 Re: [CS:GO] Plugin Crashing Server - Need help!

PHP Code:


			
#pragma semicolon 1 
#pragma newdecls required

#define PLUGIN_AUTHOR "Di3Z1E" 
#define PLUGIN_VERSION "1.01" 

#include <sourcemod>

#define SERVERTAG " [SM]"

public Plugin myinfo =  
{ 
    name = "Headshot Only",  
    author = PLUGIN_AUTHOR,  
    description = "Allowing Players To Vote For Only Headshot Mode.",  
    version = PLUGIN_VERSION,  
    url = "" 
}; 

public void OnPluginStart() 
{ 
    RegConsoleCmd("sm_hs", Command_HS, "Run vote for Headshot only mode."); 
} 

public Action Command_HS(int client, int args)
{
    if (IsVoteInProgress()) 
    { 
        PrintToChat(client, "%s Retry when to no vote is on progress!", SERVERTAG);
        return Plugin_Handled;
    } 
    DoVoteMenu();
    return Plugin_Handled;
}

void DoVoteMenu() 
{     
    Menu menu = new Menu(Handle_HS); 
    menu.SetTitle("Activate only Headshots mode?"); 
    menu.AddItem("", "Yes"); 
    menu.AddItem("", "No"); 
    menu.ExitButton = false; 
    menu.DisplayVoteToAll(60); 
}      

public int Handle_HS(Menu menu, MenuAction action, int param1, int param2)
{ 
    if (action == MenuAction_End)
    {
        delete menu;
    }
    else if (action == MenuAction_VoteEnd)
    {
        if (param1 == 0)
        {
            if(GetConVarBool(FindConVar("mp_damage_headshot_only")) == false)
            {
                SetConVarBool(FindConVar("mp_damage_headshot_only"), true);
                PrintToChatAll("%s Headshot only mode is turned\x04ON.\x01", SERVERTAG);
            }
            else
            {
                PrintToChatAll("%s Headshot only mode is already turned \x04ON.\x01", SERVERTAG);
            }
        }
        else
        {
            if(GetConVarBool(FindConVar("mp_damage_headshot_only")) == true)
            {
                SetConVarBool(FindConVar("mp_damage_headshot_only"), false);
                PrintToChatAll("%s Headshot only mode is turned \x07OFF.\x01", SERVERTAG);
            }
            else
            {
                PrintToChatAll("%s Headshot only mode is already turned \x07OFF.\x01", SERVERTAG);
            }
        }
    }
}

Try this

Di3Z1E · 12-30-2018 , 07:22 Re: [CS:GO] Plugin Crashing Server - Need help!

Quote:

Originally Posted by Cruze

PHP Code:


			
#pragma semicolon 1 



#define PLUGIN_AUTHOR "Di3Z1E" 

#define PLUGIN_VERSION "1.00" 



#include <sourcemod> 

#include <sdktools> 

#include <cstrike>



#pragma newdecls required



public Plugin myinfo =  

{ 

    name = "Headshot Only",  

    author = PLUGIN_AUTHOR,  

    description = "Allowing Players To Vote For Only Headshot Mode.",  

    version = PLUGIN_VERSION,  

    url = "" 

}; 



public void OnPluginStart() 

{ 

    RegConsoleCmd("sm_hs", Command_HS, "Run vote for Headshot only mode."); 

} 



public Action Command_HS(int client, int args)

{

    if (IsVoteInProgress()) 

    { 

        PrintToChat(client, "[SM] Retry when no vote is on progress!");

        return Plugin_Handled;

    } 

    DoVoteMenu();

    return Plugin_Handled;

}



void DoVoteMenu() 

{     

    Menu menu = new Menu(Handle_HS); 

    menu.SetTitle("Activate only Headshots mode?"); 

    menu.AddItem("", "Yes"); 

    menu.AddItem("", "No"); 

    menu.ExitButton = false; 

    menu.DisplayVoteToAll(60); 

}      

     

public int Handle_HS(Menu menu, MenuAction action, int param1, int param2)

{ 

    if (action == MenuAction_End)

    {

        delete menu;

    }

    else if (action == MenuAction_VoteEnd)

    {

        if (param1 == 0)

        {

            if(GetConVarBool(FindConVar("mp_damage_headshot_only")) == false)

            {

                SetConVarBool(FindConVar("mp_damage_headshot_only"), true);

                PrintToChatAll("[SM] HS ONLY MODE ENABLED.");

            }

            else

            {

                PrintToChatAll("[SM] HS ONLY MODE IS ALREADY ENABLED.");

            }

        }

        else

        {

            if(GetConVarBool(FindConVar("mp_damage_headshot_only")) == true)

            {

                SetConVarBool(FindConVar("mp_damage_headshot_only"), false);

                PrintToChatAll("[SM] HS ONLY MODE DISABLED.");

            }

            else

            {

                PrintToChatAll("[SM] HS ONLY MODE IS ALREADY DISABLED.");

            }

        }

    }

}

Try this

Thank you, it works!

Cruze · 12-30-2018 , 07:36 Re: [CS:GO] Plugin Crashing Server - Need help!

Quote:

Originally Posted by Di3Z1E

Thank you, it works!

No Probs

. Edited my comment. Check edit reason to know what all I changed.