[firefist235]

Hi all,
i use SM_Gungame with GGDM on my CS:S Server. Dead players respawn after death like they should, but always at default points, or those points preset in /cstrike/cfg/ggdm/spawns.
Is there a way to randomize spawn points, because i don't like to make a spawn-point file for every single map.
A few years ago i ran several css servers, on of them used Smartspawn for Mattie Eventscipts. This plugin automatically saved potential spawn points while the map was running.

Is there something similar for SM?

[101]

what is the point of [Random SpawnPoints] ?
its not a good idea to spawn players randomly right "behind enemy lines" or nearby the enemy location , its acceptable for fun gameplay but its hard to be accepted in competitive matches .

can you describe more about this mod ?
* i can help with generation random spawn points , but I can't guarantee they will be spawned in a safe place *

[firefist235]

Its meant for my Gungame Server, so it is definitely no competitive ;D
I managed to write a small script, that logs human player locations every x seconds and y meters unto a certain amount into a file that CSSM can use as spawn points.
But thank you for your offer

[101]

its not an offer , its some kind of 'knowledge generating' .
btw . while you were able to generate random spawn points based on x seconds and y meters [which is amazing method] , then why do you need to store these points in txt file ? and why you want another plugin to use that txt file ?
I mean : In your own script , you can teleport players to a random location directly once they are spawned without using any complex trick .

PHP Code:

OnPlayerSpawn(int client)
{
    TeleportEntity( client , RandomPos , NULL_VECTOR , NULL_VECTOR);
} 


so you don't need to save a txt file then asking another plugin to use that file [which is complex] .

but you have to avoid :
* saving points when the player is currently crawling under a short ceil , climbing a ladder , falling .
* teleproting more than one player at the same moment to the same location , which will lead to freeze them (collision) , so they won't be able to move .

did you manage that ?

[firefist235]

The script already only add spawnpoints when the player is on ground and not crouching.
I like the way CSSM works, thats why i save the spawns in a txt file CSSM can use.

EDIT: now i remember why i prefer CSSDM over Gungames built-in DM: CSSDM can handle bot quota better.

[101]

I can't understand the reason of your request !

- While you were able to generate random points , So I believe that you can save them in a txt file automatically without the need of hand typing!
- You can either edit the source code of 'CSSDM' by managing the part where the plugin is trying to read that txt file , then replace that function with a direct supply of your coordinates [those that was generated based on x seconds and y meters].

Anyway , If you want to dive alone and get independent of that sticky 'CSSDM' :


[ANY] Dynamic/Random Spawnpoints

PHP Code:

#include <sdktools>

#define Timer_Interval    5.0
#define POINTS_LIMIT    200
#define Cubit            50.0


Handle hTimer[MAXPLAYERS+1];
float RandomPos[POINTS_LIMIT][3];
int count;
bool safepoint[MAXPLAYERS+1];

public OnPluginStart(){
    HookEvent("player_spawn", event_player_spawn , EventHookMode_Post);
}

public event_player_spawn(Handle event, char[] event_name, bool dontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(event, "userid"));

    if (!IsValidHandle(hTimer[client]))
        hTimer[client] = CreateTimer(Timer_Interval ,Timer_Scan ,client, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);

    if (count){ // your array is carrying some points
        safepoint[client] = true;    
        int rand = GetRandomInt(0,count-1);
        TR_EnumerateEntitiesSphere(RandomPos[rand] , Cubit , PARTITION_NON_STATIC_EDICTS, Entities_Nearby_Enumerator, client);

        if ( safepoint[client] )
            TeleportEntity( client , RandomPos[rand] , NULL_VECTOR , NULL_VECTOR);
        else
            PrintToChat(client , "failed to teleport");
    }
}

public Action Timer_Scan(Handle timer , any client){
    if (count < POINTS_LIMIT){
        if (IsWalking(client) && !UnderCeil(client) )
            GetClientAbsOrigin(client , RandomPos[count++]);
        else
            PrintToChat(client , "failed to save point");
        return Plugin_Continue;
    }
    return Plugin_Stop;
}

public OnClientDisconnect(int client){
    if (IsValidHandle(hTimer[client]))
        KillTimer(hTimer[client]);
}

public OnMapEnd(){
    char CMap[32];
    GetCurrentMap(CMap, 32);
    LogMessage("%s Valid Spawn Positions :" , CMap);
    for (int i=0 ; i<count ; i++)
        LogMessage("[%f , %f , %f]" , RandomPos[i][0] , RandomPos[i][1] , RandomPos[i][2]);
    count = 0;
}

bool Entities_Nearby_Enumerator(int entity, int client){
    return (safepoint[client] = entity < 1 || entity > MaxClients);    // if true , the fucntion will continue enumerating the surrounded entities until it finds a valid player [so false means : stop enumerating]
}

bool UnderCeil(client){
    static float pos1[3],pos2[3];
    GetClientEyePosition(client , pos1);
    pos2[0] = pos1[0];
    pos2[1] = pos1[1];
    pos2[2] = pos1[2] + Cubit;
    TR_TraceRay(pos1, pos2, MASK_SOLID , RayType_EndPoint);
    return TR_DidHit();
}

bool IsWalking(int client){
    return ( (GetEntityMoveType(client) == MOVETYPE_WALK) && GetVelocity(client) > 0 ) 
}

stock float GetVelocity(int client){
    static float vel[3];
    GetEntPropVector(client, Prop_Data, "m_vecAbsVelocity", vel);
    return GetVectorLength(vel);
} 


[firefist235]

It seems I didn’t express myself clearly. At the time of my first post, I was looking for such a plugin, hoping that one already existed. However, I managed to write one myself, and it works quite well. I also moved away from CSSDM since it stopped working after the last update and am now using the built-in GGDM of the GunGame plugin. It works great; I just had to change the path in my plugin. So, it wasn’t necessary for you to write a plugin for me. Still, very very kind of you. I apologize if that wasn’t clear.