[claudiuhks]

I found a new way to remove the dropped weapons and I think it's usefully.

PHP Code:

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

public plugin_init( )
{
  RegisterHam( Ham_Think, "weaponbox", "OnThink", 1 );
  RegisterHam( Ham_Think, "weapon_shield", "OnThink", 1 );

  register_forward( FM_SetModel, "OnSetModel", 1 );
}

public OnThink( iEntity )
  engfunc( EngFunc_RemoveEntity, iEntity );

public OnSetModel( iEntity )
{
  if( pev_valid( iEntity ) )
  {
    static szClass[ 32 ];
    pev( iEntity, pev_classname, szClass, 31 );

    if( equal( szClass, "weaponbox" ) || equal( szClass, "weapon_shield" ) )
      set_pev( iEntity, pev_nextthink, get_gametime( ) + 0.1 );
  }
} 


[Arkshine]

Sorry, but that's not new thinking the weaponbox to remove it. You can see such code anyway in the HLSDK.

https://forums.alliedmods.net/showth...move+weaponbox
https://forums.alliedmods.net/showth...move+weaponbox
etc..

[jim_yang]

best way is to patch mem using orpheu
packPlayerItem set think with CWeaponBox::Kill and set nextthink time to gametime + 300.0, you just need to change 300.0 to 0.1, then let ::Kill function remove it soon.
another place is PlayerDrop

[Arkshine]

Yes, it would be more efficient though not sure it would be worth and best way because you would need to patch in 3 locations : packPlayerItem(), CBasePlayer::DropPlayerItem() and CBasePlayer::DropShield(). You can't just trying replacing some value through all the library, you would need to base from the start of the functions. But none are virtual functions thus you would need to make signatures (at least for windows) and that vs SetModel (for example), the latter would be recommended because much more simple, signatures are not that reliable and the difference in efficiently is trivial.

EDIT : For the fun, here an example :

#include <amxmodx>
#include <orpheu>
#include <orpheu_memory>
#include <orpheu_advanced>

enum Function { packPlayerItem, DropPlayerItem, DropShield };

public plugin_init()
{
    register_plugin( "Dropped Weapons Killer", "1.0.0", "Arkshine" );
    
    patch( packPlayerItem, OrpheuGetFunctionAddress( OrpheuGetFunction( "packPlayerItem" ) ) );
    patch( DropPlayerItem, OrpheuGetFunctionAddress( OrpheuGetFunction( "DropPlayerItem", "CBasePlayer" ) ) );
    patch( DropShield    , OrpheuGetFunctionAddress( OrpheuGetFunction( "DropShield"    , "CBasePlayer" ) ) );
}

public plugin_end()
{
    patch( packPlayerItem, .undo = true );
    patch( DropPlayerItem, .undo = true );
    patch( DropShield    , .undo = true );
}

patch( const Function:currentFunction, startAddress = 0, const bool:undo = false )
{
    const Float:originalValue = 300.0;
    const Float:newValue      = 0.1;
    
    static SavedAddress[ Function ];
    
    undo ? OrpheuMemorySetAtAddress( SavedAddress[ currentFunction ], "float", 1, originalValue ) :
           OrpheuMemoryReplaceAtAddress( startAddress, "float", 1, originalValue, newValue, SavedAddress[ currentFunction ] );
}

Note: Unzip the content in ./amxmodx/ directory.

[Doc-Holiday]

PHP Code:


    RegisterHam(Ham_Spawn, "weaponbox", "fwdWeaponDrop", 1); //Weapon box spawn
    RegisterHam(Ham_Spawn, "armoury_entity", "fwdWeaponDrop", 1); //Armor entity Spawn

public fwdWeaponDrop(iEnt)
{    
    if(pev_valid(iEnt))
    {
        set_task(0.5, "RemoveWeapons", iEnt);
    }
}

public RemoveWeapons(iEnt)
{
    if(pev_valid(iEnt))
    {
        new szModelName[32];
        pev(iEnt, pev_model, szModelName, charsmax(szModelName));
        
        if(containi(szModelName, "backpack") == -1)
        {
            set_pev(iEnt, pev_flags, FL_KILLME);
            ExecuteHam(Ham_Think, iEnt);
        }
    }
} 


This is how i do it in my battlefield plugin it doesnt remove thighpacks ofc.

[bibu]

I don't think that a task is required.

[Doc-Holiday]

Originally Posted by bibu I don't think that a task is required.

yup... tested both ways... i guess the mdl isnt set by the time the weapon drops there for it still removes the backpack.. but that task... allows you to also leave weapons on the floor for x amount of time before they are removed.. also tested.. but requires more code. (weapon pickup to remove the task on that specific weapon)

[Doc-Holiday]

The above code of mine tweaked a bit to work for thighpack also
The above code of mine tweaked a bit to work for thighpack also

PHP Code:

RegisterHam(Ham_Touch, "item_thighpack", "RemoveWeapons", 1);//Rmoves Thighpack
    RegisterHam(Ham_Touch, "weaponbox", "RemoveWeapons", 1); //Weapon box spawn
    RegisterHam(Ham_Touch, "armoury_entity", "RemoveWeapons", 1); //Armor entity Spawn

public RemoveWeapons(iEnt)
{
    if(pev_valid(iEnt))
    {
        new szModelName[32];
        pev(iEnt, pev_model, szModelName, charsmax(szModelName));
        
        if(containi(szModelName, "backpack") == -1)
        {
            set_pev(iEnt, pev_flags, FL_KILLME);
            ExecuteHam(Ham_Think, iEnt);
        }
    }
}