[fezh]

PHP Code:

#include <amxmodx>

// Here is the name of all "buy weapons" commands of CS, took from CS Weapons Information (AM Wiki).
// Is a tridimensional array because I'm going to use it in a loop, but actually this is not necessary,
// you can register all commands separately, but I think this is the easier & clean way to do it.
new gBuyCommands[][] = 
{
     "usp", "glock", "deagle", "p228", "elites", "fn57", "m3", "xm1014", "mp5", "tmp", "p90", "mac10", "ump45", "ak47", 
    "galil", "famas", "sg552", "m4a1", "aug", "scout", "awp", "g3sg1", "sg550", "m249", "vest", "vesthelm", "flash", "hegren",
    "sgren", "defuser", "nvgs", "shield", "primammo", "secammo", "km45", "9x19mm", "nighthawk", "228compact", "12gauge",
    "autoshotgun", "smg", "mp", "c90", "cv47", "defender", "clarion", "krieg552", "bullpup", "magnum", "d3au1", "krieg550",
    "buyammo1", "buyammo2"
}

// Variable that I'm going to use to register the pCVAR.
new gCvarPluginToggle

public plugin_init()
{
    // I think there is no need for explain this.
    register_plugin("Block Buy Example", "0.1.0", "fezh")

    // Toggle CVAR
    gCvarPluginToggle = register_cvar("amx_block_buy", "1")

    // Registering commands. As I said before, there is no need for creating a loop, but I like it anyways :P
    for (new i; i < sizeof gBuyCommands; i++)
        register_clcmd(gBuyCommands[i], "BlockBuyCommands")
}

public BlockBuyCommands(id)
{
    // If the plugin don't get the CVAR, it makes you buy normally.
    if (!get_pcvar_num(gCvarPluginToggle))
        return PLUGIN_CONTINUE;

    // Block the buy commands.
    return PLUGIN_HANDLED;
}

// Final comments: I did the "tutorial" since I saw that there are some weirds (and not actually functional) ways to do it, 
// like in the plugin called "Block Commands". 


[crazyeffect]

Finally!

[fezh]

I have a doubt. Why someone put 1 star in my thread? Is there an actual reason for this?

[Exolent[jNr]]

This is a better way:
http://forums.alliedmods.net/showpos...29&postcount=6

PHP Code:

#include < amxmodx >
#include < cstrike >

new Trie:g_tBuyCommands;

public plugin_init( )
{
    register_plugin( "Disable Buy", "0.0.1", "Exolent" );
    
    new const szBuyCommands[ ][ ] =
    {
        "usp", "glock", "deagle", "p228", "elites",
        "fn57", "m3", "xm1014", "mp5", "tmp", "p90",
        "mac10", "ump45", "ak47", "galil", "famas",
        "sg552", "m4a1", "aug", "scout", "awp", "g3sg1",
        "sg550", "m249", "vest", "vesthelm", "flash",
        "hegren", "sgren", "defuser", "nvgs", "shield",
        "primammo", "secammo", "km45", "9x19mm", "nighthawk",
        "228compact", "fiveseven", "12gauge", "autoshotgun",
        "mp", "c90", "cv47", "defender", "clarion", "krieg552",
        "bullpup", "magnum", "d3au1", "krieg550", 
        "buy", "buyammo1", "buyammo2", "buyequip", "cl_autobuy",
        "cl_rebuy", "cl_setautobuy", "cl_setrebuy"
    }
    
    g_tBuyCommands = TrieCreate( );
    for( new i = 0; i < sizeof( szBuyCommands ); i++ )
    {
        TrieSetCell( g_tBuyCommands, szBuyCommands[ i ], i );
    }
}

public plugin_end( )
{
    TrieDestroy( g_tBuyCommands );
}

public client_command( client )
{
    if( !is_user_alive( client ) )
    {
        return PLUGIN_CONTINUE;
    }
    
    static szArg[ 15 ];
    
    if( read_argv( 0, szArg, 14 ) > 13 ) // cl_setautobuy = 1234567890123 = 13
    {
        return PLUGIN_CONTINUE;
    }
    
    strtolower( szArg );
    if( TrieKeyExists( g_tBuyCommands, szArg )
    && ( 1 << ( _:cs_get_user_team( client ) ) & ( ( 1 << ( _:CS_TEAM_T ) ) | ( 1 << ( _:CS_TEAM_CT ) ) ) )
    {
        return PLUGIN_HANDLED;
    }
    
    return PLUGIN_CONTINUE;
} 


[Alucard^]

Good Job...

About Exolent method... i don't think you have to replace Exolent code with your code... i think you have to show the 2 differents method... so ppl can understand the basic first and then the other.

[Exolent[jNr]]

I don't think fezh's will work 100% because not all commands are able to be hooked with register_clcmd( ).

[jim_yang]

client_command and register_clcmd hook the same function, so the commands they can hooked or not are the same. and I think register_clcmd may be a little faster than client_command, because it let module level to compare the command string.

[Jon]

If you want to block all kind of buying it would be better altering the "buying" key at info_map_parameters (eventually creating the entity yourself).

[Zpoke]

ty exolent this was what iv'e looking for

[Alka]

Originally Posted by Jon If you want to block all kind of buying it would be better altering the "buying" key at info_map_parameters (eventually creating the entity yourself).