[Sn!ff3r]

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define NAME "show teammate's money"
#define VERSION "1.2.1"
#define AUTHOR "K.K.Lv"


public plugin_init()
{
    register_plugin(NAME, VERSION, AUTHOR)
    
    RegisterHam(Ham_Spawn, "player", "player_spawn", 1)
    
    register_clcmd("say /money", "show_money")
}

public player_spawn(client)
{
    if (is_user_alive(client))
    {
        set_task(1.0, "show_money", client)
    }
}

public show_money(client)
{        
    set_hudmessage(100, 200, 0, 0.05, 0.35, 0, 0.02, 5.0, 0.1, 0.2, 2)
    show_hudmessage(client, format_money(cs_get_user_team(client), client))
}

public format_money(CsTeams:Team, req)
{
    new team[10], message[480]
    switch(CsTeams:Team) {
        case CS_TEAM_CT: team = "CT"
            case CS_TEAM_T: team = "TERRORIST"        
        }    
    
    new len = formatex(message, sizeof message - 1, "The teammate's money:^n")
    
    new players[32], num, id, name[33]
    get_players(players, num, "ae", team)
    for(new i = 0; i < num; i++)
    {
        id = players[i]
    
        if(id == req)
            continue
    
        get_user_name(id, name, 32)
        len += formatex(message[len], sizeof message - 1 - len, "%-22.22s: %d^n", name, cs_get_user_money(id))        
    }
    return message
} 


[roflmao456]

It would be cool if it will show on the StatusText right after Health when you aim at your team

for example: Friend: Player Health: 100% Money: 800

[K.K.Lv]

Originally Posted by roflmao456 It would be cool if it will show on the StatusText right after Health when you aim at your team for example: Friend: Player Health: 100% Money: 800

will be updated !

[Hawk552]

There are major errors in this that prevent it from being approved. Here are some of them:

PHP Code:

    for (id = 1; id < g_max_players; id++) 


This will skip the last player if the server is full.

PHP Code:

        if (get_user_team(pid) == 1) 


Use cs_get_user_team().

PHP Code:

new message[1024] 


Use static.

If you would like any information regarding possible adjustments you could make or things you could do to make this better, please feel free to post here or PM me.

Approval pending on changes.

[K.K.Lv]

@Hawk552, fixed !

[Hawk552]

There are a few mistakes and optimizations that can be made, however it is acceptable.

If you would like any information regarding possible adjustments you could make or things you could do to make this better, please feel free to post here or PM me.

Approved.

[K.K.Lv]

can you point it out !
and I will be fixed it !

[Hawk552]

Changes have been requested.

PHP Code:

#pragma semicolon 1 


This should be removed from releases.

PHP Code:

sizeof message - 1 


Use charsmax().

PHP Code:

        if (id != client)
        {
            if (is_user_connected(id))
            {
                if (cs_get_user_team(id) == cs_get_user_team(client))
                { 


Group these into one if statement to avoid unnecessary jumps.

PHP Code:

    set_hudmessage(100, 200, 0, 0.05, 0.35, 0, 0.02, 5.0, 0.1, 0.2, 2);
    show_hudmessage(client, message); 


Consider using HUD sync objects.

PHP Code:

if (g_teammate[id] == 1) 


Use boolean logic, i.e.:

PHP Code:

if (g_teammate[id]) 


PHP Code:

public client_disconnect(client)
{
    remove_task(client);
    return PLUGIN_CONTINUE;
} 


Unnecessary return.

[K.K.Lv]

All have been fixed！

[La scatola magica]

A client-side solution was also released recently: CSMoneyReporter.