[Contrenature]

Nvault sux...
Our community support only Sql
There nothing specily.

[-Acid-]

Did you read the description??
>:[ Contrenature

[[-X-ViSi0N]]

I love this plugins... can you make it save BOT frags too? because BOT don't save their frags... and I want death to be saved too.... and I also want the frags saved by nickname... can you help me?

[Bugsy]

Originally Posted by [-X-ViSi0N] I love this plugins... can you make it save BOT frags too? because BOT don't save their frags... and I want death to be saved too.... and I also want the frags saved by nickname... can you help me?

This will save real players frags by steam-id and bots frags by name. Saving all players frags by name makes no sense because any player can change their name to acquire another players frags.

PHP Code:

#include <amxmodx>
#include <fun>
#include <nvault>

new g_szKey[ 33 ][ 33 ];
new bool: g_bSaveFrags[ 33 ];
new g_iFrags[ 33 ];
new g_pEnabled;
new g_pSaveBots;
new g_iVault;

new const g_szVaultFile[] = "frag_saver";

public plugin_init()
{
    register_plugin( "Frag_Saver" , "2.0" , "-Acid-" );
    
    register_event( "ScoreInfo" , "fwEvScoreInfo" , "a" );
    
    g_pEnabled = register_cvar( "fs_enabled" , "1" );
    g_pSaveBots = register_cvar( "fs_savebots" , "1" );
}

public plugin_cfg()
{
    g_iVault = nvault_open( g_szVaultFile );

    if ( g_iVault == INVALID_HANDLE )
        set_fail_state( "Error opening nVault" );
}

public plugin_end()
{
    nvault_close( g_iVault );
}

public client_putinserver( id )
{
    if ( !get_pcvar_num( g_pEnabled ) )
        return PLUGIN_CONTINUE;
        
    static iFrags;
    static iBot; iBot = is_user_bot( id );
    
    g_bSaveFrags[ id ] = bool: ( !iBot || ( iBot && get_pcvar_num( g_pSaveBots ) ) );
    
    if ( g_bSaveFrags[ id ] )
    {
        if ( iBot )
            get_user_name( id , g_szKey[ id ] , 32 );
        else
            get_user_authid( id , g_szKey[ id ] , 32 );
    
        iFrags = nvault_get( g_iVault , g_szKey[ id ] );
        
        if ( iFrags )
        {
            g_iFrags[ id ] = iFrags;
            set_user_frags( id , iFrags );
        }
    }
    
    return PLUGIN_CONTINUE;
}

public client_disconnect( id )
{
    if ( !get_pcvar_num( g_pEnabled ) )
        return PLUGIN_CONTINUE;
        
    static szFrags[ 6 ];
    
    if ( g_iFrags[ id ] )
    {
        num_to_str( g_iFrags[id] , szFrags , 5 );
        nvault_set( g_iVault , g_szKey[ id ] , szFrags );
    
        g_iFrags[ id ] = 0;
        g_bSaveFrags[ id ] = false;
        g_szKey[ id ][ 0 ] = 0;
    }
    
    return PLUGIN_CONTINUE;
}

public fwEvScoreInfo()
{
    static id; id = read_data( 1 );
    
    if ( !get_pcvar_num( g_pEnabled ) || !g_bSaveFrags[ id ] )
        return PLUGIN_CONTINUE;
        
    static iFrags; iFrags = read_data( 2 );
        
    if ( !iFrags && g_iFrags[ id ] )
    {
        set_user_frags( id , g_iFrags[ id ] );
        return PLUGIN_CONTINUE;
    }
    
    g_iFrags[ id ] = iFrags;
    
    return PLUGIN_CONTINUE;
} 


[[-X-ViSi0N]]

Thanks.... it would be better if Deaths also saved!

How do you save deaths? I try reverse the Frags to Deaths but it failed... can someone help?

[algoasi]

great plugin ... but the deaths should also save

[Bugsy]

Save kills & deaths with bot support

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <fakemeta_util>
#include <nvault>

#define OFFSET_CSDEATHS            444
#define fm_set_user_deaths(%1,%2)    set_pdata_int( %1, OFFSET_CSDEATHS, %2, 5)  

new g_szKey[ 33 ][ 33 ];
new bool: g_bSaveScore[ 33 ];
new g_iFrags[ 33 ];
new g_iDeaths[ 33 ];
new g_pEnabled;
new g_pSaveBots;
new g_iVault;

new const g_szVaultFile[] = "score_saver";

public plugin_init()
{
    register_plugin( "Score Saver" , "1.0" , "bugsy" );
    
    register_event( "ScoreInfo" , "fwEvScoreInfo" , "a" );
    
    g_pEnabled = register_cvar( "fs_enabled" , "1" );
    g_pSaveBots = register_cvar( "fs_savebots" , "1" );
}

public plugin_cfg()
{
    g_iVault = nvault_open( g_szVaultFile );

    if ( g_iVault == INVALID_HANDLE )
        set_fail_state( "Error opening nVault" );
}

public plugin_end()
{
    nvault_close( g_iVault );
}

public client_putinserver( id )
{
    if ( !get_pcvar_num( g_pEnabled ) )
        return PLUGIN_CONTINUE;
        
    static iBot; iBot = is_user_bot( id );
    static szVaultData[ 10 ] , szFrags[ 5 ] , szDeaths[ 5 ] , iTimestamp;
    
    g_bSaveScore[ id ] = bool: ( !iBot || ( iBot && get_pcvar_num( g_pSaveBots ) ) );
    
    if ( g_bSaveScore[ id ] )
    {
        if ( iBot )
            get_user_name( id , g_szKey[ id ] , 32 );
        else
            get_user_authid( id , g_szKey[ id ] , 32 );
    
        if ( nvault_lookup( g_iVault , g_szKey[ id ] , szVaultData , 9 , iTimestamp ) )
        {
            strbreak( szVaultData , szFrags , 4 , szDeaths , 4 );
            
            g_iFrags[ id ] = str_to_num( szFrags );
            g_iDeaths[ id ] = str_to_num( szDeaths );
            
            //I tested the plugin using PodBots and I was getting a server crash at mapchange
            //when trying to call SetScore at putinserver(). This seems to have fixed it.
            set_task( 0.1 , "SetScore" , id );
        }
    }
    
    return PLUGIN_CONTINUE;
}

public client_disconnect( id )
{
    if ( !get_pcvar_num( g_pEnabled ) )
        return PLUGIN_CONTINUE;
        
    static szVaultData[ 10 ];
    
    if ( g_iFrags[ id ] || g_iDeaths[ id ] )
    {
        formatex( szVaultData , 9 , "%d %d" , g_iFrags[ id ] , g_iDeaths[ id ] );
        
        nvault_set( g_iVault , g_szKey[ id ] , szVaultData );
    
        g_szKey[ id ][ 0 ] = EOS;
        g_iFrags[ id ] = 0;
        g_iDeaths[ id ] = 0;
        g_bSaveScore[ id ] = false;
    }
    
    return PLUGIN_CONTINUE;
}

public fwEvScoreInfo()
{
    static id; id = read_data( 1 );
    
    if ( !get_pcvar_num( g_pEnabled ) || !g_bSaveScore[ id ] )
        return PLUGIN_CONTINUE;
        
    static iFrags; iFrags = read_data( 2 );
    static iDeaths; iDeaths = read_data( 3 );
    
    if ( ( !iFrags && !iDeaths ) && ( g_iFrags[ id ] || g_iDeaths[ id ] ) )
    {
        SetScore( id );
        
        return PLUGIN_CONTINUE;
    }
    
    g_iFrags[ id ] = iFrags;
    g_iDeaths[ id ] = iDeaths;
    
    return PLUGIN_CONTINUE;
}

public SetScore( id )
{
    fm_set_user_frags( id , g_iFrags[ id ] );
    fm_set_user_deaths( id , g_iDeaths[ id ] );
} 


[[-X-ViSi0N]]

Originally Posted by Bugsy Save kills & deaths with bot support PHP Code: #include <amxmodx> #include <fakemeta> #include <fakemeta_util> #include <nvault> #define OFFSET_CSDEATHS            444 #define fm_set_user_deaths(%1,%2)    set_pdata_int( %1, OFFSET_CSDEATHS, %2, 5)   new g_szKey[ 33 ][ 33 ]; new bool: g_bSaveScore[ 33 ]; new g_iFrags[ 33 ]; new g_iDeaths[ 33 ]; new g_pEnabled; new g_pSaveBots; new g_iVault; new const g_szVaultFile[] = "score_saver"; public plugin_init() {     register_plugin( "Score Saver" , "1.0" , "bugsy" );          register_event( "ScoreInfo" , "fwEvScoreInfo" , "a" );          g_pEnabled = register_cvar( "fs_enabled" , "1" );     g_pSaveBots = register_cvar( "fs_savebots" , "1" ); } public plugin_cfg() {     g_iVault = nvault_open( g_szVaultFile );     if ( g_iVault == INVALID_HANDLE )         set_fail_state( "Error opening nVault" ); } public plugin_end() {     nvault_close( g_iVault ); } public client_putinserver( id ) {     if ( !get_pcvar_num( g_pEnabled ) )         return PLUGIN_CONTINUE;              static iBot; iBot = is_user_bot( id );     static szVaultData[ 10 ] , szFrags[ 5 ] , szDeaths[ 5 ] , iTimestamp;          g_bSaveScore[ id ] = bool: ( !iBot || ( iBot && get_pcvar_num( g_pSaveBots ) ) );          if ( g_bSaveScore[ id ] )     {         if ( iBot )             get_user_name( id , g_szKey[ id ] , 32 );         else             get_user_authid( id , g_szKey[ id ] , 32 );              if ( nvault_lookup( g_iVault , g_szKey[ id ] , szVaultData , 9 , iTimestamp ) )         {             strbreak( szVaultData , szFrags , 4 , szDeaths , 4 );                          g_iFrags[ id ] = str_to_num( szFrags );             g_iDeaths[ id ] = str_to_num( szDeaths );                          //I tested the plugin using PodBots and I was getting a server crash at mapchange             //when trying to call SetScore at putinserver(). This seems to have fixed it.             set_task( 0.1 , "SetScore" , id );         }     }          return PLUGIN_CONTINUE; } public client_disconnect( id ) {     if ( !get_pcvar_num( g_pEnabled ) )         return PLUGIN_CONTINUE;              static szVaultData[ 10 ];          if ( g_iFrags[ id ] || g_iDeaths[ id ] )     {         formatex( szVaultData , 9 , "%d %d" , g_iFrags[ id ] , g_iDeaths[ id ] );                  nvault_set( g_iVault , g_szKey[ id ] , szVaultData );              g_szKey[ id ][ 0 ] = EOS;         g_iFrags[ id ] = 0;         g_iDeaths[ id ] = 0;         g_bSaveScore[ id ] = false;     }          return PLUGIN_CONTINUE; } public fwEvScoreInfo() {     static id; id = read_data( 1 );          if ( !get_pcvar_num( g_pEnabled ) || !g_bSaveScore[ id ] )         return PLUGIN_CONTINUE;              static iFrags; iFrags = read_data( 2 );     static iDeaths; iDeaths = read_data( 3 );          if ( ( !iFrags && !iDeaths ) && ( g_iFrags[ id ] || g_iDeaths[ id ] ) )     {         SetScore( id );                  return PLUGIN_CONTINUE;     }          g_iFrags[ id ] = iFrags;     g_iDeaths[ id ] = iDeaths;          return PLUGIN_CONTINUE; } public SetScore( id ) {     fm_set_user_frags( id , g_iFrags[ id ] );     fm_set_user_deaths( id , g_iDeaths[ id ] ); }

I tired this one... it only save frags, and it doesn't save deaths,

why don't make 2 seperate plugins...
1. Frag saver + bot support
2. Death saver + bot support

[Bugsy]

Originally Posted by [-X-ViSi0N] I tired this one... it only save frags, and it doesn't save deaths,

It works for me (tested with podbots)

[[-X-ViSi0N]]

well it doesn;t save my deaths, even bot's deaths too, I'll try to RE-compile again...