[Immortal_BLG]

Sorry I was wrong....

[Foghrye4]

xPaw
I have a question. A memory offset for m_fReloadTimefor get_pdata_float() is?

[Arkshine]

It doesn't exist. It's hardcoded in each weapon file, passed into DefaultReload() and into this function set in m_flNextAttack. (player, 83)

[Foghrye4]

Arkshine
So, if i want to change reload time i must check "if weapon reloading" state using m_fInReload with memory offset 54 and then simple change m_flNextAttack with memory offset 83?
Does it work fine?

UPD(15:46)___________________________________ _____________
Okey, i try it and it's work, thanx to Arkshine. I try it in "RPGx 2.0" plugin by Roflmao, by modification "Speed Shot+".
Here is code:

#pragma semicolon 1

#include <amxmodx>
#include <engine>
#include <fakemeta_util>
#include <rpgx>

new upgrade_id, level, weaponid, ent, str[16], Float:reload_delay, weapon[32], bool:is_reloading;

public plugin_init(){
    register_plugin("Reload Speed+ RPGx Upgrade", "1.0", "roflmao456+Foghrye4");
}
    
public RPGx_OnPluginReady()
    upgrade_id = RPGx_MakeUpgrade("Reload+", 5, 15, 20);

public client_PreThink(id){
    level = RPGx_GetUpgradeLevel(id, upgrade_id);
    if(level){
        weaponid = get_user_weapon(id);
        if(weaponid){
            get_weaponname(weaponid, weapon, 31);
            ent = fm_find_ent_by_owner(-1, weapon, id);
            if(ent){
            reload_delay = get_pdata_float(id, 83, 4);
        is_reloading = (reload_delay > 0.0) &&  (get_pdata_int(ent, 54, 4) > 0);
                if(is_reloading){
        set_pdata_float(id, 83, reload_delay - (reload_delay * (level * 0.05)), 4);
             }
        }
        }
 }
/* For debug only */
format(str, 15, "Accuracy %f", reload_delay);
client_print(id, print_chat, "%L", id, str);
}

But now i have one more problem. How i can change animation speed for reloading process?
Because it looks too unrealistic in high levels to shoot just after clip is empty with no clip reloading.

[Backstabnoob]

How do I get weapon owner id when the weapon is being reloaded?

Edit: Well sorry for being too lazy, I browser wiki and found out this works:
new id = pev( iWeapon, pev_owner )

[xPaw]

Originally Posted by Backstabnoob How do I get weapon owner id when the weapon is being reloaded? Edit: Well sorry for being too lazy, I browser wiki and found out this works: new id = pev( iWeapon, pev_owner )

You can also use m_pPlayer offset.

PHP Code:

#define m_pPlayer 41

new id = get_pdata_cbase( iWeapon, m_pPlayer, 4 ); 


[Xalus]

Euhm,
those settings are for Windows?

If yes,
Can U give me the Linux settings / Link me?

[Arkshine]

It will work for linux too.

[ConnorMcLeod]

Reload end : (seems to be reliable after only few tests) :
Can be altered with register_message instead of register_event.

SHOTGUNS are not covered because of their special reload system.

PHP Code:

#define NADES_BITSUM    (1 << CSW_HEGRENADE) |  (1 << CSW_FLASHBANG) | (1 << CSW_SMOKEGRENADE)
#define NORELOAD_BITSUM NADES_BITSUM | (1 << CSW_KNIFE) | (1 << CSW_C4) | (1 << CSW_M3) | (1 << CSW_XM1014) 

const XO_WEAPON = 4
const m_pPlayer = 41
const m_iId = 43
const m_iClip = 51
const m_iClientClip = 52
const m_fInReload  = 54

const XO_PLAYER = 5
const m_pActiveItem = 373 


PHP Code:

register_event("CurWeapon", "Event_CurWeapon", "be", "1=1", "3>0") 


PHP Code:

public Event_CurWeapon( id )
{
    new iId = read_data(2)
    if( ~NORELOAD_BITSUM & 1<<iId )
    {
        new iWeapon = get_pdata_cbase(id, m_pActiveItem, XO_PLAYER)
        new iClientClip = get_pdata_int(iWeapon, m_iClientClip, XO_WEAPON)
        new iClip = read_data(3)
        if( iClip > iClientClip )
        {
            // Player <id> has reloaded weapon <m_pActiveItem>, weapontype iId
        }
    }
} 


Note : If this is reliable, it uses less cpu than hooking Item_PreFrame


Other way :

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

#define NADES_BITSUM    (1 << CSW_HEGRENADE) |  (1 << CSW_FLASHBANG) | (1 << CSW_SMOKEGRENADE)
#define NORELOAD_BITSUM NADES_BITSUM | (1 << CSW_KNIFE) | (1 << CSW_C4) | (1 << CSW_M3) | (1 << CSW_XM1014) 

const XO_WEAPON = 4
const m_pPlayer = 41
const m_iId = 43
const m_iClip = 51
const m_iClientClip = 52
const m_fInReload  = 54

const XO_PLAYER = 5
const m_pActiveItem = 373

const MAX_PLAYERS = 32
new g_iPlayerWeaponReloading[MAX_PLAYERS+1]

public plugin_init() 
{
    register_plugin("Reload", "0.0.1", "ConnorMcLeod")

    new szWeapon[32]
    for(new iId = CSW_P228; iId <= CSW_P90; iId++) 
    {
        if( ~NORELOAD_BITSUM & (1 << iId) && get_weaponname( iId, szWeapon, charsmax(szWeapon)) )
        {
            RegisterHam( Ham_Weapon_Reload, szWeapon, "Weapon_Reload_Post", true)
            RegisterHam(Ham_Item_Holster, szWeapon, "Item_Holster")
        }
    }
    register_event("CurWeapon", "Event_CurWeapon", "be", "1=1", "3>0")
}

public Weapon_Reload_Post( iWeapon ) 
{
    if( get_pdata_int(iWeapon, m_fInReload, XO_WEAPON) )
    {
        // starts reloading
        new id = get_pdata_cbase(iWeapon, m_pPlayer, XO_WEAPON)
        new iId = get_pdata_int(iWeapon, m_iId, XO_WEAPON)
        g_iPlayerWeaponReloading[ id ] = iId
        new szWeapon[32]
        get_weaponname(iId, szWeapon, charsmax(szWeapon))
        client_print(id, print_chat, "START RELOAD %s", szWeapon)
    }
}

public Item_Holster( iWeapon )
{
    if( get_pdata_int(iWeapon, m_fInReload, XO_WEAPON) )
    {
        new id = get_pdata_cbase(iWeapon, m_pPlayer, XO_WEAPON)
        new iId = g_iPlayerWeaponReloading[ id ]
        if( iId )
        {
            new szWeapon[32]
            get_weaponname(iId, szWeapon, charsmax(szWeapon))
            client_print(id, print_chat, "STOP RELOAD %s", szWeapon)
        }
        g_iPlayerWeaponReloading[ id ] = 0
    }
}

public Event_CurWeapon( id )
{
    new iId = read_data(2)

    new iPlayerWeaponReloading = g_iPlayerWeaponReloading[ id ]
    if( iPlayerWeaponReloading && iPlayerWeaponReloading == iId )
    {
        // player has finished to reload
        new szWeapon[32]
        get_weaponname(iId, szWeapon, charsmax(szWeapon))
        client_print(id, print_chat, "Finished Reload %s", szWeapon)
        g_iPlayerWeaponReloading[ id ] = 0
    }
} 


You can find the exact way it should be hooked in this plugin, but as i said, Item_Preframe uses more cpu.