[oxygen935]

Hey everyone,

I just wanna create a simple plugin.
This plugin will read the players' steamid and the custom name, and if a player has this steamid, it will set this custom name(the one which read from the file).
The c_names.ini will be like this:

;"SteamID" "Custom Name"
"STEAM_0:X:YYYYYYYY" "Troller"

So, i have this code by now:

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "oxygen"

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
}

LoadCustomNames() 
{
    new file[64];
    get_configsdir(file, charsmax(file));
    add(file, charsmax(file), "/c_names.ini")
    
    new f = fopen(file, "rt")
    
    if(!f) return
    
    // File format:
    // "SteamID" "Custom Name"
    
    new line[256]
    new szFileSteamId[32]
    new rank[128]
    
    while(!feof(f)) 
    {
        fgets(f, line, charsmax(line))
        trim(line)
        
        if(!line[0] || line[0] == ';' || (line[0] == '/' && line[1] == '/'))
        {
            continue
        }    
    }
    fclose(f)
} 


So, i know what to do, but i don't know how to do it.
I wanna store the player's name on client_putinserver, then set the custom name, if it is available, and on client_disconnect set again the old name.

So please help me, cause this my first time working with fopen natives.

With Respect,
Oxygen

[claudiuhks]

Why do you name it simple if you can't do it? I really don't understand what you want to do. Sanity checks inside the While loop are bad written. You should inform yourself more.

PHP Code:

line[0] == '/' && line[1] == '/' 


->

PHP Code:

(line[0] == '/' && line[1] == '/') 


Consider that client_infochanged may alter the client's name.

Isn't get_configsdir an AMXMISC function? You forgot to include this file.

http://www.amxmodx.org/doc/index.htm...re%2Fparse.htm

[oxygen935]

oh thanks, i'm stupid. Code updated

Lets explain myself more.
we have this line in the c_names.ini --> "STEAM_0:X:YYYYYYYY" "Troller"

when the player with the steamid: STEAM_0:X:YYYYYYYY connect to my server, his name will be saved on a variable and then the plugin will set its name to "Troller". when the player will disconnect from the server, his name will be set to his old one.

so i want some help on how to read the steamid and the name from the c_names.ini

[Blizzard_87]

Take a read thru this.

Saving the data read from file in a trie.

Then when ever the name change forward is executed you check the trie.

https://forums.alliedmods.net/showpo...0&postcount=27

[oxygen935]

Originally Posted by Blizzard_87 Take a read thru this. Saving the data read from file in a trie. Then when ever the name change forward is executed you check the trie. https://forums.alliedmods.net/showpo...0&postcount=27

That helps a lot. Will try it soon.

Thanks for Help Blizzard ;)

[ConnorMcLeod]

To read text in files i'm using this template :

PHP Code:

    new fp = fopen(szCfgFile, "rt");
    if( fp )
    {
        new buffer[256], c;
        while( !feof(fp) )
        {
            fgets(fp, buffer, charsmax(buffer));
            trim(buffer);
            c = buffer[0];
            if( c && c != '#' && c != ';' && !( c == '/' && buffer[1] == '/' ) )
            {
            }
        }
        fclose( fp );
        fp = 0;
    } 


For the plugin you want :

PHP Code:

#include < amxmodx >
#include < amxmisc >

#pragma semicolon 1

#define PLUGIN ""
#define VERSION "0.0.1"

#define cm(%0)    ( sizeof(%0) - 1 )

new Trie:g_tCustomNames;

new g_szCustomName[33][32];

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );
}

public plugin_cfg()
{
    new szCfgFile[64];
    get_configsdir(szCfgFile, cm(szCfgFile));
    add(szCfgFile, cm(szCfgFile), "/c_names.ini");
    new fp = fopen(szCfgFile, "rt");
    if( fp )
    {
        new buffer[256], c;
        new szSteamId[21], szCustomName[32];
        g_tCustomNames = TrieCreate();
        while( !feof(fp) )
        {
            fgets(fp, buffer, charsmax(buffer));
            trim(buffer);
            c = buffer[0];
            if( c && c != '#' && c != ';' && !( c == '/' && buffer[1] == '/' ) )
            {
                parse(buffer, szSteamId, cm(szSteamId), szCustomName, cm(szCustomName));
                TrieSetString(g_tCustomNames, szSteamId, szCustomName);
            }
        }
        fclose( fp );
        fp = 0;
    }
}

GETPLAYERAUTHID(id, bGet = false)
{
    static szAuthid[33][21];
    if( bGet )
    {
        get_user_authid(id, szAuthid[id], charsmax(szAuthid[]));
    }
    return szAuthid[id];
}

public client_putinserver(id)
{
    g_szCustomName[id][0] = EOS;
    if( TrieGetString(g_tCustomNames, GETPLAYERAUTHID(id, true), g_szCustomName[id], cm(g_szCustomName[])) )
    {
        set_user_name(id, g_szCustomName[id]);
    }
}

public client_infochanged(id)
{
    if( g_szCustomName[id][0] && is_user_connected(id) )
    {
        set_user_name(id, g_szCustomName[id]);
    }
}

set_user_name(id, const name[])
{
    set_user_info(id, "name", name);
}