[ConnorMcLeod]

You don't understand what i mean, try this :

T slots are removed and changed into CT slots, so no one can join T team.

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define VERSION "0.0.1"
#define PLUGIN "Change T spawns in CT spawns"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    new iEnt = FM_NULLENT
    while( (iEnt = engfunc(EngFunc_FindEntityByString, iEnt, "classname", "info_player_deathmatch")) )
    {
        engfunc(EngFunc_RemoveEntity, iEnt)
    }
}

public plugin_precache()
{
    enum _:SpawnsDatas
    {
        m_szAngles[18],
        m_szOrigins[18]
    }
    new Array:aSpawns = ArrayCreate(SpawnsDatas)
    new mTempDatas[SpawnsDatas]

    enum
    {
        iAngles,
        iOrigins,
        iClassName
    }
    new Trie:tKeyType = TrieCreate()
    TrieSetCell(tKeyType, "angles", iAngles)
    TrieSetCell(tKeyType, "origin", iOrigins)
    TrieSetCell(tKeyType, "classname", iClassName)

    new szMapFile[64]
    get_mapname(szMapFile, charsmax(szMapFile))
    format(szMapFile, charsmax(szMapFile), "maps/%s.bsp", szMapFile)

    new szBuffer[64], szKey[16], szValue[32], iType
    new bool:bInEntityDatas, bool:bIsInfoPlayerStartEntity
    new fp = fopen(szMapFile, "rb")

    new iOffset, iLength, iMaxPos
    fseek(fp, 4, SEEK_SET)
    fread(fp, iOffset, BLOCK_INT)
    fread(fp, iLength, BLOCK_INT)
    iMaxPos = iOffset + iLength
    fseek(fp, iOffset, SEEK_SET)

    while( ftell(fp) < iMaxPos )
    {
        fgets(fp, szBuffer, charsmax(szBuffer))
        trim(szBuffer)

        if( bInEntityDatas )
        {
            if( szBuffer[0] == '}' )
            {
                bInEntityDatas = false
                if( bIsInfoPlayerStartEntity )
                {
                    ArrayPushArray(aSpawns, mTempDatas)
                }
            }
            else
            {
                parse(szBuffer, szKey, charsmax(szKey), szValue, charsmax(szValue))
                if( TrieGetCell(tKeyType, szKey, iType) )
                {
                    switch( iType )
                    {
                        case iAngles:
                        {
                            copy(mTempDatas[m_szAngles], charsmax(mTempDatas[m_szAngles]), szValue)
                        }
                        case iOrigins:
                        {
                            copy(mTempDatas[m_szOrigins], charsmax(mTempDatas[m_szOrigins]), szValue)
                        }
                        case iClassName:
                        {
                            if( equal(szValue, "info_player_deathmatch") )
                            {
                                bIsInfoPlayerStartEntity = true
                            }
                        }
                    }
                }
            }
        }
        else if( szBuffer[0] == '{' )
        {
            bInEntityDatas = true
            bIsInfoPlayerStartEntity = false
        }
    }
    fclose(fp)

    new iSpawnsNum = ArraySize( aSpawns )

    new iszClassName = engfunc(EngFunc_AllocString, "info_player_start")

    set_kvd(0, KV_ClassName, "info_player_start")
    set_kvd(0, KV_fHandled, 0)
    for(new i, iEnt; i<iSpawnsNum; i++)
    {
        ArrayGetArray(aSpawns, i, mTempDatas)

        iEnt = engfunc(EngFunc_CreateNamedEntity, iszClassName)
        DispatchKeyValueCustom(iEnt, "angles", mTempDatas[m_szAngles])
        DispatchKeyValueCustom(iEnt, "origin", mTempDatas[m_szOrigins])
        dllfunc(DLLFunc_Spawn, iEnt)
    }

    ArrayDestroy( aSpawns )
    TrieDestroy( tKeyType )
}

DispatchKeyValueCustom(iEntity, szKey[], szValue[])
{
    set_kvd(0, KV_KeyName, szKey)
    set_kvd(0, KV_Value, szValue)
    dllfunc(DLLFunc_KeyValue, iEntity, 0)
} 


[JoKeR LauGh]

for terrorist ?

EDIT : Just tested your code and it works . I tried to join CT but it says the CT team is full . anyway , I wrote the tittle wrong .. I want all people in the server to be in CT not T . very sorry

[ConnorMcLeod]

Edited.

[yokomo]

Originally Posted by JoKeR LauGh I tried to join CT but it says the CT team is full

That cause by spawnpoint is reach limit. For example in a small maps. You need to add more custom spawn point to prevent this message spamming in your console.

[ConnorMcLeod]

Originally Posted by yokomo That cause by spawnpoint is reach limit. For example in a small maps. You need to add more custom spawn point to prevent this message spamming in your console.

No, it was because i was removing all CT spawns.

[Backstabnoob]

If you don't want that message to pop-up, use humans_join_team "ct", I think it will automatically assign that team to them and not show the selection.

[JoKeR LauGh]

L 01/01/2012 - 23:17:13: Start of error session.
L 01/01/2012 - 23:17:13: Info (map "de_dust2") (file "addons/amxmodx/logs/error_20120101.log")
L 01/01/2012 - 23:17:13: [AMXX] Displaying debug trace (plugin "Monster_Mod.amxx")
L 01/01/2012 - 23:17:13: [AMXX] Run time error 4: index out of bounds 
L 01/01/2012 - 23:17:13: [AMXX]    [0] Monster_Mod.sma::PickMonster (line 105)
L 01/01/2012 - 23:17:13: [AMXX] Displaying debug trace (plugin "Monster_Mod.amxx")
L 01/01/2012 - 23:17:13: [AMXX] Run time error 4: index out of bounds 
L 01/01/2012 - 23:17:13: [AMXX]    [0] Monster_Mod.sma::PickMonster (line 105)
L 01/01/2012 - 23:17:13: [AMXX] Displaying debug trace (plugin "Monster_Mod.amxx")
L 01/01/2012 - 23:17:13: [AMXX] Run time error 4: index out of bounds 
L 01/01/2012 - 23:17:13: [AMXX]    [0] Monster_Mod.sma::PickMonster (line 105)
L 01/01/2012 - 23:17:13: [AMXX] Displaying debug trace (plugin "Monster_Mod.amxx")
L 01/01/2012 - 23:17:13: [AMXX] Run time error 4: index out of bounds 
L 01/01/2012 - 23:17:13: [AMXX]    [0] Monster_Mod.sma::PickMonster (line 105)
L 01/01/2012 - 23:17:13: [AMXX] Displaying debug trace (plugin "Monster_Mod.amxx")
L 01/01/2012 - 23:17:13: [AMXX] Run time error 4: index out of bounds 
L 01/01/2012 - 23:17:13: [AMXX]    [0] Monster_Mod.sma::PickMonster (line 105)
L 01/01/2012 - 23:17:13: [AMXX] Displaying debug trace (plugin "Monster_Mod.amxx")
L 01/01/2012 - 23:17:13: [AMXX] Run time error 4: index out of bounds 
L 01/01/2012 - 23:17:13: [AMXX]    [0] Monster_Mod.sma::PickMonster (line 105)
L 01/01/2012 - 23:17:13: [AMXX] Displaying debug trace (plugin "Monster_Mod.amxx")
L 01/01/2012 - 23:17:13: [AMXX] Run time error 4: index out of bounds 
L 01/01/2012 - 23:17:13: [AMXX]    [0] Monster_Mod.sma::PickMoMonster (line 105)

this line ...

PHP Code:

fread(fp, iLength, BLOCK_INT) 


[ConnorMcLeod]

Originally Posted by JoKeR LauGh this line ...

Can't be that line, that line is executed only 1 time (you have multiple errors) and the line doesn't contain any array.
This code is ripped from another plugin i have released and that doesn't generate any errors.