[KaH]

Well I been Searching for this Plugin after Playing in some Servers with it But I Cannot Find It :/


Pics of Plugins:






the welcome message & leaving message !

[hamood 400]

which plugins 0.o ?

[KaH]

Originally Posted by hamood 400 which plugins 0.o ?

The Welcome & Leaving Message.

[KaH]

Originally Posted by Balck Do you mean this :S ? http://forums.alliedmods.net/showthread.php?p=789735

Originally Posted by KaH The Welcome & Leaving Message.

[iljos]

Use AMX super 4.2

and look into

PHP Code:

amx_super.cfg 


[ConnorMcLeod]

Try this :

PHP Code:

/*
* Enter and Leave Message
*  v 0.1
*
*  by [MUPPETS] Gonzo
*   [email protected]
*
* some code was taken from
* welcome_hudmsg by JustinHoMi
*
* Traduit par c@n3d@
*/

#include < amxmodx >

native get_user_stats(index, stats[], bodyhits[8]);

new amx_enter_message, amx_leave_message, pcvar_hostname, amx_enter_message_color, amx_leave_message_color, amx_enter_message_sound, amx_leave_message_sound;

new const namePattern[] = "%name%";
new const hostnamePattern[] = "%hostname%";
new const rankPattern[] = "%rankpos%";

new g_iXstats;

enum
{
    _None,
    _Normal,
    _Dodx,
}

new g_bConnected[33 char];

new g_szConnectSound[256], g_szDisconnectSound[256];

public plugin_init()
{
    register_plugin("Enter-Leave Message", "0.4.2", "[MUPPETS] Gonzo");

    amx_enter_message = register_cvar("amx_enter_message", "%name% has joined!^nEnjoy the server.");
    amx_enter_message_color = register_cvar("amx_enter_message_color", "50 255 50");
    amx_leave_message = register_cvar("amx_leave_message", "%name% has left!^nHope to see you back sometime.");
    amx_leave_message_color = register_cvar("amx_enter_message_color", "255 50 120");
    amx_leave_message_sound = register_cvar("amx_leave_message_sound", "buttons/bell.wav");

    pcvar_hostname = get_cvar_pointer("hostname");

    if(    IsModuleLoaded("csx")
    ||    IsModuleLoaded("tfcx")
    ||    IsModuleLoaded("tsx")    )
    {
        g_iXstats = _Normal
    }
    else if( IsModuleLoaded("dodx") )
    {
        g_iXstats = _Dodx
    }
}

IsModuleLoaded(const library[])
{
    return LibraryExists(library, LibType_Library)
}

public plugin_precache()
{
    amx_enter_message_sound = register_cvar("amx_enter_message_sound", "buttons/blip.wav");
    new szFile[256];
    get_pcvar_string(amx_enter_message_sound, g_szConnectSound, charsmax(g_szConnectSound));
    formatex(szFile, charsmax(szFile), "sound/%s", g_szConnectSound);
    if( file_exists(szFile) )
    {
        precache_sound(g_szConnectSound);
    }
    else
    {
        g_szConnectSound[0] = EOS;
    }

    get_pcvar_string(amx_leave_message_sound, g_szDisconnectSound, charsmax(g_szDisconnectSound));
    formatex(szFile, charsmax(szFile), "sound/%s", g_szDisconnectSound);
    if( file_exists(szFile) )
    {
        precache_sound(g_szDisconnectSound);
    }
    else
    {
        g_szDisconnectSound[0] = EOS;
    }
}

public client_putinserver(id)
{
    if( !is_user_bot(id) && !is_user_hltv(id) )
    {
        g_bConnected{id} = true;
        set_task(2.0, "enter_msg", id);
    }
}

public enter_msg(id)
{
    if( is_user_connected(id) )
    {
        ShowMessage(id, amx_enter_message, amx_enter_message_color, g_szConnectSound);
    }
}

public client_disconnect(id)
{
    if( g_bConnected{id} )
    {
        g_bConnected{id} = false;

        if( task_exists(id) )
        {
            remove_task(id);
        }
        else 
        {
            ShowMessage(id, amx_leave_message, amx_leave_message_color, g_szDisconnectSound);
        }
    }
}

ShowMessage(id, pcvarMessage, pcvarColor, const szSound[])
{
    new message[192];
    get_pcvar_string(pcvarMessage, message, charsmax(message));

    if( message[0] )
    {
        new color[12], red[4], green[4], blue[4]
        get_pcvar_string(pcvarColor, color, charsmax(color));
        parse(color, red, charsmax(red), green, charsmax(green), blue, charsmax(blue))
        new pos = contain(message, namePattern);
        if( pos != -1 )
        {
            new name[32];
            get_user_name(id, name, charsmax(name));
            replace(message[pos], charsmax(message)-pos, namePattern, name);
        }

        if( (pos = contain(message, hostnamePattern)) != -1 )
        {
            new hostname[64];
            get_pcvar_string(pcvar_hostname, hostname, charsmax(hostname));
            replace(message[pos], charsmax(message)-pos, hostnamePattern, hostname);
        }

        if( (pos = contain(message, rankPattern)) != -1 )
        {
            new szRank[32];
            formatex(szRank, charsmax(szRank), "%d", get_user_rank(id));
            replace(message[pos], charsmax(message)-pos, rankPattern, szRank);
        }

        replace_all(message, charsmax(message), "\n", "^n");

        set_hudmessage(str_to_num(red), str_to_num(green), str_to_num(blue), 0.05, 0.55, 0, 6.0, 6.0, 0.5, 0.15, -1);
        show_hudmessage(0, message);
    }

    if( szSound[0] )
    {
        client_cmd(0, "spk %s", szSound);
    }
}

get_user_rank(id)
{
    switch( g_iXstats )
    {
        case _Normal:
        {
            new stats[8], hits[8];
            return get_user_stats(id, stats, hits);
        }
        case _Dodx:
        {
            new stats[9], hits[8];
            return get_user_stats(id, stats, hits);
        }
    }
    return 0;
} 


[BLacking98]

No it has nothing to do with that Balck.
Look Kah, this isn't a plugin. This is a regular addon that comes with AMX MOD X.
If you turn your multiplayer game into a dedicated server and a real person (not a bot) enters, that message will appear.
As simple as that
PM me for more questions ;)

[YamiKaitou]

Originally Posted by BLacking98 Look Kah, this isn't a plugin. This is a regular addon that comes with AMX MOD X. If you turn your multiplayer game into a dedicated server and a real person (not a bot) enters, that message will appear.

AMXX does not include this feature by default. A plugin is required to accomplish this

[ConnorMcLeod]

Originally Posted by BLacking98 PM me for more questions ;)

Sounds really stupid.

[BLacking98]

Originally Posted by ConnorMcLeod Sounds really stupid.

God I'm offering help x)