[LukeyB]

I'm trying to get cz bots to stop when shooting to increase their accuracy, then continue to move as normal. I have got it to where they will stop when shooting but can't move again. Here is what I have so far.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <fun>
// any of the buttons on the right will count as moving
#define IN_MOVING (IN_FORWARD|IN_BACK|IN_MOVELEFT|IN_MOVERIGHT| IN_JUMP)
// Tracks players Shots-Fired: [0]=WeaponID, [1]=Ammo
new g_iCurrWeapon[33][2]
public plugin_init()
{
register_event( "CurWeapon", "Event_ShotFired", "b" )
}
public Event_ShotFired( id )
{
// Players current weapon data..
new wID = read_data( 2 )
new wAmmo = read_data( 3 )
if( g_iCurrWeapon[id][0] != wID ) // User Changed Weapons..
{
g_iCurrWeapon[id][0] = wID
g_iCurrWeapon[id][1] = wAmmo
return PLUGIN_CONTINUE
}
if( g_iCurrWeapon[id][1] < wAmmo ) // User Reloaded..
{
g_iCurrWeapon[id][1] = wAmmo
return PLUGIN_CONTINUE
}
if( g_iCurrWeapon[id][1] == wAmmo ) // User did something else, but didn't shoot..
{
return PLUGIN_CONTINUE
}
// This far means user shot his/her gun..
// Save new weapon data..
g_iCurrWeapon[id][1] = wAmmo
g_iCurrWeapon[id][0] = wID
// Do Stuff here..
// he is alive and using movement keys
if( is_user_alive(id) && is_user_bot(id) && (pev(id, pev_button) & IN_MOVING) )
{
// make sure he is using a gun
if( wID != CSW_HEGRENADE && wID != CSW_FLASHBANG && wID != CSW_SMOKEGRENADE
&& wID != CSW_C4 && wID != CSW_KNIFE )
{
set_user_maxspeed( id , 0.1)
}
}
return PLUGIN_CONTINUE
} 


[Xellath]

You could try hooking Ham_Weapon_PrimaryAttack in both Pre (and set maxspeed to 0.1) and in Post (reset the maxspeed).

[LukeyB]

Thanks. How would I go about doing this for all weapons?

[Xellath]

#include < amxmodx >
#include < hamsandwich >
#include < fun >

const m_pPlayer = 41;

public plugin_init( )
{
    new WeaponName[ 32 ];
    // no knifes, nades or c4
    new NoPrimaryAttack = ( ( 1 << CSW_KNIFE ) | ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_C4 ) ); 
    for( new CSWConstant = CSW_P228; CSWConstant <= CSW_P90; CSWConstant++ ) 
    {
        if( ~NoPrimaryAttack & ( 1 << CSWConstant ) // check for invalid CSW_* constants
        && get_weaponname( CSWConstant, WeaponName, charsmax( WeaponName ) ) ) // get weaponname
        {
            RegisterHam( Ham_Weapon_PrimaryAttack, WeaponName, "Ham_Weapon_PrimaryAttack_Pre", 0 ); // hook pre
            RegisterHam( Ham_Weapon_PrimaryAttack, WeaponName, "Ham_Weapon_PrimaryAttack_Post", 1 ); // hook post
        }
    }
}

public Ham_Weapon_PrimaryAttack_Pre( Weapon ) 
{
    new id = get_pdata_cbase( Weapon, m_pPlayer, 4 ); 
    
    set_user_maxspeed( id, 0.1 ); // set low speed
}

public Ham_Weapon_PrimaryAttack_Post( Weapon ) 
{
    new id = get_pdata_cbase( Weapon, m_pPlayer, 4 ); 
    
    set_user_maxspeed( id ); // reset speed
}

[LukeyB]

Thanks for your help, but I get a lot of errors when trying to compile this.

[Devil259]

#include < fun >

[Xellath]

Originally Posted by Devil259 #include < fun >

Forgot about that. Thanks. Edited.

[LukeyB]

I appreciate your help with this. Unfortunately the speed does not reset until weapon is changed, which is a problem for the bots. I would like for this not to affect players, only bots and when I add is_user_alive(id) && is_user_bot(id) && to the script, i get error 017: undefined symbol "id".

PHP Code:

#include < amxmodx >
#include < hamsandwich >
#include < fun >
const m_pPlayer = 41;
public plugin_init( )
{
    new WeaponName[ 32 ];
    // no knifes, nades or c4
    new NoPrimaryAttack = ( ( 1 << CSW_KNIFE ) | ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_C4 ) ); 
    for( new CSWConstant = CSW_P228; CSWConstant <= CSW_P90; CSWConstant++ ) 
    {
        if( is_user_alive(id) && is_user_bot(id) && ~NoPrimaryAttack & ( 1 << CSWConstant ) // check for invalid CSW_* constants
        && get_weaponname( CSWConstant, WeaponName, charsmax( WeaponName ) ) ) // get weaponname
        {
            RegisterHam( Ham_Weapon_PrimaryAttack, WeaponName, "Ham_Weapon_PrimaryAttack_Pre", 0 ); // hook pre
            RegisterHam( Ham_Weapon_PrimaryAttack, WeaponName, "Ham_Weapon_PrimaryAttack_Post", 1 ); // hook post
        }
    }
}
public Ham_Weapon_PrimaryAttack_Pre( Weapon ) 
{
    new id = get_pdata_cbase( Weapon, m_pPlayer, 4 ); 
    
    set_user_maxspeed( id, 0.1 ); // set low speed
}
public Ham_Weapon_PrimaryAttack_Post( Weapon ) 
{
    new id = get_pdata_cbase( Weapon, m_pPlayer, 4 ); 
    
    set_user_maxspeed( id ); // reset speed
} 


Thanks again for your help!

[Devil259]

You can't use id in plugin_init( )

#include < amxmodx >
#include < hamsandwich >
#include < fun >

const m_pPlayer = 41;

public plugin_init( )
{
    new WeaponName[ 32 ];
    // no knifes, nades or c4
    new NoPrimaryAttack = ( ( 1 << CSW_KNIFE ) | ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_C4 ) ); 
    for( new CSWConstant = CSW_P228; CSWConstant <= CSW_P90; CSWConstant++ ) 
    {
        if( ~NoPrimaryAttack & ( 1 << CSWConstant ) // check for invalid CSW_* constants
        && get_weaponname( CSWConstant, WeaponName, charsmax( WeaponName ) ) ) // get weaponname
        {
            RegisterHam( Ham_Weapon_PrimaryAttack, WeaponName, "Ham_Weapon_PrimaryAttack_Pre", 0 ); // hook pre
            RegisterHam( Ham_Weapon_PrimaryAttack, WeaponName, "Ham_Weapon_PrimaryAttack_Post", 1 ); // hook post
        }
    }
}

public Ham_Weapon_PrimaryAttack_Pre( Weapon ) 
{
    new id = get_pdata_cbase( Weapon, m_pPlayer, 4 ); 
    
    if( is_user_bot( id ) )
        set_user_maxspeed( id, 0.1 ); // set low speed
}

public Ham_Weapon_PrimaryAttack_Post( Weapon ) 
{
    new id = get_pdata_cbase( Weapon, m_pPlayer, 4 ); 
    
    if( is_user_bot( id ) )
        set_user_maxspeed( id ); // reset speed
}

If it doesn't work, try to use pev_velocity.

[LukeyB]

Gotcha. I am learning slowly, but surely.

This does stop the bot when shooting, but the bot speed in not reset after shooting so they get stuck in place.

Was reading about pev_velocity and am confused on how to add this instead of set_user_maxspeed.

Thanks again for all of your help.