[I'mSane]

When I'm trying to teleport an entity when playing, entity teleports exactly to my player. But when I'm a spectator, it works properly and entity teleports to the point when I aim. Here's code:

PHP Code:

decl Float:vecOrigin[3], Float:vecAngles[3], Float:vecPos[3];  
GetClientAbsOrigin(client, vecOrigin); 
GetClientEyeAngles(client, vecAngles); 
new Handle:trace = TR_TraceRayFilterEx(vecOrigin, vecAngles, CONTENTS_SOLID|CONTENTS_MOVEABLE, RayType_Infinite, TraceEntityFilterPlayers, ent);  
if(TR_DidHit(trace)) 
{  
    TR_GetEndPosition(vecPos, trace); 
} 
CloseHandle(trace); 
TeleportEntity(ent, vecPos, NULL_VECTOR, NULL_VECTOR); 


Why?

[McFlurry]

A little bit of code from Zuko's Weapon Spawner
you must define g_pos[3] at the beginning of your plugin. Then this will return true if there is a spawn point it hit or false if it goes on into infinity.
then teleport the entity using g_pos as the place for it to go.

PHP Code:

SetTeleportEndPoint(client)
{
    decl Float:vAngles[3];
    decl Float:vOrigin[3];
    decl Float:vBuffer[3];
    decl Float:vStart[3];
    decl Float:Distance;
    
    GetClientEyePosition(client,vOrigin);
    GetClientEyeAngles(client, vAngles);
    
    //get endpoint for teleport
    new Handle:trace = TR_TraceRayFilterEx(vOrigin, vAngles, MASK_SHOT, RayType_Infinite, TraceEntityFilterPlayer);

    if(TR_DidHit(trace))
    {
        TR_GetEndPosition(vStart, trace);
        GetVectorDistance(vOrigin, vStart, false);
        Distance = -35.0;
        GetAngleVectors(vAngles, vBuffer, NULL_VECTOR, NULL_VECTOR);
        g_pos[0] = vStart[0] + (vBuffer[0]*Distance);
        g_pos[1] = vStart[1] + (vBuffer[1]*Distance);
        g_pos[2] = vStart[2] + (vBuffer[2]*Distance);
    }
    else
    {
        CloseHandle(trace);
        return false;
    }
    CloseHandle(trace);
    return true;
} 


[I'mSane]

Yes, now it works! Thank you!

[blodia]

when you're alive the trace hits the player since the trace starts inside the player. you defined the filter as TraceEntityFilterPlayers inside this function you can choose whether the ray should hit the entity or not.