[spancer35]

Hi there,

In multigames players shouldn't kill each other at spawn so multigame maps spawns players without guns or knives but in some maps players can use that items from last round and kills player at spawn this brakes a lot. I need a plugin to disarm all players on round start.

You can use "sm_disarm @all" command

Thank you!

sorry for my bad english

[PinHeaDi]

PHP Code:

#include <sourcemod>
#include <cstrike>
#include <smlib>

#define StripConfig "configs/strip_mapconfig.cfg"
bool StripMap;

public void OnPluginStart()
{
    HookEvent("player_spawn", PlayerSpawn);
}

public Action PlayerSpawn(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(event, "userid"));

    if (StripMap)
    {
        Client_RemoveAllWeapons(client, "", true);
    }
    
    return Plugin_Continue;
}

public void OnMapStart()
{
    checkmapforstrip();
}

void checkmapforstrip()
{
    char line[128], g_Config[PLATFORM_MAX_PATH], g_CurrentMap[128];
    GetCurrentMap(g_CurrentMap, sizeof(g_CurrentMap));
    BuildPath(Path_SM, g_Config, sizeof(g_Config), StripConfig);

    StripMap = false;
    File StripMaps;
    StripMaps = OpenFile(g_Config, "r");

    if (StripMaps != null)
    {
        while(StripMaps.ReadLine(line, sizeof(line)))
        {
            TrimString(line);
            if (StrEqual(line, g_CurrentMap, true))
            {
                StripMap = true;
                break;
            }
        }
        StripMaps.Close();
    }
} 


Make a new config file strip_mapconfig.cfg in ./addons/sourcemod/configs and the maps where the guns need to be stripped (Every map on new line, without the .bsp extension). You need smlib to compile the plugin. Example config:

PHP Code:

mg_awp_multigames_csgo
mg_raphi_multigame 


[spancer35]

Works perfectly. Thank you so much!