[tRololo312312]

Hello. Im trying to make MedicBot to work on other classes too but i have a problem with it.

My idea for other classes was that afk players follow allies (that are not afk) until enemy becomes visible. After that they ignore allies until no enemies on vision.

Problem is that, when enemy becomes visible for afk player, afk player still follows ally and will not shoot enemy until enemy is closer than that ally.

Code:

		if(IsPointVisible(vecOrigin_center, vecOrigin_edict) && classme != TFClass_Medic)
		{
			if(GetClientTeam(i) != GetClientTeam(client))
			{
				if (TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
					continue;
				new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
				if((edict_distance < distance) || (distance == -1.0))
				{
					distance = edict_distance;
					closestEdict = i;
				}
			}
			else if(GetClientTeam(i) == GetClientTeam(client))
			{
				if(g_bAfkbot[i] || TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
					continue;
				new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
				if((edict_distance < distance) || (distance == -1.0))
				{
					distance = edict_distance;
					closestEdict = i;
				}
			}
		}

Please help.

[Miu]

PHP Code:

        if(IsPointVisible(vecOrigin_center, vecOrigin_edict) && classme != TFClass_Medic)
        {
            if(GetClientTeam(i) != GetClientTeam(client))
            {
                if (TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
                    continue;
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
                if((edict_distance < distance) || (distance == -1.0))
                {
                    distance = edict_distance;
                    closestEdict = i;
                }
            }
            else if(GetClientTeam(i) == GetClientTeam(client))
            {
                if(g_bAfkbot[i] || TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
                    continue;
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
                if(((edict_distance < distance) || (distance == -1.0)) && (!closestEdict || GetClientTeam(closestEdict) == GetClientTeam(client)))
                {
                    distance = edict_distance;
                    closestEdict = i;
                }
            }
        } 


[tRololo312312]

Still not working. Now its not detecting anyone

[Miu]

well it depends on the default value of closestEdict, if it's -1 you need to change !closestEdict to closestEdict == -1. that should be the right change in logic though, checking if closestEdict is currently either unset or another ally before setting it to an ally.

[tRololo312312]

Originally Posted by Miu well it depends on the default value of closestEdict, if it's -1 you need to change !closestEdict to closestEdict == -1. that should be the right change in logic though, checking if closestEdict is currently either unset or another ally before setting it to an ally.

Well now it detects players again, but still follows own team member even though Enemy is visible until Enemy is closer than the Team mate.

Here is the whole stock:

PHP Code:

stock Client_GetClosest(Float:vecOrigin_center[3], const client)
{    
    decl Float:vecOrigin_edict[3];
    new Float:distance = -1.0;
    new closestEdict = -1;
    for(new i=1;i<=MaxClients;i++)
    {
        if (!IsClientInGame(i) || !IsPlayerAlive(i) || (i == client))
            continue;
        GetClientEyePosition(i, vecOrigin_edict);
        new TFClassType:classme = TF2_GetPlayerClass(client);
        if(GetClientTeam(i) == GetClientTeam(client) && classme == TFClass_Medic)
        {
            new TFClassType:class = TF2_GetPlayerClass(i);
            if(g_bAfkbot[i] && class == TFClass_Medic || TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
                continue;
            if(IsPointVisible(vecOrigin_center, vecOrigin_edict))
            {
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
                if((edict_distance < distance) || (distance == -1.0))
                {
                    distance = edict_distance;
                    closestEdict = i;
                }
            }
        }
        else if(GetClientTeam(i) != GetClientTeam(client) && classme == TFClass_Medic)
        {
            if (TF_IsUberCharge(client) || TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
                continue;
            if(IsPointVisible(vecOrigin_center, vecOrigin_edict))
            {
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
                if((edict_distance < distance) || (distance == -1.0))
                {
                    distance = edict_distance;
                    closestEdict = i;
                }
            }
        }

        if(IsPointVisible(vecOrigin_center, vecOrigin_edict) && classme != TFClass_Medic)
        {
            if(GetClientTeam(i) != GetClientTeam(client))
            {
                if (TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
                    continue;
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
                if((edict_distance < distance) || (distance == -1.0))
                {
                    distance = edict_distance;
                    closestEdict = i;
                }
            }
            else if(GetClientTeam(i) == GetClientTeam(client))
            {
                if(g_bAfkbot[i] || TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised))
                    continue;
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict);
                if(((edict_distance < distance) || (distance == -1.0)) && (closestEdict == -1 || GetClientTeam(closestEdict) == GetClientTeam(client)))
                {
                    distance = edict_distance;
                    closestEdict = i;
                }
            }
        }
    }
    return closestEdict;
} 


[Miu]

ah my bad, try this

PHP Code:

        if(IsPointVisible(vecOrigin_center, vecOrigin_edict) && classme != TFClass_Medic) 
        { 
            if(GetClientTeam(i) != GetClientTeam(client)) 
            { 
                if (TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised)) 
                    continue; 
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict); 
                if(closestEdict == -1 || edict_distance < distance || GetClientTeam(closestEdict) == GetClientTeam(client)) 
                { 
                    distance = edict_distance; 
                    closestEdict = i; 
                } 
            } 
            else if(GetClientTeam(i) == GetClientTeam(client)) 
            { 
                if(g_bAfkbot[i] || TF2_IsPlayerInCondition(i, TFCond_Cloaked) || TF2_IsPlayerInCondition(i, TFCond_Disguised)) 
                    continue; 
                new Float:edict_distance = GetVectorDistance(vecOrigin_center, vecOrigin_edict); 
                if(closestEdict == -1 || (edict_distance < distance && GetClientTeam(closestEdict) == GetClientTeam(client)))
                { 
                    distance = edict_distance;
                    closestEdict = i;
                } 
            } 
        } 


[tRololo312312]

It works! Thank you so much for your effort!