[PC Gamer]

What is the best method of making all TF2 Bots stop moving and attacking?

I tried the server command of 'nb_blind 1'. I tried adding condition 87. I tried adding the no attack attribute to Bot weapons. I tried the Freeze command. These either didn't work or only partially worked.

I ended up making the script below. It prevents the Bots from moving and it removes their weapons so they can't attack. It just seems like a hacky way of doing it.

Is there a better way of preventing Bots from moving and attacking that allows them to keep their weapons?

Code:

PHP Code:

#include <sourcemod>
#include <tf2_stocks> 

#pragma semicolon 1
#pragma newdecls required

#define PLUGIN_VERSION "1.0"

public Plugin myinfo = 
{
    name = "Bots Chill/Attack",
    author = "PC Gamer",
    description = "Prevents Bots from moving or attacking",
    version = PLUGIN_VERSION,
    url = "https://www.alliedmods.net"
}

public void OnPluginStart() 
{    
    RegAdminCmd("sm_botschill", Command_BotsChill, ADMFLAG_SLAY, "Make Bots Chill");
    RegAdminCmd("sm_botsattack", Command_BotsAttack, ADMFLAG_SLAY, "Make Bots Attack");    
}

public Action Command_BotsChill(int client, int args)
{
    ReplyToCommand(client, "Bots are now Chill and won't move or attack.");
    ReplyToCommand(client, "Use sm_botsattack to make them move/attack again");    
    PrintToChatAll("Bots have been forced to Chill. They no longer move or attack");
    
    int i;
    for (i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i) && IsFakeClient(i))
        {
            SetEntityMoveType(i, MOVETYPE_NONE);
            TF2_RemoveWeaponSlot(i, 0);
            TF2_RemoveWeaponSlot(i, 1);            
            TF2_RemoveWeaponSlot(i, 2);    
            SetEntPropEnt(i, Prop_Send, "m_hActiveWeapon", -1);
        }
    }

    return Plugin_Handled;
}

public Action Command_BotsAttack(int client, int args)
{
    ReplyToCommand(client, "Bots are now moving and attacking.");
    ReplyToCommand(client, "Use sm_botschill to make them stop attacking again");
    PrintToChatAll("Bots are no longer Chill.  They will now move and attack");

    int i;
    for (i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i) && IsFakeClient(i))
        {
            SetEntityMoveType(i, MOVETYPE_WALK);
            TF2_RegeneratePlayer(i);            
        }
    }

    return Plugin_Handled;
} 


[FroGeX]

bot_stop 1 not work in TF2?

[PC Gamer]

Originally Posted by FroGeX bot_stop 1 not work in TF2?

bot_stop is an unknown command in TF2

[ThatKidWhoGames]

You might be able to do something along the lines of hooking button presses for bots with OnPlayerRunCmd and blocking them (completely untested though).

[nosoop]

Originally Posted by PC Gamer bot_stop is an unknown command in TF2

It should be nb_stop for TF.

The leaked source suggests that you can also apply the FL_FROZEN entity flag, or you can prevent the bot from being flagged for updates (getting the member variable for that is an exercise left to you, since it's inlined), or you can supercede NextBotManager::ShouldUpdate() entirely.

Setting the next think time might also work since it's controlled by the think system, but I've tested exactly zero of these.

[PC Gamer]

Thanks ThatKidWhoGames! I generally avoid using OnPlayerRunCmd because of the resource drain but in this case I think it is probably the best option.

Thanks nosoop! As usual, great answer. I just tested the nb_stop command. I can confirm that it mostly works but I didn't like the results. When enabled the Bots still move until they reach a map barrier or wall. I was hoping for an immediate stop. I also noticed a Pyro continuing to use his flamethrower and a Demoman with shield continued to charge, even after hitting a wall. I previously tested FL_FROZEN and found that it worked as desired as far as the player not moving or firing. However, made the targets turn blue.

I developed and tested a solution using the recommendation from ThatKidWhoGames and it works well. The Bots stop moving immediately. They keep their weapons. They don't attack. Here's the working solution for anyone that is interested:

PHP Code:

#include <sourcemod>
#include <tf2_stocks> 

#pragma semicolon 1
#pragma newdecls required

bool g_bBotsAreChill = false;

#define PLUGIN_VERSION "1.1"

public Plugin myinfo = 
{
    name = "Bots Chill/Attack",
    author = "PC Gamer",
    description = "Prevents Bots from moving or attacking",
    version = PLUGIN_VERSION,
    url = "https://www.alliedmods.net"
}

public void OnPluginStart() 
{    
    RegAdminCmd("sm_botschill", Command_BotsChill, ADMFLAG_SLAY, "Make Bots Chill");
    RegAdminCmd("sm_botsattack", Command_BotsAttack, ADMFLAG_SLAY, "Make Bots Attack");    
}

public Action Command_BotsChill(int client, int args)
{
    ReplyToCommand(client, "Bots are now Chill and won't move or attack.");
    ReplyToCommand(client, "Use sm_botsattack to make them move/attack again");    
    PrintToChatAll("Bots have been forced to Chill. They no longer move or attack");

    g_bBotsAreChill = true;
    
    int i;
    for (i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i) && IsFakeClient(i))
        {
            SetEntityMoveType(i, MOVETYPE_NONE);
        }
    }

    return Plugin_Handled;
}

public Action Command_BotsAttack(int client, int args)
{
    ReplyToCommand(client, "Bots are now moving and attacking.");
    ReplyToCommand(client, "Use sm_botschill to make them stop attacking again");
    PrintToChatAll("Bots are no longer Chill.  They will now move and attack");
    
    g_bBotsAreChill = false;
    
    int i;
    for (i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i) && IsFakeClient(i))
        {
            SetEntityMoveType(i, MOVETYPE_WALK);
            TF2_RegeneratePlayer(i);            
        }
    }

    return Plugin_Handled;
}

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float vel[3], float angles[3], int &weapon) 
{ 
    if (g_bBotsAreChill == true && IsFakeClient(client)) 
    { 
        if(buttons & IN_ATTACK || buttons & IN_ATTACK2 || buttons & IN_ATTACK3)         
        { 
            return Plugin_Handled;
        }
    }
    
    return Plugin_Continue;    
} 


[Pelipoika]

nb_player_move 0
tf_bot_fire_weapon_allowed 0
nb_blind 1 ?