[Depresie]

is_visible native doesn't work correctly, even tho there is another player in my sight the client print is not displayed, however if the entity = target it works...

Tested on -> 1.8.3 last dev / 1.8.2 same result

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <engine>
#include <fakemeta>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "author"


public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_clcmd("say check", "checkvis")
    
    // Add your code here...
}

public checkvis(id)
{
    new iPlayers[32], iNum, pl2
    
    get_players(iPlayers, iNum, "h")
    
    for(new i = 0; i < iNum; i++)
    {
        pl2 = iPlayers[i]
        
        if( (id != pl2 ) && is_visible(id, pl2))
        {
            client_print(0, print_chat, "Another player in sight")
        }
    }
} 


[Arkshine]

is_visible is very basic and just trace a straight line between your eye position (origin + view_ofs) and the other player as well. If there is something blocking the line (like a well corner), it will return false. Check the tutorial section for engineX or whatever, don't remember.

[Depresie]

I was standing right in front of the target... nothing in between us

[Arkshine]

It's a copy paste of the HLDS function, I don't see how it could fail unless you're messing with player's flags or trace handle.

[Depresie]

Wasn't messing with anything, it was tested on stock amxmodx 1.8.3 and 1.8.2 no other plugins running, the script used was the one above

[PRoSToTeM@]

Fraction can't be 1.0 because ray hits target head before end point.
You can check it:

#include <amxmodx>
#include <fakemeta>

public plugin_init() {
    register_clcmd("say /checkvis", "OnClientCmdSayCheckVisReceive");
}

public OnClientCmdSayCheckVisReceive(player) {
    new anotherPlayer = FindAnotherPlayer(player);
    if (anotherPlayer != 0) {
        new traceResult = create_tr2();
        engfunc(
            EngFunc_TraceLine,
            GetPlayerEyePosition(player),
            GetPlayerEyePosition(anotherPlayer),
            DONT_IGNORE_MONSTERS,
            player,
            traceResult);
        
        new Float:fraction;
        get_tr2(traceResult, TR_flFraction, fraction);
        client_print(
            player,
            print_chat,
            "InOpen: %s, InWater: %s, Fraction: %.3f",
            get_tr2(traceResult, TR_InOpen) != 0 ? "True" : "False",
            get_tr2(traceResult, TR_InWater) != 0 ? "True" : "False",
            fraction);
        
        free_tr2(traceResult);
    }
}

FindAnotherPlayer(currentPlayer) {
    new bool:found = false;
    new savedPlayer = 0;
    for (new anotherPlayer = 1; anotherPlayer <= get_maxplayers(); anotherPlayer++) {
        if (!is_user_alive(anotherPlayer)) {
            continue;
        }
        if (anotherPlayer != currentPlayer) {
            if (found) {
                return 0;
            }
            
            savedPlayer = anotherPlayer;
            found = true;
        }
    }
    
    return savedPlayer;
}

Float:GetPlayerEyePosition(player) {
    new Float:position[3];
    pev(player, pev_origin, position);
    new Float:eyeOffset[3];
    pev(player, pev_view_ofs, eyeOffset);
    position[0] += eyeOffset[0];
    position[1] += eyeOffset[1];
    position[2] += eyeOffset[2];
    return position;
}

[Arkshine]

^ He's right, fraction will be never 1.0, not sure why it hasn't been reported already .

[Depresie]

Another bug, another cookie...

[PRoSToTeM@]

I don't know the best way, but this works good:

new oldSolid = pev(anotherPlayer, pev_solid);
set_pev(anotherPlayer, pev_solid, SOLID_NOT);
engfunc(
    EngFunc_TraceLine,
    GetPlayerEyePosition(player),
    GetPlayerEyePosition(anotherPlayer),
    DONT_IGNORE_MONSTERS,
    player,
    traceResult);
set_pev(anotherPlayer, pev_solid, oldSolid);