[PriceLess]

Hi there, im testing out some new stuff for my server..

The issue I'm having I sew the tuts at wiki. But how can I make them virutualy press a button?

Like etc. Shift or ctrl. I figgured out how to block them, but didnt help out much.. Is this possible?

[K0Killer2]

PHP Code:

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon)
{
    buttons |= IN_DUCK;
} 


[PriceLess]

When i execute the command the only error that appears 100's time per second is Can't find second player or something like that.
And it says unknown command. But it prints out the message obviously.

PHP Code:

#include <sourcemod>
#include <sdktools>

new PandaFreeday = 0;
new ZombieFreeday = 0;

public OnPluginStart()
{
    RegConsoleCmd("sm_panda", Panda);
    RegConsoleCmd("sm_zombie", Zombie);
}

public Action:Panda(client, args)
{
    PandaFreeday = 1;
    PrintToChatAll("Panda freeday");
}

public Action:Zombie(client, args)
{
    ZombieFreeday = 1;
    PrintToChatAll("Zombie freeday");
}
    

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon)
{
    for (new i = 1; GetMaxClients(); i++)
    {
        if(GetClientTeam(i) == 2)
        {
            if(PandaFreeday == 1)
            {
                buttons |= IN_DUCK;
                buttons |= IN_LEFT;
            }
            return Plugin_Continue;
            
            if(ZombieFreeday == 1)
            {
                buttons |= IN_WALK;
                buttons |= IN_RIGHT;
            }
            return Plugin_Continue;
        }
    }
} 


[K0Killer2]

The loop wasn't needed. You also had returns in random places.

PHP Code:

#include <sourcemod> 
#include <sdktools> 

new PandaFreeday = 0; 
new ZombieFreeday = 0; 

public OnPluginStart() 
{ 
    RegConsoleCmd("sm_panda", Panda); 
    RegConsoleCmd("sm_zombie", Zombie); 
} 

public Action:Panda(client, args) 
{ 
    PandaFreeday = 1; 
    PrintToChatAll("Panda freeday"); 
} 

public Action:Zombie(client, args) 
{ 
    ZombieFreeday = 1; 
    PrintToChatAll("Zombie freeday"); 
} 
     

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon) 
{ 
    if(GetClientTeam(client) == 2) 
    { 
        if(PandaFreeday == 1) 
        { 
            buttons |= IN_DUCK; 
            buttons |= IN_LEFT; 
        }  
        if(ZombieFreeday == 1) 
        { 
            buttons |= IN_WALK; 
            buttons |= IN_RIGHT;
        } 
    }
} 


[shavit]

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <cstrike>

#pragma semicolon 1

new Day;

public Plugin:myinfo =
{
    name = "Jailbreak Days",
    author = "PriceLess",
    description = "Jailbreak days, duh",
    version = "1.0"
}

public OnPluginStart()
{
    RegAdminCmd("sm_panda", PandaDay, ADMFLAG_GENERIC, "Activate \"Panda Day\"");
    RegAdminCmd("sm_zombie", ZombieDay, ADMFLAG_GENERIC, "Activate \"Zombie Day\"");
    RegAdminCmd("sm_nodays", NoDays, ADMFLAG_GENERIC, "Disable all Jailbreak days.");
}

public Action:NoDays(client, args)
{
    if(!IsValidClient(client))
    {
        return Plugin_Handled;
    }

    Day = 0;

    ReplyToCommand(client, "\x04[SM]\x01 No days are activated.");

    return Plugin_Handled;
}

public Action:PandaDay(client, args)
{ 
    if(!IsValidClient(client))
    {
        return Plugin_Handled;
    }

    Day = 1;

    ReplyToCommand(client, "\x04[SM]\x01 Panda day is activated.");

    return Plugin_Handled;
}

public Action:ZombieDay(client, args)
{
    if(!IsValidClient(client))
    {
        return Plugin_Handled;
    }

    Day = 2;

    ReplyToCommand(client, "\x04[SM]\x01 Zombie day is activated.");

    return Plugin_Handled;
}
     

public Action:OnPlayerRunCmd(client, &buttons, &impulse, Float:vel[3], Float:angles[3], &weapon) 
{
    if(!IsValidClient(client, true))
    {
        return Plugin_Continue;
    }

    if(GetClientTeam(client) == CS_TEAM_T) 
    {
        switch(Day)
        {
            case 1:
            {
                buttons |= IN_DUCK;
                buttons |= IN_LEFT;
            }

            case 2:
            {
                buttons |= IN_WALK;
                buttons |= IN_RIGHT;
            }

            default:
            {
                return Plugin_Continue;
            }
        }
    }

    return Plugin_Continue;
}

stock bool:IsValidClient(client, bool:bAlive = false)
{
    if(client >= 1 && client <= MaxClients && IsClientConnected(client) && IsClientInGame(client) && (bAlive == false || IsPlayerAlive(client)))
    {
        return true;
    }
    
    return false;
} 


[K0Killer2]

Can a client running a command be invalid? I don't see why you need to check for that.

[Powerlord]

If you're going to check every player, you might was well do it on a 0.1 sec timer or in OnGameFrame.

[PriceLess]

For some reason the buttons doesn't force on zombie?