[r14170]

How do i spin an entity around me in radius of some units?

[Hunter-Digital]

Well, if it's a point entity and you really must rotate it the hard way, there are alot of calculations to do which I don't have experience in... however, if the sole purpose of that entity is to orbit a player, you can make the model of that entity offset from the center and then just place the entity in the middle of the player and apply rotation velocity, that will make it look like it's orbiting.

[Exolent[jNr]]

Originally Posted by Hunter-Digital if it's a point entity and you really must rotate it the hard way

Here's some example code for that.

Note that you should use a different think method (such as register_think()) as it would be more efficient than FM_Think.
FM_Think was only used in this example to be generic enough so you could understand the idea.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <xs>

#define SPECIAL_ROTATE_VALUE 3761571

public plugin_init() {
    register_forward(FM_Think, "FwdThink");
}

public FwdThink(ent) {
    if(pev(ent, pev_iuser4) == SPECIAL_ROTATE_VALUE) {
        new Float:center[3];
        pev(ent, pev_vuser4, center);
        
        new Float:radius, Float:rps;
        pev(ent, pev_fuser3, radius);
        pev(ent, pev_fuser4, rps);
        
        new Float:degrees;
        pev(ent, pev_fuser2, degrees);
        
        if(++degrees > 180.0) {
            degrees -= 360.0;
        }
        
        new Float:angle[3];
        angle[1] = degrees;
        
        angle_vector(angle, ANGLEVECTOR_FORWARD, angle);
        
        xs_vec_mul_scalar(angle, radius / vector_length(angle), angle);
        xs_vec_add(angle, center, angle);
        
        engfunc(EngFunc_SetOrigin, ent, angle);
        
        set_pev(ent, pev_fuser2, degrees);
        
        set_pev(ent, pev_nextthink, get_gametime() + (1.0 / rps / 360.0));
    }
}

// rps = rotations per second
StartRotate(ent, Float:center[3], Float:radius, Float:rps) {
    set_pev(ent, pev_iuser4, SPECIAL_ROTATE_VALUE);
    
    set_pev(ent, pev_vuser4, center);
    set_pev(ent, pev_fuser3, radius);
    set_pev(ent, pev_fuser4, rps);
    
    set_pev(ent, pev_fuser2, 0.0); // set initial degrees to 0
    
    set_pev(ent, pev_nextthink, get_gametime());
} 


[SpeeDeeR]

In this case, you have to consider renaming

PHP Code:

new Float:degrees; 


to something different, because its predefined in xs and float includes.

[avril-lavigne]

hm interesting.
can I rotate a rocket with this code while it moving in the air ?

[Exolent[jNr]]

Yes. You would have to calculate the angles based on the certain degree angle.
Angle calculations for the model may vary by the model being used.