[Bacardi]

PHP Code:

public OnPluginStart()
{
    HookUserMessage(GetUserMessageId("SayText2"), SayText2, true);
}

public Action:SayText2(UserMsg:msg_id, Handle:bf, players[], playersNum, bool:reliable, bool:init)
{
    if(!reliable)
    {
        return Plugin_Continue;
    }

    new String:buffer[25];

    if(GetUserMessageType() == UM_Protobuf) // CSGO
    {
        PbReadString(bf, "msg_name", buffer, sizeof(buffer));

        if(StrEqual(buffer, "#Cstrike_Name_Change"))
        {
            return Plugin_Handled;
        }
    }
    else // CSS
    {
        BfReadChar(bf);
        BfReadChar(bf);
        BfReadString(bf, buffer, sizeof(buffer));

        if(StrEqual(buffer, "#Cstrike_Name_Change"))
        {
            return Plugin_Handled;
        } 
    }
    return Plugin_Continue;
} 


[TnTSCS]

Do we need protobuf instead of bitbuffer or no?

This is one of the areas I've not ventured into much, yet.

[Root_]

Protobuf is required for CS:GO and Dota2, each other still using bitbuffer.
And yeah, most likely Bacardi's snippet will work fine

[TheWho]

Thanks for every help!