[Bugsy]

You don't need replace(), use szWeaponName[7] in copy(). I would leave out the uppercase first char, that's just me though.

[klippy]

Make GrenadeBits a static constant.

[Bugsy]

Originally Posted by KliPPy Make GrenadeBits a static constant.

I don't think static is necessary here, it's a single cell in a function that likely will not be hammered with usage. I would change it to a const, though.

[klippy]

Originally Posted by Bugsy I don't think static is necessary here, it's a single cell in a function that likely will not be hammered with usage. I would change it to a const, though.

Yeah, while writing that post I was thinking if static is necessary. I think that const on local variables implies static. Anyway, single cell const should make better code than a variable.

[Craxor]

Done.

Tested and works ( see attach example ).

[Bugsy]

Did you re-arrange stuff so that you can pass bpammo param as clip for grenades? If so, I would do the below instead. Though, I don't know if you want to do this or not as it may confuse people who know grenades are stored as a bpammo. They may try to pass the ammo as bpammo which will result in them getting none. You could do something like max( iClip , iBPAmmo ) which will make it grab whichever one is not zero, or whichever is larger. But I think sticking to bpammo param for grenades is better and more consistent.

PHP Code:

give_user_weapon( index , iWeaponTypeID , iClip=0 , iBPAmmo=0 , szWeapon[]="" , maxchars=0 )
{
    if ( !( CSW_P228 <= iWeaponTypeID <= CSW_P90 ) || ( iClip < 0 ) || ( iBPAmmo < 0 ) || !is_user_alive( index ) )
        return -1;
        
    const GrenadeBits = ( ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_C4 ) );
    new szWeaponName[ 20 ] , iWeaponEntity , bool:bIsGrenade;
    
    get_weaponname( iWeaponTypeID , szWeaponName , charsmax( szWeaponName ) );
    
    if ( ( iWeaponEntity = user_has_weapon( index , iWeaponTypeID ) ? find_ent_by_owner( -1 , szWeaponName , index ) : give_item( index , szWeaponName ) ) > 0 )
    {
        bIsGrenade = bool:!!( GrenadeBits & ( 1 << iWeaponTypeID ) );
        
        if ( iClip && !bIsGrenade )
            cs_set_weapon_ammo( iWeaponEntity , iClip );

        if ( iWeaponTypeID == CSW_C4 ) 
            cs_set_user_plant( index , 1 , 1 );
        else if ( ( bIsGrenade && iClip ) || ( !bIsGrenade && iBPAmmo ) )
            cs_set_user_bpammo( index , iWeaponTypeID , bIsGrenade ? iClip : iBPAmmo ); 
            
        if ( maxchars )
            copy( szWeapon , maxchars , szWeaponName );
    }
    
    return iWeaponEntity;
} 


For your post above about getting weapon name without specifying clip, you can skip the param, or specify it directly:

PHP Code:

new szWeaponName[ 20 ];
    
give_user_weapon(id , CSW_C4 , .szWeapon=szWeaponName , .maxchars=charsmax( szWeaponName ) );
client_print( id , print_chat , "You were given a %s" , szWeaponName[ 7 ] ); 


[Craxor]

Now i re-arrange so that can use bpammo & iclip parameter for grenades, will be readed anyway as BpAmmo.

[addons_zz]

Hi, nice stock, but it is missing from its documentation:

@return: Weapon Entity ID
@return: Weapon Entity ID. On failure -1, due the user being dead or an invalid parameter. 

And before that 'return -1;' could be some useful information as:

    if ( !( CSW_P228 <= iWeaponTypeID <= CSW_P90 ) || ( iClip < 0 ) || ( iBPAmmo < 0 ) || !is_user_alive( index ) )
    {
        log_amx( "The item could not given. iWeaponTypeID: %d, iClip: %d, iBPAmmo: %d, is_user_alive? %s",
                iWeaponTypeID, iClip, iBPAmmo, is_user_alive( index ) ? "true" : "false" );
        return -1;
    }

But I am not sure about if this function should log such events.

These lines look trickier:

        @param szWeapon: Weapon Name you give, without weapon_ prefix + with first letter by UpperCase.
        @maxchars: lengh of szWeapon, 20 recomandated.

Because you do not provide them to function, they recive the weapon name by the given maxchars. So, what do you think about this:

        @param szWeapon[]: The weapon name pointer to receive the weapon name for the given iWeaponTypeID. The Weapon Name is 
                             without 'weapon_' prefix with its first letter uppercase. Example: Glock
        @param maxchars: The szWeapon[] pointer max name length accepted. The value 20 is recommended for most weapons.

[Craxor]

Thank , i updadated the doc, about adding an log message if is not respect requrimenets for taking a weapon, answer is No. I will not add something there.

[Bugsy]

You are setting bpammo for c4 and you shouldn't. You should try to avoid calling things that have no impact and also avoid redundant code, you now have set_bpammo() twice when this can be accomplished with 1 like I have in my code.

I agree, I don't think the log should be printed on fail. The function returns -1 in this case, the scripter should be handling this. That would be more of a debugging thing.

I think this works nicely:

PHP Code:

#include <amxmodx>
#include <fun>
#include <engine>
#include <cstrike>

public plugin_init() 
{
    register_clcmd( "say test" , "GiveWeapon" )
}

public GiveWeapon( id )
{
    //Gives M4A1 with 12 clip, 0 bpammo
    give_user_weapon( id , CSW_M4A1 , 12 );
    
    //Gives AK with full clip (default) and 12 bpammo
    give_user_weapon( id , CSW_AK47 , _ , 12 );
    
    //Gives C4
    give_user_weapon( id , CSW_C4 );
    
    //Gives 1 grenade
    give_user_weapon( id , CSW_HEGRENADE );
    
    //Gives 2 flashbang
    give_user_weapon( id , CSW_FLASHBANG , 2 );
    
    //Gives 3 smoke
    give_user_weapon( id , CSW_SMOKEGRENADE , _ , 3 );
}

give_user_weapon( index , iWeaponTypeID , iClip=0 , iBPAmmo=0 , szWeapon[]="" , maxchars=0 )
{
    if ( !( CSW_P228 <= iWeaponTypeID <= CSW_P90 ) || ( iClip < 0 ) || ( iBPAmmo < 0 ) || !is_user_alive( index ) )
        return -1;
    
    new szWeaponName[ 20 ] , iWeaponEntity , GrenadeBits , bool:bIsGrenade;
    
    GrenadeBits = ( ( 1 << CSW_HEGRENADE ) | ( 1 << CSW_FLASHBANG ) | ( 1 << CSW_SMOKEGRENADE ) | ( 1 << CSW_C4 ) );
    
    if ( ( bIsGrenade = bool:!!( GrenadeBits & ( 1 << iWeaponTypeID ) ) ) )
        iClip = clamp( iClip ? iClip : iBPAmmo , 1 );
    
    get_weaponname( iWeaponTypeID , szWeaponName , charsmax( szWeaponName ) );
    
    if ( ( iWeaponEntity = user_has_weapon( index , iWeaponTypeID ) ? find_ent_by_owner( -1 , szWeaponName , index ) : give_item( index , szWeaponName ) ) > 0 )
    {
        if ( iClip && !bIsGrenade )
            cs_set_weapon_ammo( iWeaponEntity , iClip );

        if ( iWeaponTypeID == CSW_C4 ) 
            cs_set_user_plant( index , 1 , 1 );
        else
            cs_set_user_bpammo( index , iWeaponTypeID , bIsGrenade ? iClip : iBPAmmo ); 
            
        if ( maxchars )
            copy( szWeapon , maxchars , szWeaponName );
    }
    
    return iWeaponEntity;
}