[slava123]

how can i edit this script to show the grey screen to the victim on death https://forums.alliedmods.net/showthread.php?t=282773

[Cruze]

PHP Code:

#include <sourcemod>

public Plugin myinfo = 
{
    name = "Blue Screen On Kill",
    author = "Addicted [smol edit by Cruze]",
    version = "1.2",
    url = "oaaron.com"
};

public void OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
}

public Action Event_PlayerDeath(Event ev, const char[] name, bool dbc)
{
    int victim = GetClientOfUserId(ev.GetInt("userid"));

    if(victim < 1 || victim > MaxClients || IsFakeClient(victim))
        return Plugin_Continue;

    ShowScreenFade(victim, 211, 211, 211, 100); // Your preffered grey color code here

    return Plugin_Continue;    
}

void ShowScreenFade(int client, int r, int g, b, int a)
{
    int duration = 200, holdtime = 200, flags = (0x0001 | 0x0010), color[4];

    color[0] = r;
    color[1] = g;
    color[2] = b;
    color[3] = a;

    int clients[2];
    clients[0] = client;

    Handle message = StartMessageEx(GetUserMessageId("Fade"), clients, 1);

    if (GetUserMessageType() == UM_Protobuf)
    {
        Protobuf pb = UserMessageToProtobuf(message);
        pb.SetInt("duration", duration);
        pb.SetInt("hold_time", holdtime);
        pb.SetInt("flags", flags);
        pb.SetColor("clr", color);
    }
    else
    {
        BfWriteShort(message, duration);
        BfWriteShort(message, holdtime);
        BfWriteShort(message, flags);
        BfWriteByte(message, color[0]);
        BfWriteByte(message, color[1]);
        BfWriteByte(message, color[2]);
        BfWriteByte(message, color[3]);
    }

    EndMessage();
} 


[slava123]

Originally Posted by Cruze PHP Code: #include <sourcemod> public Plugin myinfo =  {     name = "Blue Screen On Kill",     author = "Addicted [smol edit by Cruze]",     version = "1.1",     url = "oaaron.com" }; public void OnPluginStart() {     HookEvent("player_death", Event_PlayerDeath); } public Action Event_PlayerDeath(Handle event, const char[] name, bool dontbroadcast) {     int victim = GetClientOfUserId(GetEventInt(event, "victim"));          if (victim < 1 || victim > MaxClients || IsFakeClient(attacker))         return Plugin_Continue;          int clients[2];     clients[0] = victim;     Handle message = StartMessageEx(GetUserMessageId("Fade"), clients, 1);          Protobuf pb = UserMessageToProtobuf(message);     pb.SetInt("duration", 200);     pb.SetInt("hold_time", 200);     pb.SetInt("flags", (0x0001 | 0x0010));     pb.SetColor("clr", {211, 211, 211, 100}); // Your preffered grey color code here          EndMessage();              return Plugin_Continue;     }

i think you should change if (victim < 1 || victim > MaxClients || IsFakeClient(attacker))
to
if (victim < 1 || victim > MaxClients || IsFakeClient(victim))

[slava123]

after testing it doesnt work on css server

[slava123]

PHP Code:

#include <sourcemod>

public Plugin myinfo =
{
    name = "Grey Screen On death",
    author = "Addicted",
    version = "1.0",
    url = "oaaron.com"
};

public void OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
}

public Action Event_PlayerDeath(Handle event, const char[] name, bool dontbroadcast)
{ 
    int victim = GetClientOfUserId(GetEventInt(event, "userid")); 

    if (victim < 1 || victim > MaxClients || !IsClientConnected(victim) || !IsClientInGame(victim) || IsFakeClient(victim)) 
        return Plugin_Continue;

    int clients[2];
    clients[0] = victim;
    int duration = 200,
        holdtime = 200,
        flags = (0x0001 | 0x0010),
        color[4] = {211, 211, 211, 100};
    
    Handle message = StartMessageEx(GetUserMessageId("Fade"), clients, 1);
    if (GetUserMessageType() == UM_Protobuf)
    {
        Protobuf pb = UserMessageToProtobuf(message);
        pb.SetInt("duration", duration);
        pb.SetInt("hold_time", holdtime);
        pb.SetInt("flags", flags);
        pb.SetColor("clr", color);
    }
    else //write them bytez
    {
        BfWriteShort(message, duration);
        BfWriteShort(message, holdtime);
        BfWriteShort(message, flags);
        BfWriteByte(message, color[0]);
        BfWriteByte(message, color[1]);
        BfWriteByte(message, color[2]);
        BfWriteByte(message, color[3]);
    }
    EndMessage();

    return Plugin_Continue;
} 


after some research i found that there is no event called victim you should replace it with userid which is user who died https://wiki.alliedmods.net/Counter-...s#player_death

[Cruze]

Originally Posted by slava123 PHP Code: #include <sourcemod> public Plugin myinfo = {     name = "Grey Screen On death",     author = "Addicted",     version = "1.0",     url = "oaaron.com" }; public void OnPluginStart() {     HookEvent("player_death", Event_PlayerDeath); } public Action Event_PlayerDeath(Handle event, const char[] name, bool dontbroadcast) {      int victim = GetClientOfUserId(GetEventInt(event, "userid"));      if (victim < 1 || victim > MaxClients || !IsClientConnected(victim) || !IsClientInGame(victim) || IsFakeClient(victim))          return Plugin_Continue;     int clients[2];     clients[0] = victim;     int duration = 200,         holdtime = 200,         flags = (0x0001 | 0x0010),         color[4] = {211, 211, 211, 100};          Handle message = StartMessageEx(GetUserMessageId("Fade"), clients, 1);     if (GetUserMessageType() == UM_Protobuf)     {         Protobuf pb = UserMessageToProtobuf(message);         pb.SetInt("duration", duration);         pb.SetInt("hold_time", holdtime);         pb.SetInt("flags", flags);         pb.SetColor("clr", color);     }     else //write them bytez     {         BfWriteShort(message, duration);         BfWriteShort(message, holdtime);         BfWriteShort(message, flags);         BfWriteByte(message, color[0]);         BfWriteByte(message, color[1]);         BfWriteByte(message, color[2]);         BfWriteByte(message, color[3]);     }     EndMessage();     return Plugin_Continue; }  after some research i found that there is no event called victim you should replace it with userid which is user who died https://wiki.alliedmods.net/Counter-...s#player_death

Yeah my bad I am too sleepy I guess. Updated the main post.