[5c0r-|3i0]

I'm tryin' to make a stock that drops players' weapons and keep backpack ammo in that. But seems it's now a little complicated . I need a stock that
1) Drop primary weapon .
2) Drop secondary weapon .
3) Drop both .
Thanks in advance .

[padilha007]

This help you?

PHP Code:

new const m_rgpPlayerItems_plr[] = {268, 269};

268 - primary weapon
269 - secondary weapon
270 - knife
271 - Flash, He, Smoke
272 - C4 


PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

new const m_rgpPlayerItems_plr[] = {268, 269};

public plugin_init()
{
    // Your code
}

public stripweapon(id)
    ham_strip_weapon(id)

stock ham_strip_weapon(id)
{
    for(new i; i<sizeof(m_rgpPlayerItems_plr); i++)
    {
        new iWeapon;
        iWeapon = get_pdata_cbase(id, m_rgpPlayerItems_plr[i], 5);
        while( pev_valid( iWeapon ) )
        {
            new szWeapon[20];
            pev(iWeapon, pev_classname, szWeapon, charsmax(szWeapon));
        
            new wId = get_weaponid(szWeapon);
            if(!wId) return 0;

            new wEnt;
            while((wEnt = engfunc(EngFunc_FindEntityByString,wEnt,"classname",szWeapon)) && pev(wEnt,pev_owner) != id) {}
            if(!wEnt) return 0;

            if(get_user_weapon(id) == wId) ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt);

            if(!ExecuteHamB(Ham_RemovePlayerItem,id,wEnt)) return 0;
            ExecuteHamB(Ham_Item_Kill,wEnt);

            set_pev(id,pev_weapons,pev(id,pev_weapons) & ~(1<<wId));
        }
    }

    return 1;
} 


[5c0r-|3i0]

I think I need a stock that makes players drop weapons and leave it on the ground . Your code just remove weapons from players , right ??
But thanks a lot ^^!. Already +k !

[padilha007]

sorry man =x ( From zp )

PHP Code:

// CS Offsets
#if cellbits == 32
const OFFSET_CSTEAMS = 114
const OFFSET_CSMONEY = 115
const OFFSET_NVGOGGLES = 129
const OFFSET_ZOOMTYPE = 363
const OFFSET_CSDEATHS = 444
const OFFSET_AWM_AMMO  = 377 
const OFFSET_SCOUT_AMMO = 378
const OFFSET_PARA_AMMO = 379
const OFFSET_FAMAS_AMMO = 380
const OFFSET_M3_AMMO = 381
const OFFSET_USP_AMMO = 382
const OFFSET_FIVESEVEN_AMMO = 383
const OFFSET_DEAGLE_AMMO = 384
const OFFSET_P228_AMMO = 385
const OFFSET_GLOCK_AMMO = 386
const OFFSET_FLASH_AMMO = 387
const OFFSET_HE_AMMO = 388
const OFFSET_SMOKE_AMMO = 389
const OFFSET_C4_AMMO = 390
const OFFSET_CLIPAMMO = 51
#else
const OFFSET_CSTEAMS = 139
const OFFSET_CSMONEY = 140
const OFFSET_NVGOGGLES = 155
const OFFSET_ZOOMTYPE = 402
const OFFSET_CSDEATHS = 493
const OFFSET_AWM_AMMO  = 426
const OFFSET_SCOUT_AMMO = 427
const OFFSET_PARA_AMMO = 428
const OFFSET_FAMAS_AMMO = 429
const OFFSET_M3_AMMO = 430
const OFFSET_USP_AMMO = 431
const OFFSET_FIVESEVEN_AMMO = 432
const OFFSET_DEAGLE_AMMO = 433
const OFFSET_P228_AMMO = 434
const OFFSET_GLOCK_AMMO = 435
const OFFSET_FLASH_AMMO = 46
const OFFSET_HE_AMMO = 437
const OFFSET_SMOKE_AMMO = 438
const OFFSET_C4_AMMO = 439
const OFFSET_CLIPAMMO = 65
#endif

// Weapon bitsums
const PRIMARY_WEAPONS_BIT_SUM = (1<<CSW_SCOUT)|(1<<CSW_XM1014)|(1<<CSW_MAC10)|(1<<CSW_AUG)|(1<<CSW_UMP45)|(1<<CSW_SG550)|(1<<CSW_GALIL)|(1<<CSW_FAMAS)|(1<<CSW_AWP)|(1<<CSW_MP5NAVY)|(1<<CSW_M249)|(1<<CSW_M3)|(1<<CSW_M4A1)|(1<<CSW_TMP)|(1<<CSW_G3SG1)|(1<<CSW_SG552)|(1<<CSW_AK47)|(1<<CSW_P90)
const SECONDARY_WEAPONS_BIT_SUM = (1<<CSW_P228)|(1<<CSW_ELITE)|(1<<CSW_FIVESEVEN)|(1<<CSW_USP)|(1<<CSW_GLOCK18)|(1<<CSW_DEAGLE)

const OFFSET_LINUX = 5 // offsets 5 higher in Linux builds

public plugin_init()
{
    // Your code
}

// Drop primary/secondary weapons
stock drop_weapons(id, dropwhat)
{
    // Get user weapons
    static weapons[32], num, i, weaponid
    num = 0 // reset passed weapons count (bugfix)
    get_user_weapons(id, weapons, num)
    
    // Loop through them and drop primaries or secondaries
    for (i = 0; i < num; i++)
    {
        // Prevent re-indexing the array
        weaponid = weapons[i]
        
        if ((dropwhat == 1 && ((1<<weaponid) & PRIMARY_WEAPONS_BIT_SUM)) || (dropwhat == 2 && ((1<<weaponid) & SECONDARY_WEAPONS_BIT_SUM)))
        {
            // Get the weapon entity
            static wname[32], weapon_ent
            get_weaponname(weaponid, wname, sizeof wname - 1)
            weapon_ent = fm_find_ent_by_owner(-1, wname, id);
            
            // Hack: store weapon bpammo on PEV_ADDITIONAL_AMMO
            set_pev(weapon_ent, PEV_ADDITIONAL_AMMO, fm_get_user_bpammo(id, weaponid))
            
            // Player drops the weapon and looses his bpammo
            engclient_cmd(id, "drop", wname)
            fm_set_user_bpammo(id, weaponid, 0)
        }
    }
}

// Find entity by its owner (from fakemeta_util)
stock fm_find_ent_by_owner(entity, const classname[], owner)
{
    while ((entity = engfunc(EngFunc_FindEntityByString, entity, "classname", classname)) && pev(entity, pev_owner) != owner) {}
    
    return entity;
}

// Set User BP Ammo
stock fm_set_user_bpammo(id, weapon, amount)
{
    static offset
    
    switch(weapon)
    {
        case CSW_AWP: offset = OFFSET_AWM_AMMO;
        case CSW_SCOUT,CSW_AK47,CSW_G3SG1: offset = OFFSET_SCOUT_AMMO;
        case CSW_M249: offset = OFFSET_PARA_AMMO;
        case CSW_M4A1,CSW_FAMAS,CSW_AUG,CSW_SG550,CSW_GALI,CSW_SG552: offset = OFFSET_FAMAS_AMMO;
        case CSW_M3,CSW_XM1014: offset = OFFSET_M3_AMMO;
        case CSW_USP,CSW_UMP45,CSW_MAC10: offset = OFFSET_USP_AMMO;
        case CSW_FIVESEVEN,CSW_P90: offset = OFFSET_FIVESEVEN_AMMO;
        case CSW_DEAGLE: offset = OFFSET_DEAGLE_AMMO;
        case CSW_P228: offset = OFFSET_P228_AMMO;
        case CSW_GLOCK18,CSW_MP5NAVY,CSW_TMP,CSW_ELITE: offset = OFFSET_GLOCK_AMMO;
        case CSW_FLASHBANG: offset = OFFSET_FLASH_AMMO;
        case CSW_HEGRENADE: offset = OFFSET_HE_AMMO;
        case CSW_SMOKEGRENADE: offset = OFFSET_SMOKE_AMMO;
        case CSW_C4: offset = OFFSET_C4_AMMO;
        default: return;
    }
    
    set_pdata_int(id, offset, amount, OFFSET_LINUX)
} 


PHP Code:

drop_weapons(id, 1) - primary weapon
drop_weapons(id, 2) - secondary weapon

drop_weapons(id, 1); drop_weapons(id, 2) - drop both 


[5c0r-|3i0]

WoW. Thanks a lot !!

[SchlumPF*]

you should use #defines instead of that many constants

[xPaw]

Originally Posted by SchlumPF* you should use #defines instead of that many constants

Why?

[Exolent[jNr]]

Constants use up memory, whereas #defines are replaced with their value upon compilation.

[joaquimandrade]

Don't use defines. It's fine with consts.

[Dores]

C'mon, make up your minds guys! I need to know which to use..