[TUT] Crear usuarios vip desde archivo *.ini

Anti · **Author**

Hola, como anduve sin internet un tiempo estube aburrido y me puse a joder con el pawn studio.
Acá les dejo un tuto(le puse aclaraciones a algunas lineas) medio feo de como crear usuarios "vips" desde un archivo .ini en la carpeta config.
No vi ninguno así que lo posteo, si le ven algo mal avisen

PHP Code:


			
/*
NOTA:
NO PONER MAS DE 20 VIPS, SI QUERES MAS EDITA EL DEFINE 'MAXVIPS';
LOS NAMES QUE TENGAN ';' O '/' O '/'(EN LAS SEGUNDA POSICION) NO LOS LEERA;
*/
#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define MAXVIPS    20
#define VIPSCARACT    32

new gFileName[] = "names_vip.ini";

new gVips[MAXVIPS+1][VIPSCARACT+1];

new PlayersVip[33];

public plugin_init()
{
    register_plugin("Usuarios vip en *.ini", "1.0", "Anti");
    
}

public client_putinserver(id)
    set_task(3.0, "get_user_vip", id)

public get_user_vip(id)
{
    new Path[256];
    get_configsdir(Path, charsmax(Path));
    formatex(Path, charsmax(Path),"%s/%s", Path, gFileName);// ruta del archivo .ini
    
    if(!file_exists(Path))
    {
        client_print(id, print_chat, "El archivo %s no existe, crealo y pone los vips!!!", gFileName);// si no existe el archivo
        return PLUGIN_HANDLED;
    }
    
    new f = fopen(Path, "rt");            // abrimos y leemos el archivo
    
    new iName[VIPSCARACT+1];
    new gName[32];
    new Vip;
    get_user_name(id, gName, 31)        //obtenemos el nombre del player
    while(!feof(f))
    {
        fgets(f, iName, charsmax(iName));//obtenemos el nombre de gFileName
        
        copy(gVips[Vip], charsmax(gVips), iName);
        Vip++;
        
        if(Vip >= MAXVIPS) break;
        
        if(!iName[0] || iName[0] == ';'
        || iName[0] == '/' && iName[1] == '/' ) continue;// si el nombre tiene ';' O '/' O '/'(EN LAS SEGUNDA POSICION) LOS LEERA;
        
        if ( equal( gName, iName ))        // si el nombre del player es igual a el del archivo es le mandamos un hudd
            esVip(id)
    }
    fclose(f);                          //cerramos el archivo
    return PLUGIN_HANDLED;
}

public esVip(id)
{
    new szName[32]
    get_user_name(id, szName, 31)
    PlayersVip[id] = 1;
    set_hudmessage(200, 0, 100)
    show_hudmessage(0, "%s es usuario vip!!", szName)
    /*----Pones el code----*/
}

PD: Yo los subí con la mejor onda espero que me respondan así!!
gracias a Roccoxx por hacerme acordar de que no es conveniente abrir muchas veces el archivo .ini por eso verifiquen el vip una vez sola o lo menos posible

Roccoxx · 08-20-2013 , 21:17 Re: [TUT] Crear usuarios vip desde archivo *.ini

te parece bien ejecutar tantas cosas cada vez que revive un jugador

de onda lo digo, no intenten aportar sino estan seguros que lo que hacen es la mejor forma para los usuarios nuevos.

Anti · 08-20-2013 , 21:57 Re: [TUT] Crear usuarios vip desde archivo *.ini

si, iba a aclararlo pero se me paso este caso es un ejemplo, cada uno lo adaptara a sus necesidades.
gracias roccoxx!!
si ven algo mas mal avisen

gladius · *Last edited by gladius; 08-20-2013 at 22:23.*

Usa Arrays o Tries queda más bonito y dinámico.

r0ma · *Last edited by r0ma; 08-23-2013 at 23:12.*

Nunca usas hamsandwich

Edit:

PHP Code:


			
#include < amxmodx >
#include < amxmisc >

new g_flags[ 33 ];
new Trie:g_vip;

public plugin_init( ) {
    register_plugin( "Vip", "1.0.0", "r0ma'" );
}

public plugin_cfg( ) {
    new buffer[ 64 ], steam[ 33 ], flags[ 33 ], file;
    
    g_vip = TrieCreate( );
    
    get_configsdir( buffer, charsmax( buffer ) );
    add( buffer, charsmax( buffer ), "/vips.ini" );
    
    if( !file_exists( buffer ) ) {
        file = fopen( buffer, "wt" );
        
        fprintf( file, "; Si la linea tiene ; al principio no los tomara;Como crear un usuario vip.^n;^"steam_id^" ^"abcdefghijklmnopqrstu^"" );
        
        fclose( file );
        
        return;
    }
    
    file = fopen( buffer, "rt" );
    
    while( !feof( file ) ) {
        fgets( file, buffer, charsmax( buffer ) );
        trim( buffer );
        
        if( !buffer[ 0 ] || buffer[ 0 ] == ';' )
            continue;
        
        parse( buffer, steam, charsmax( steam ), flags, charsmax( flags ) );
        
        remove_quotes( steam );
        remove_quotes( flags );
        
        TrieSetCell( g_vip, steam, read_flags( flags ) );
    }
    
    fclose( file );
}

public plugin_end( ) {
    TrieDestroy( g_vip );
}

public plugin_natives( ) {
    register_native( "get_user_vip", "native_get_user_vip", 1 );
    register_native( "set_user_vip", "native_set_user_vip", 1 );
}

public client_putinserver( id ) {
    check_user_vip( id );
}

public check_user_vip( id ) {
    new steamid[ 33 ];
    
    get_user_authid( id, steamid, charsmax( steamid ) );
    
    if( TrieKeyExists( g_vip, steamid ) ) {
        new flags;
        TrieGetCell( g_vip, steamid, flags );
        
        g_flags[ id ] |= flags;
    }
    else
        g_flags[ id ] = 0;
}

public native_get_user_vip( id ) {
    return g_flags[ id ];
}

public native_set_user_vip( id, flags ) {
    g_flags[ id ] |= flags;
    
    return 1;
}

vips.inc

PHP Code:


			
#if defined _vips_included
  #endinput
#endif
#define _vips_included

#define VIP_A (1<<0)
#define VIP_B (1<<1)
#define VIP_C (1<<2)
#define VIP_D (1<<3)
#define VIP_E (1<<4)
#define VIP_F (1<<5)
#define VIP_G (1<<6)
#define VIP_H (1<<7)
#define VIP_I (1<<8)
#define VIP_J (1<<9)
#define VIP_K (1<<10)
#define VIP_L (1<<11)
#define VIP_M (1<<12)
#define VIP_N (1<<13)
#define VIP_O (1<<14)
#define VIP_P (1<<15)
#define VIP_Q (1<<16)
#define VIP_R (1<<17)
#define VIP_S (1<<18)
#define VIP_T (1<<19)
#define VIP_U (1<<20)

native get_user_vip( id );
native set_user_vip( id, flags );

EDIT2:

Vips Via MySQL:

PHP Code:


			
#include < amxmodx >
#include < amxmisc >
#include < sqlx >

/* 
CREATE TABLE `users_vip` (
    `steam` VARCHAR( 33 ) NOT NULL ,
    `flags` VARCHAR( 33 ) NOT NULL ,
    UNIQUE (
        `steam`
    )
) ENGINE = MYISAM ;
*/

new g_flags[ 33 ];
new Trie:g_vip;

public plugin_init( ) {
    register_plugin( "Vip", "1.0.0", "r0ma'" );
}

public plugin_cfg( ) {
    
    g_vip = TrieCreate( );
    
    new Handle:hTuple = SQL_MakeDbTuple( "127.0.0.1", "root", "", "vip" );
    
    if( !hTuple ) {
        log_to_file( "sql_error.txt", "Error al conectar con la MySQL" );
        
        return;
    }
    
    new error[ 128 ], iError;
    
    hTuple = SQL_Connect( hTuple, iError, error, charsmax( error ) );
    
    if( !hTuple ) {
        log_to_file( "sql_error.txt", "Error al conectar '%d': %s", iError, error );
        
        return;
    }
    
    new Handle:Query = SQL_PrepareQuery( hTuple, "SELECT * FROM users_vip" );
    
    if( SQL_Execute( Query ) ) {
        new steam[ 33 ], flags[ 33 ];
        
        while( SQL_MoreResults( Query ) ) {
            SQL_ReadResult( Query, 0, steam, charsmax( steam ) );
            SQL_ReadResult( Query, 1, flags, charsmax( flags ) );
            
            SQL_NextRow( Query );
            
            TrieSetCell( g_vip, steam, read_flags( flags ) );
        }
    }
    
    SQL_FreeHandle( Query );
    SQL_FreeHandle( hTuple );
}

public plugin_end( ) {
    TrieDestroy( g_vip );
}

public plugin_natives( ) {
    register_native( "get_user_vip", "native_get_user_vip", 1 );
    register_native( "set_user_vip", "native_set_user_vip", 1 );
}

public client_putinserver( id ) {
    check_user_vip( id );
}

public check_user_vip( id ) {
    new steamid[ 33 ];
    
    get_user_authid( id, steamid, charsmax( steamid ) );
    
    if( TrieKeyExists( g_vip, steamid ) ) {
        new flags;
        TrieGetCell( g_vip, steamid, flags );
        
        g_flags[ id ] |= flags;
    }
    else
        g_flags[ id ] = 0;
}

public native_get_user_vip( id ) {
    return g_flags[ id ];
}

public native_set_user_vip( id, flags ) {
    g_flags[ id ] |= flags;
    
    return 1;
}