[dhokla123]

Hey,

I have been seeing since 2 days that some players are using an exploit by which they plant the c4 and explode instantly and same for defuse under 1 second.

I know earlier this was patched by valve back in 2018 or 19.

Anyone here who can tell me any possible solution.

[Bacardi]

...looking from (old) video example, player is using hacks.
Player create lag and glitch weapon switch and bomb plant animation.

*edit
second example is using glitch, were you hear water splash.

[raj kaul]

if someone gonna create a fix please read this thread once https://www.unknowncheats.me/forum/c...t-exploit.html

maybe this help

[Bacardi]

This is not fix.
Test plugin to log exploit
and ban player by week on instant explode event.
Instant defuse is only logged.

Because there are plugins which let player instant defuse or explode c4,
I try to code so it avoid those events as good as I can figure in my mind.

Spoiler

PHP Code:

#include <sdktools>

/*
Server event "bomb_planted", Tick 15875:
- "userid" = "6"
- "site" = "302"

Server event "bomb_exploded", Tick 31055:
- "userid" = "6"
- "site" = "302"


Server event "bomb_begindefuse", Tick 258913:
- "userid" = "16"
- "haskit" = "1"

Server event "bomb_defused", Tick 259557:
- "userid" = "16"
- "site" = "302"

*/

ConVar mp_c4timer;
bool CTDefusing = false;

public void OnPluginStart()
{
    mp_c4timer = FindConVar("mp_c4timer");

    HookEvent("bomb_planted", bomb);
    HookEvent("bomb_exploded", bomb);

    HookEvent("bomb_begindefuse", defuse);
    HookEvent("bomb_defused", defuse);

    HookEvent("round_start", round_start);
}

public void round_start(Event event, const char[] name, bool dontBroadcast)
{
    CTDefusing = false;
}

public void defuse(Event event, const char[] name, bool dontBroadcast)
{
    static float timestamp_defusing = 0.0;
    static int userid_defuser = 0;

    if(StrEqual(name, "bomb_begindefuse", false))
    {
        timestamp_defusing = GetGameTime();
        userid_defuser = event.GetInt("userid");
        CTDefusing = true;

        return;
    }

    int userid = event.GetInt("userid");

    if(userid_defuser != userid)
    {
        // This error should not happen.
        return;
    }

    float defusing_time = GetGameTime() - timestamp_defusing;

    // Log only, because of those instant defuse plugins...
    if(defusing_time <= 1.0)
    {
        char reason[PLATFORM_MAX_PATH];
        int client = GetClientOfUserId(userid_defuser);

        if(client && IsClientInGame(client) && !IsFakeClient(client))
        {
            Format(reason, sizeof(reason), "Player '%L' C4 instant defuse exploit/hack suspicion. Defusing takes %f second", client, defusing_time);
            LogAction(-1, -1, reason);
        }
        else
        {
            Format(reason, sizeof(reason), "Player with userid #%i, C4 instant defuse exploit/hack suspicion. Defusing takes %f second", userid_defuser, defusing_time);
            LogAction(-1, -1, reason);
        }
    }
}


public void bomb(Event event, const char[] name, bool dontBroadcast)
{
    static float timestamp_planted = 0.0;
    static int userid_planted = 0;

    if(StrEqual(name, "bomb_planted", false))
    {
        timestamp_planted = GetGameTime();
        userid_planted = event.GetInt("userid");

        return;
    }


    int userid = event.GetInt("userid");

    if(userid_planted != userid)
    {
        // Why many bomb_planted happened, multiple c4s ?
        return;
    }


    float c4timer = float(mp_c4timer.IntValue);
    float c4lifetime = GetGameTime() - timestamp_planted;

    // bomb_exploded 1 second after mp_c4timer time.
    // mp_c4timer not accept float values, only integer

    // When CT have not touch planted C4, and C4 explode sooner than suppose to.
    // By plugin mods ?

    if(!CTDefusing && c4lifetime < c4timer + 1.0)
    {
        char reason[PLATFORM_MAX_PATH];
        int client = GetClientOfUserId(userid_planted);

        if(client && IsClientInGame(client) && !IsFakeClient(client))
        {
            Format(reason, sizeof(reason), "Player '%L' C4 instant explosion exploit/hack suspicion. Planted C4 lifetime was %f < server convar mp_c4timer is %f (Explosion happens +1.0 second)", client, c4lifetime, c4timer);
            LogAction(-1, -1, reason);

            // If c4 explode in second or less, ban player with week and log player;
            if(c4lifetime <= 1.0)
            {
                Format(reason, sizeof(reason), "Banned player '%L' for C4 instant explosion exploit/hack suspicion (under 1.0 second delay)", client);
                LogAction(-1, -1, reason);

                BanClient(client, 10080, BANFLAG_AUTO,
                                        reason,
                                        "There were unexpected event, try contact server Admin",
                                        "sm_ban", 0);
            }
        }
        else
        {
            Format(reason, sizeof(reason), "Player with userid #%i, C4 instant explosion exploit/hack suspicion. Planted C4 lifetime was %f, server convar mp_c4timer is %f (Explosion happens +1.0 second)", userid_planted, c4lifetime, c4timer);
            LogAction(-1, -1, reason);
        }
    }
} 


[backwards]

This should fix it

[raj kaul]

parched by valve in today’s update

https://twitter.com/csgo/status/1514...yVZ7mBHCLnoPFA