[Sajmooooon]

Hi is there any sourcepawn command for sourcebans to check if player is muted/gaged ?

Thanks.

[azalty]

Afaik there is no command BUT you can get muted/gaged players through the /admin menu

I think there was also sm_listbans and sm_listblocks but you have to enter a username/steamid I think

[FAQU]

I've no idea if this will work with sourcebans, but it might be worth giving it a try:

PHP Code:

#include <sourcemod>
#include <basecomm>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    LoadTranslations("common.phrases");
    RegConsoleCmd("sm_comms", Command_Comms, "Shows a players communications status");
}

public Action Command_Comms(int client, int args)
{
    if (args != 1)
    {
        ReplyToCommand(client, "[SM] Usage: sm_comms <name|userid>");
        return Plugin_Handled;
    }
    
    char arg1[MAX_NAME_LENGTH];
    GetCmdArg(1, arg1, sizeof(arg1));
    
    int target = FindTarget(client, arg1, true, false);
    if (target == -1)
    {
        return Plugin_Handled;
    }
    
    bool gag = BaseComm_IsClientGagged(target);
    bool mute = BaseComm_IsClientMuted(target);
    
    ReplyToCommand(client, gag ? "%N is gagged":"%N is ungagged", target);
    ReplyToCommand(client, mute ? "%N is muted":"%N is unmuted", target);
    
    return Plugin_Handled;
} 


[Sajmooooon]

Thanks works great.