[proffs]

The Emit Sound doesn't work.
There is no sound when you hit someone.


return FMRES_IGNORED
}[/PHP]

[ConnorMcLeod]

Remove sound/ from paths.

[proffs]

Originally Posted by ConnorMcLeod Remove sound/ from paths.

great works, ONly on slash not the others.

I am using this instead now:

PHP Code:

public EmitSound(id, channel, sample[])
{
    if(!is_user_alive(id)) 
        return FMRES_IGNORED
    
    if ( cs_get_user_team ( id ) == CS_TEAM_T )
    {    
        new temp[2], weapon = get_user_weapon(id, temp[0], temp[1])
        if( g_iCurrentGame == GAME_BOXING )
        {    
            if(weapon == CSW_KNIFE)
            {
                if(equal(sample,"weapons/knife_hit1.wav")) 
                {
                    emit_sound(id, CHAN_WEAPON, g_szBoxingSound1, 1.0, ATTN_NORM, 0, PITCH_NORM)
                    return FMRES_SUPERCEDE
                }
                else if(equal(sample,"weapons/knife_hit2.wav")) 
                {
                    emit_sound(id, CHAN_WEAPON, g_szBoxingSound2, 1.0, ATTN_NORM, 0, PITCH_NORM)
                    return FMRES_SUPERCEDE
                }
                else if(equal(sample,"weapons/knife_hit3.wav")) 
                {
                    emit_sound(id, CHAN_WEAPON, g_szBoxingSound3, 1.0, ATTN_NORM, 0, PITCH_NORM)
                    return FMRES_SUPERCEDE
                }
                else if(equal(sample,"weapons/knife_hit4.wav")) 
                {
                    emit_sound(id, CHAN_WEAPON, g_szBoxingSound4, 1.0, ATTN_NORM, 0, PITCH_NORM)
                    return FMRES_SUPERCEDE
                }
                else if(equal(sample,"weapons/knife_hit5.wav")) 
                {
                    emit_sound(id, CHAN_WEAPON, g_szBoxingSound5, 1.0, ATTN_NORM, 0, PITCH_NORM)
                    return FMRES_SUPERCEDE
                }
            }
        }
    }
    return FMRES_IGNORED;
} 


[ConnorMcLeod]

PHP Code:

    if(!is_user_alive(id))  
        return FMRES_IGNORED 
     
    if ( cs_get_user_team ( id ) == CS_TEAM_T ) 
    {     
        new temp[2], weapon = get_user_weapon(id, temp[0], temp[1]) 
        if( g_iCurrentGame == GAME_BOXING ) 
        {     
            if(weapon == CSW_KNIFE) 


->

PHP Code:

    if( g_iCurrentGame == GAME_BOXING && is_user_alive(id) && cs_get_user_team ( id ) == CS_TEAM_T && get_user_weapon(id) == CSW_KNIFE )
    { 


[proffs]

Originally Posted by ConnorMcLeod Remove sound/ from paths.

Originally Posted by ConnorMcLeod PHP Code:     if(!is_user_alive(id))           return FMRES_IGNORED            if ( cs_get_user_team ( id ) == CS_TEAM_T )      {              new temp[2], weapon = get_user_weapon(id, temp[0], temp[1])          if( g_iCurrentGame == GAME_BOXING )          {                  if(weapon == CSW_KNIFE)  -> PHP Code:     if( g_iCurrentGame == GAME_BOXING && is_user_alive(id) && cs_get_user_team ( id ) == CS_TEAM_T && get_user_weapon(id) == CSW_KNIFE )     {

Thanks, But some of the sound is still not replaced. Like the knife_stab..

[ConnorMcLeod]

Better to use a trie though :

If there is still a problem with some sounds, problem is not with code, problem is with original sound name, or new sound name, or new sound encoding.

PHP Code:


new const g_szBoxingSound1[ ] = "hays/knife_hit1.wav";
new const g_szBoxingSound2[ ] = "hays/knife_hit2.wav";
new const g_szBoxingSound3[ ] = "hays/knife_hit3.wav";
new const g_szBoxingSound4[ ] = "hays/knife_hit4.wav";
new const g_szBoxingSound5[ ] = "hays/knife_stab.wav"; 

new Trie:g_tKnifeSoundsReplacement;

new g_iMaxPlayers;
#define IsPlayer(%0)    ( 1 <= (%0) <= g_iMaxPlayers )

public plugin_init()
{
    g_tKnifeSoundsReplacement = TrieCreate();
    TrieSetString(g_tKnifeSoundsReplacement, "weapons/knife_hit1.wav", g_szBoxingSound1);
    TrieSetString(g_tKnifeSoundsReplacement, "weapons/knife_hit2.wav", g_szBoxingSound2);
    TrieSetString(g_tKnifeSoundsReplacement, "weapons/knife_hit3.wav", g_szBoxingSound3);
    TrieSetString(g_tKnifeSoundsReplacement, "weapons/knife_hit4.wav", g_szBoxingSound4);
    TrieSetString(g_tKnifeSoundsReplacement, "weapons/knife_stab.wav", g_szBoxingSound5);

    register_forward(FM_EmitSound, "OnEmitSound", false);
}

public plugin_precache() 
{ 
    precache_sound( g_szBoxingSound1 ); 
    precache_sound( g_szBoxingSound2 ); 
    precache_sound( g_szBoxingSound3 ); 
    precache_sound( g_szBoxingSound4 ); 
    precache_sound( g_szBoxingSound5 ); 
}  

// void        (*pfnEmitSound)                (edict_t *entity, int channel, const char *sample, /*int*/float volume, float attenuation, int fFlags, int pitch);
public OnEmitSound(id, channel, const sample[], Float:volume, Float:attenuation, fFlags, pitch)
{
    static szNewSound[32];
    if(    g_iCurrentGame == GAME_BOXING
    &&    IsPlayer(id)
    &&    cs_get_user_team ( id ) == CS_TEAM_T
    &&    get_user_weapon(id) == CSW_KNIFE
    &&    TrieGetString(g_tKnifeSoundsReplacement, sample, szNewSound, charsmax(szNewSound))    )
    {
        emit_sound(id, channel, szNewSound, volume, attenuation, fFlags, pitch);
        return FMRES_SUPERCEDE;
    }
    return FMRES_IGNORED;
} 


[proffs]

Originally Posted by ConnorMcLeod Better to use a trie though : If there is still a problem with some sounds, problem is not with code, problem is with original sound name, or new sound name, or new sound encoding.

Works great, thanks!