[letgoofmyeggs]

ive searched but couldnt find a plugin like this. ive been to a server where you type in chat "find (part of map name)" and all the matching results are displayed in a hud message on theright of the screen

[letgoofmyeggs]

bump

[One]

Hmmm... i know only this http://forums.alliedmods.net/showthread.php?p=657545

its a realy cool plugin. but not that what u wannted. users can say :

vote de_

& become all de_ maps to vote or vote de_dust2 & the map de_dust2 will be voted by player. i hope could help.

[letgoofmyeggs]

thanks but i jus want a simple plugin that allows me to search through my maps thru the chat ina hud message. that plugin looks very complex and i will only be using a little portion of it

[letgoofmyeggs]

BUMPPPPPP

[Dores]

Try this.


Command: amx_findmap <partial mapname> - Displays maps names from the maps folder that match the partial mapname entered.

CVar: mf_display - If set to 0, a HUD will be displayed at the right of the screen. 1 = Prints at console.

PHP Code:

#include <amxmodx>
#include <amxmisc>

new g_SyncedHudObj;
new p_display;

public plugin_init()
{
    register_plugin("Map Finder", "1.0", "Dores");
    
    register_clcmd("amx_findmap", "Cmd_FindMap", ADMIN_KICK, "amx_findmap <partial mapname> - Finds matching maps from the maps folder");
    
    p_display = register_cvar("mf_display", "0"); // 0 = HUD, 1 = Console.
    
    g_SyncedHudObj = CreateHudSyncObj();
}

public Cmd_FindMap(id, lvl, cid)
{
    if(!cmd_access(id, lvl, cid, 2))
        return;
    
    new map[32];
    read_argv(1, map, 31);
    
    if(!DisplayMatchingMaps(id, map))
    {
        console_print(id, "Could not find wanted map(s). Make sure you don't have any typos.");
    }
}

bool:DisplayMatchingMaps(const id, const map[])
{
    new dirh = open_dir("maps", "", 0);
    new map_file[36], mapCount, bool:found;
    
    while(next_file(dirh, map_file, 35))
    {
        if(containi(map_file, ".bsp") == -1)
            continue;
        
        replace(map_file, 35, ".bsp", "");
        
        if(is_map_valid(map_file) && containi(map_file, map) != -1)
        {
            if(!get_pcvar_num(p_display))
            {
                set_hudmessage(0, 0, 255, 0.58, 0.0, 0, 6.0, 12.0);
                ShowSyncHudMsg(id, g_SyncedHudObj, "%d) %s", ++mapCount, map_file);
            }
            
            else
            {
                console_print(id, "%d) %s", ++mapCount, map_file);
            }
            
            found = true;
        }
    }
    
    close_dir(dirh);
    
    return found;
} 


[letgoofmyeggs]

thanks how do i change the console comand into a chat command?

[Dores]

There, just type findmap <mapname> in chat and results will appear in console(can't think of a way to display all of the maps using HUD).

PHP Code:

#include <amxmodx>
#include <amxmisc>

public plugin_init()
{
    register_plugin("Map Finder", "1.0", "Dores");
    
    register_clcmd("say", "Cmd_HookSay");
}

public Cmd_HookSay(id)
{
    if(!access(id, ADMIN_KICK))
        return;
    
    new command[41], map[32];
    read_args(command, 40);
    remove_quotes(command);
    
    if(containi(command, "findmap ") == -1)
    {
        return;
    }
    
    parse(command, command, 40, map, 31);
    
    if(!DisplayMatchingMaps(id, map))
    {
        console_print(id, "Could not find wanted map(s). Make sure you don't have any typos.");
    }
}

bool:DisplayMatchingMaps(const id, const map[])
{
    new dirh = open_dir("maps", "", 0);
    new map_file[36], mapCount, bool:found;
    
    while(next_file(dirh, map_file, 35))
    {
        if(containi(map_file, ".bsp") == -1)
            continue;
        
        replace(map_file, 35, ".bsp", "");
        
        if(is_map_valid(map_file) && containi(map_file, map) != -1)
        {
            console_print(id, "%d) %s", ++mapCount, map_file);
            
            found = true;
        }
    }
    
    close_dir(dirh);
    
    return found;
} 


[letgoofmyeggs]

on the server it dint say al the maps, it jus showed the ones it could fit on the screen. do yu no how to do that?

[fysiks]

For the second code it's in your console so you should be able to just scroll up .

For the first, there is a limit on hud messages.