[alasfourom]

Hello Everyone,

I have started scripting and reading about scripts almost 3 months ago, I have read from here on how to create menu Here.

I got the basics a little bit.

I wanted to create a simple survivors bot list > for l4d2, but not necessary since the concept is the same. I read few scripts but they are either old or too complicated for me with more than 800 lines on simple function.

I made this one, which display the bots, but I cant target each of their names, I tried to select for example "Nick", but it showed me I selected the wrong bot. In fact, it only shows me the first survivor bot. I would really appreciate some helps here, thanks

PHP Code:

public void OnPluginStart()
{
    RegConsoleCmd("sm_bot", Command_ShowBotsMenu, "Show Bots Menu.");
}

public Action Command_ShowBotsMenu(int client, int args)
{
    PrintToChat(client, "Menu Opened");
    Create_SurvivorsBotListMenu(client);
    return Plugin_Handled;
}

void Create_SurvivorsBotListMenu(int client)
{
    Menu menu = new Menu(BotsList, MENU_ACTIONS_ALL);
    menu.SetTitle("Select A Bot:");
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (!IsClientInGame(i) || !IsFakeClient(i) || !IsPlayerAlive(i) || GetClientTeam(i) != 2)
            continue;
        
        char sID[32];
        char sName[64];
        
        GetClientName(i, sName, sizeof(sName));
        Format(sID, sizeof(sID), "%N", i);
        
        menu.AddItem(sID, sName);
    }
    menu.Display(client, MENU_TIME_FOREVER);
}

public int BotsList(Menu menu, MenuAction action, int param1, int param2)
{
    switch(action)
    {
        case MenuAction_Select:
        {
            char sInfo[64];
            menu.GetItem(param2, sInfo, sizeof(sInfo));
            
            for (int i = 1; i <= MaxClients; i++)
            {
                if (!IsClientInGame(i) || !IsFakeClient(i) || !IsPlayerAlive(i) || GetClientTeam(i) != 2 && (StringToInt(sInfo) != i))
                    continue;
                    
                PrintToChatAll("%N has selected %N.", param1, i);
                return;
            }
        }
        case MenuAction_End:
        {
            delete menu;
        }
    }
} 


[alasfourom]

for (int i = 1; i <= MaxClients; i++) { if (!IsClientInGame(i) || !IsFakeClient(i) || !IsPlayerAlive(i) || GetClientTeam(i) != 2 && (StringToInt(sInfo) != i)) continue; PrintToChatAll("%N has selected %N.", param1, i); return; }

I'm sure this is the main issue, I dont know how to target the exact bot selected, which seems like I'm targeting all the bots instead of only the selected one.

[Bacardi]

https://wiki.alliedmods.net/Format_C...mat_Specifiers

You add player name, two times. %N
Try %i

*edit
If you want make it more correctly, you should use player UserId. With this you can try search client index, is player still in game.
But try client index first.

    for (int i = 1; i <= MaxClients; i++)
    {
        if (!IsClientInGame(i) || !IsFakeClient(i) || !IsPlayerAlive(i) || GetClientTeam(i) != 2)
            continue;
        
        char sID[32];
        char sName[64];
        
        GetClientName(i, sName, sizeof(sName));
        Format(sID, sizeof(sID), "%N", i);
        
        menu.AddItem(sID, sName);
    }
    menu.Display(client, MENU_TIME_FOREVER);

[alasfourom]

Thank You Bacardi,

I was finally able to detect them with their "GetClientOfUserId",

Thanks a lot

[Grey83]

PHP Code:

public void OnPluginStart()
{
    RegConsoleCmd("sm_bot", Cmd_ShowBotsMenu, "Show Bots Menu.");
}

public Action Cmd_ShowBotsMenu(int client, int args)
{
    if(!client || !IsClientInGame(client))
        return Plugin_Handled;

    PrintToChat(client, "Menu Opened");
    Menu menu = new Menu(BotsList);
    menu.SetTitle("Select A Bot:");

    char uid[8], sName[MAX_NAME_LENGTH];
    for(int i = 1; i <= MaxClients; i++)
        if(IsClientInGame(i) && IsFakeClient(i) && IsPlayerAlive(i) && GetClientTeam(i) == 2)
        {
            GetClientName(i, sName, sizeof(sName));
            FormatEx(uid, sizeof(uid), "%i", GetClientUserId(i));
            menu.AddItem(uid, sName);
        }

    if(!menu.ItemCount) menu.AddItem("", "Bots not found", ITEMDRAW_DISABLED);
    menu.Display(client, MENU_TIME_FOREVER);

    return Plugin_Handled;
}

public int BotsList(Menu menu, MenuAction action, int client, int param)
{
    switch(action)
    {
        case MenuAction_Select:
        {
            char sInfo[8];
            menu.GetItem(param, sInfo, sizeof(sInfo));
            int target = StringToInt(sInfo);
            if(target && (target = GetClientUserId(target)))
                PrintToChatAll("%N has selected %N.", client, target);
            else Cmd_ShowBotsMenu(client, 0);
        }
        case MenuAction_End: delete menu;
    }

    return 0;
} 


[alasfourom]

Originally Posted by Grey83 PHP Code: public void OnPluginStart() {     RegConsoleCmd("sm_bot", Cmd_ShowBotsMenu, "Show Bots Menu."); } public Action Cmd_ShowBotsMenu(int client, int args) {     if(!client || !IsClientInGame(client))         return Plugin_Handled;     PrintToChat(client, "Menu Opened");     Menu menu = new Menu(BotsList);     menu.SetTitle("Select A Bot:");     char uid[8], sName[MAX_NAME_LENGTH];     for(int i = 1; i <= MaxClients; i++)         if(IsClientInGame(i) && IsFakeClient(i) && IsPlayerAlive(i) && GetClientTeam(i) == 2)         {             GetClientName(i, sName, sizeof(sName));             FormatEx(uid, sizeof(uid), "%i", GetClientUserId(i));             menu.AddItem(uid, sName);         }     if(!menu.ItemCount) menu.AddItem("", "Bots not found", ITEMDRAW_DISABLED);     menu.Display(client, MENU_TIME_FOREVER);     return Plugin_Handled; } public int BotsList(Menu menu, MenuAction action, int client, int param) {     switch(action)     {         case MenuAction_Select:         {             char sInfo[8];             menu.GetItem(param, sInfo, sizeof(sInfo));             int target = StringToInt(sInfo);             if(target && (target = GetClientUserId(target)))                 PrintToChatAll("%N has selected %N.", client, target);             else Cmd_ShowBotsMenu(client, 0);         }         case MenuAction_End: delete menu;     }     return 0; }

Awwww, Excellent Grey83