[JLmelenchon]

Any idea on how to protect SourceTV against "callvote kick" ?

native bool:IsClientSourceTV(client) could be used i guess.

[cravenge]

PHP Code:

if (IsClientSourceTV(client) || IsClientReplay(client)) 


[JLmelenchon]

What will look like the code in relation to the callvote kick command ?

[Psyk0tik]

It would look something like this:

PHP Code:

#include <sourcemod>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    AddCommandListener(cmdCallVote, "callvote");
}

public Action cmdCallVote(int client, const char[] command, int argc)
{
    if (!(0 < client <= MaxClients && IsClientInGame(client)))
    {
        return Plugin_Continue;
    }

    char sType[32];
    GetCmdArg(1, sType, sizeof sType);
    if (StrEqual(sType, "kick", false))
    {
        char sTarget[32];
        GetCmdArg(2, sTarget, sizeof sTarget);
        int iTarget = GetClientOfUserId(StringToInt(sTarget));
        if (IsClientSourceTV(iTarget) || IsClientReplay(iTarget))
        {
            return Plugin_Handled;
        }
    }

    return Plugin_Continue;
} 


I've never had to check for Source TV or Replay before so I don't know what other validity checks are required.

[JLmelenchon]

Thank you it works at first glance.