[ajr1234]

Obviously I'm doing something wrong, so am wondering if this is not possible or...

I'm trying to get all the players to have a glow around them. Kind of like a forced glow. (l4d2)

PHP Code:

glow()
{
    // turn on glow
    for (new i = 1; i <= MAXPLAYERS; i++)
    {
        SetEntProp(i, Prop_Send, "m_bSurvivorGlowEnabled", 1);
        SetEntProp(i, Prop_Send, "m_glowColorOverride", 255255);
    }
    CreateTimer(15.0, _DisableGlow);
}

public Action:_DisableGlow(Handle:timer)
{
    // turn off glow
    for (new i = 1; i <= MAXPLAYERS; i++)
    {
        SetEntProp(i, Prop_Send, "m_bSurvivorGlowEnabled", 0);
        SetEntProp(i, Prop_Send, "m_glowColorOverride", 0);
    }
} 


Thanks for your help!

[Mr. Zero]

I wrote some glow stocks some time ago.

PHP Code:

enum L4D2GlowType
{
    L4D2Glow_None = 0,
    L4D2Glow_OnUse,
    L4D2Glow_OnLookAt,
    L4D2Glow_Constant
}

/**
 * Set entity glow. This is consider safer and more robust over setting each glow
 * property on their own because glow offset will be check first.
 *
 * @param entity        Entity index.
 * @parma type            Glow type.
 * @param range            Glow max range, 0 for unlimited.
 * @param minRange        Glow min range.
 * @param colorOverride Glow color, RGB.
 * @param flashing        Whether the glow will be flashing.
 * @return                True if glow was set, false if entity does not support
 *                        glow.
 */
stock bool:L4D2_SetEntGlow(entity, L4D2GlowType:type, range, minRange, colorOverride[3], bool:flashing)
{
    decl String:netclass[128];
    GetEntityNetClass(entity, netclass, 128);

    new offset = FindSendPropInfo(netclass, "m_iGlowType");
    if (offset < 1)
    {
        return false;    
    }

    L4D2_SetEntityGlow_Type(entity, type);
    L4D2_SetEntityGlow_Range(entity, range);
    L4D2_SetEntityGlow_MinRange(entity, minRange);
    L4D2_SetEntityGlow_ColorOverride(entity, colorOverride);
    L4D2_SetEntityGlow_Flashing(entity, flashing);
    return true;
}

/**
 * Set entity glow type.
 *
 * @param entity        Entity index.
 * @parma type            Glow type.
 * @noreturn
 * @error                Invalid entity index or entity does not support glow.
 */
stock L4D2_SetEntGlow_Type(entity, L4D2GlowType:type)
{
    SetEntProp(entity, Prop_Send, "m_iGlowType", _:type);
}

/**
 * Set entity glow range.
 *
 * @param entity        Entity index.
 * @parma range            Glow range.
 * @noreturn
 * @error                Invalid entity index or entity does not support glow.
 */
stock L4D2_SetEntGlow_Range(entity, range)
{
    SetEntProp(entity, Prop_Send, "m_nGlowRange", range);
}

/**
 * Set entity glow min range.
 *
 * @param entity        Entity index.
 * @parma minRange        Glow min range.
 * @noreturn
 * @error                Invalid entity index or entity does not support glow.
 */
stock L4D2_SetEntGlow_MinRange(entity, minRange)
{
    SetEntProp(entity, Prop_Send, "m_nGlowRangeMin", minRange);
}

/**
 * Set entity glow color.
 *
 * @param entity        Entity index.
 * @parma colorOverride    Glow color, RGB.
 * @noreturn
 * @error                Invalid entity index or entity does not support glow.
 */
stock L4D2_SetEntGlow_ColorOverride(entity, colorOverride[3])
{
    SetEntProp(entity, Prop_Send, "m_glowColorOverride", colorOverride[0] + (colorOverride[1] * 256) + (colorOverride[2] * 65536));
}

/**
 * Set entity glow flashing state.
 *
 * @param entity        Entity index.
 * @parma flashing        Whether glow will be flashing.
 * @noreturn
 * @error                Invalid entity index or entity does not support glow.
 */
stock L4D2_SetEntGlow_Flashing(entity, bool:flashing)
{
    SetEntProp(entity, Prop_Send, "m_bFlashing", _:flashing);
} 


PHP Code:

glow()
{
    // turn on glow
    for (new client = 1; client <= MaxClients; client++)
    {
        if (!IsClientInGame(client)) continue;
        L4D2_SetEntGlow(client, L4D2Glow_Constant, 0, 0, {255, 255, 255}, false);
    }
    CreateTimer(15.0, _DisableGlow);
}

public Action:_DisableGlow(Handle:timer)
{
    // turn off glow
    for (new client = 1; client <= MaxClients; client++)
    {
        if (!IsClientInGame(client)) continue;
        L4D2_SetEntGlow(client, L4D2Glow_None, 0, 0, {255, 255, 255}, false);
    }
} 


[ajr1234]

This is awesome! Thank you very much If there was a +rep button I would click it.

[000101010001]

ok what do we do with this ???? makes no sense to me copy this text and put where exactly
im trying to compile a version of you glows plugin but it is looking for stocks whatever that is ,all im doing is getting rid of max glow but it wont work if anyone knows how please help me or do it for me +)

[Bacardi]

Originally Posted by 000101010001 ok what do we do with this ???? makes no sense to me copy this text and put where exactly im trying to compile a version of you glows plugin but it is looking for stocks whatever that is ,all im doing is getting rid of max glow but it wont work if anyone knows how please help me or do it for me +)

If anyone notice it have typos, this why not work.

    L4D2_SetEntityGlow_Type(entity, type);
    L4D2_SetEntityGlow_Range(entity, range);
    L4D2_SetEntityGlow_MinRange(entity, minRange);
    L4D2_SetEntityGlow_ColorOverride(entity, colorOverride);
    L4D2_SetEntityGlow_Flashing(entity, flashing);

Here try, I added plugin so you type admin command sm_glow it will glow all players for 15sec
Hope it works because I don't have this game.

[DonProof]

Originally Posted by Bacardi If anyone notice it have typos, this why not work. L4D2_SetEntityGlow_Type(entity, type); L4D2_SetEntityGlow_Range(entity, range); L4D2_SetEntityGlow_MinRange(entity, minRange); L4D2_SetEntityGlow_ColorOverride(entity, colorOverride); L4D2_SetEntityGlow_Flashing(entity, flashing); Here try, I added plugin so you type admin command sm_glow it will glow all players for 15sec Hope it works because I don't have this game.

How can I change the time, add more colors and add it to a menu selector to choose the colors more easily please.

[Darkwob]

Originally Posted by DonProof How can I change the time, add more colors and add it to a menu selector to choose the colors more easily please.

CreateTimer(your time _DisableGlow);

For the menu, you can check this article.

https://wiki.alliedmods.net/Menus_St...Mod_Scripting))